modules/lsp: add onAttach option

modules/lsp/default.nix

@@ -20,6 +20,7 @@ in
   imports = [
     ./servers
     ./keymaps.nix
+    ./on-attach.nix
   ];
 
   config = {

modules/lsp/on-attach.nix

@@ -0,0 +1,48 @@
+{ lib, config, ... }:
+let
+  cfg = config.lsp;
+in
+{
+  options.lsp = {
+    onAttach = lib.mkOption {
+      type = lib.types.lines;
+      description = ''
+        Lines of lua to be run when a language server is attached.
+
+        > [!TIP]
+        > The variables `client` and `bufnr` are made available in scope.
+
+        This is a global equivialent to the per-server `on_attach` callback,
+        which can be defined via `lsp.servers.<name>.settings.on_attach`.
+
+        Unlike the per-server callback, which should be defined as a lua
+        callback function, this option should be defined as the function body.
+      '';
+      default = "";
+    };
+  };
+
+  config = lib.mkIf (cfg.onAttach != "") {
+    autoGroups.nixvim_lsp_on_attach.clear = false;
+
+    autoCmd = [
+      {
+        event = "LspAttach";
+        group = "nixvim_lsp_on_attach";
+        callback = lib.nixvim.mkRaw ''
+          function(args)
+            do
+              -- client and bufnr are supplied to the builtin `on_attach` callback,
+              -- so make them available in scope for our global `onAttach` impl
+              local client = vim.lsp.get_client_by_id(args.data.client_id)
+              local bufnr = args.bufnr
+
+              ${cfg.onAttach}
+            end
+          end
+        '';
+        desc = "Run LSP onAttach";
+      }
+    ];
+  };
+}

plugins/by-name/lsp-format/default.nix

@@ -96,35 +96,30 @@ lib.nixvim.plugins.mkNeovimPlugin {
       '';
     };
 
-    autoGroups.nixvim_lsp_fmt_setup.clear = false;
+    lsp.onAttach =
+      let
+        toLua = lib.nixvim.lua.toLua' {
+          multiline = false;
+        };
 
-    autoCmd = lib.optionals (cfg.lspServersToEnable != "none") [
-      {
-        desc = "set up autoformatting on LSP attach";
-        event = "LspAttach";
-        group = "nixvim_lsp_fmt_setup";
-        callback =
-          let
-            enableCondition =
-              if cfg.lspServersToEnable == "all" then
-                "true"
-              else if lib.isList cfg.lspServersToEnable then
-                # Lua
-                "vim.list_contains(${lib.nixvim.toLuaObject cfg.lspServersToEnable}, client.name)"
-              else
-                throw "Unhandled value for `lspServersToEnable`: ${
-                  lib.generators.toPretty { } cfg.lspServersToEnable
-                }";
-          in
-          lib.nixvim.mkRaw ''
-            function(args)
-              local client = assert(vim.lsp.get_client_by_id(args.data.client_id))
-              if ${enableCondition} then
-                require("lsp-format").on_attach(client, args.buf)
+        wrapLua =
+          lua:
+          if cfg.lspServersToEnable == "all" then
+            lua
+          else if lib.isList cfg.lspServersToEnable then
+            # lua
+            ''
+              if vim.list_contains(${toLua cfg.lspServersToEnable}, client.name) then
+                ${lib.removeSuffix "\n" lua}
               end
-            end
-          '';
-      }
-    ];
+            ''
+          else
+            throw "Unhandled value for `lspServersToEnable`: ${
+              lib.generators.toPretty { } cfg.lspServersToEnable
+            }";
+      in
+      lib.mkIf (cfg.lspServersToEnable != "none") (wrapLua ''
+        require("lsp-format").on_attach(client, bufnr)
+      '');
   };
 }

tests/test-sources/plugins/by-name/lsp-format/default.nix

@@ -76,4 +76,19 @@
       };
     };
   };
+
+  listed-servers = {
+    plugins = {
+      lspconfig.enable = true;
+
+      lsp-format = {
+        enable = true;
+        lspServersToEnable = [
+          "foo"
+          "bar"
+          "baz"
+        ];
+      };
+    };
+  };
 }