[Pass Bug] pto-insert-sync primes both multi_tile slots for a preload + prefetch loop (design doc §7.2): wrong data with an even trip count, hang with an odd one #1519

module attributes {pto.target_arch = "a2a3"} {
  func.func @x2_kernel(%arg0: !pto.ptr<f32>, %arg1: !pto.ptr<f32>) attributes {pto.kernel_kind = #pto.kernel_kind<vector>} {
  %c0 = arith.constant 0 : index
  %c1 = arith.constant 1 : index
  %c2 = arith.constant 2 : index
  %c32 = arith.constant 32 : index
  %c128 = arith.constant 128 : index
  %cN = arith.constant 8 : index
  %cWa = arith.constant 1152 : index
  %cWo = arith.constant 1024 : index
  %out_view = pto.make_tensor_view %arg0, shape = [%c32, %cWo], strides = [%cWo, %c1] {layout = #pto.layout<nd>} : !pto.tensor_view<?x?xf32>
  %a_view = pto.make_tensor_view %arg1, shape = [%c32, %cWa], strides = [%cWa, %c1] {layout = #pto.layout<nd>} : !pto.tensor_view<?x?xf32>
  %mb = pto.alloc_multi_tile valid_row = %c32 valid_col = %c128 : !pto.multi_tile_buf<!pto.tile_buf<loc=vec, dtype=f32, rows=32, cols=128, v_row=?, v_col=?, blayout=row_major, slayout=none_box, fractal=512, pad=0>, count=2>
  // preload iter 0 -> slot0
  %pre = pto.multi_tile_get %mb[%c0] : !pto.multi_tile_buf<!pto.tile_buf<loc=vec, dtype=f32, rows=32, cols=128, v_row=?, v_col=?, blayout=row_major, slayout=none_box, fractal=512, pad=0>, count=2> -> !pto.tile_buf<loc=vec, dtype=f32, rows=32, cols=128, v_row=?, v_col=?, blayout=row_major, slayout=none_box, fractal=512, pad=0>
  %av_pre = pto.partition_view %a_view, offsets = [%c0, %c0], sizes = [%c32, %c128] : !pto.tensor_view<?x?xf32> -> !pto.partition_tensor_view<32x128xf32>
  pto.tload ins(%av_pre : !pto.partition_tensor_view<32x128xf32>) outs(%pre : !pto.tile_buf<loc=vec, dtype=f32, rows=32, cols=128, v_row=?, v_col=?, blayout=row_major, slayout=none_box, fractal=512, pad=0>)
  scf.for %i = %c0 to %cN step %c1 {
    %next     = arith.addi  %i,    %c1 : index
    %cur_idx  = arith.remui %i,    %c2 : index
    %next_idx = arith.remui %next, %c2 : index
    // prefetch chunk i+1 into the other slot
    %s_next = pto.multi_tile_get %mb[%next_idx] : !pto.multi_tile_buf<!pto.tile_buf<loc=vec, dtype=f32, rows=32, cols=128, v_row=?, v_col=?, blayout=row_major, slayout=none_box, fractal=512, pad=0>, count=2> -> !pto.tile_buf<loc=vec, dtype=f32, rows=32, cols=128, v_row=?, v_col=?, blayout=row_major, slayout=none_box, fractal=512, pad=0>
    %aoff = arith.muli %next, %c128 : index
    %av = pto.partition_view %a_view, offsets = [%c0, %aoff], sizes = [%c32, %c128] : !pto.tensor_view<?x?xf32> -> !pto.partition_tensor_view<32x128xf32>
    pto.tload ins(%av : !pto.partition_tensor_view<32x128xf32>) outs(%s_next : !pto.tile_buf<loc=vec, dtype=f32, rows=32, cols=128, v_row=?, v_col=?, blayout=row_major, slayout=none_box, fractal=512, pad=0>)
    // compute chunk i from the current slot, then store it
    %s_cur = pto.multi_tile_get %mb[%cur_idx] : !pto.multi_tile_buf<!pto.tile_buf<loc=vec, dtype=f32, rows=32, cols=128, v_row=?, v_col=?, blayout=row_major, slayout=none_box, fractal=512, pad=0>, count=2> -> !pto.tile_buf<loc=vec, dtype=f32, rows=32, cols=128, v_row=?, v_col=?, blayout=row_major, slayout=none_box, fractal=512, pad=0>
    %y = pto.alloc_tile valid_row = %c32 valid_col = %c128 : !pto.tile_buf<loc=vec, dtype=f32, rows=32, cols=128, v_row=?, v_col=?, blayout=row_major, slayout=none_box, fractal=512, pad=0>
    pto.tadd ins(%s_cur, %s_cur : !pto.tile_buf<loc=vec, dtype=f32, rows=32, cols=128, v_row=?, v_col=?, blayout=row_major, slayout=none_box, fractal=512, pad=0>, !pto.tile_buf<loc=vec, dtype=f32, rows=32, cols=128, v_row=?, v_col=?, blayout=row_major, slayout=none_box, fractal=512, pad=0>) outs(%y : !pto.tile_buf<loc=vec, dtype=f32, rows=32, cols=128, v_row=?, v_col=?, blayout=row_major, slayout=none_box, fractal=512, pad=0>)
    %ooff = arith.muli %i, %c128 : index
    %ov = pto.partition_view %out_view, offsets = [%c0, %ooff], sizes = [%c32, %c128] : !pto.tensor_view<?x?xf32> -> !pto.partition_tensor_view<32x128xf32>
    pto.tstore ins(%y : !pto.tile_buf<loc=vec, dtype=f32, rows=32, cols=128, v_row=?, v_col=?, blayout=row_major, slayout=none_box, fractal=512, pad=0>) outs(%ov : !pto.partition_tensor_view<32x128xf32>)
  }
  return
  }
}