Merge pull request #103: Open HTML in split & Mediawiki converter

In this merge commit I'm making a couple of minor changes:

 - The `---` sequence is now used as a horizontal divider in the
   Mediawiki syntax converter.

 - The changes to xolox#notes#html#view() created a temporary file even
   when the HTML was shown in a Vim split window, now the temporary file
   is only created when it needs to be passed to a web browser.

 - I changed some wrong indentation, removed some unused code (the
   counter variable) and renamed some private variables
   (s/hilight/highlight/g) and added word boundaries to the
   TODO/DONE/XXX matching in the file mediawiki.vim.

 - No trailing empty lines are added when a note is converted to
   Mediawiki syntax (there were in the pull request, but without context
   or explanation so I'd rather keep the Markdown, HTML and Mediawiki
   converters consistent).

Author: xolox

README.md

@@ -230,7 +230,13 @@ If for any reason you want to recreate the list of tags you can execute the `:In
 
 ### The `:NoteToHtml` command
 
-This command converts the current note to HTML. It works by first converting the current note to [Markdown] [markdown] and then using the `markdown` program to convert that to HTML. It requires an external program to convert Markdown to HTML. By default the program `markdown` is used, but you can change the name of the program using the `g:notes_markdown_program` option.
+This command converts the current note to HTML. It works by first converting the current note to [Markdown] [markdown] and then using the `markdown` program to convert that to HTML. It requires an external program to convert Markdown to HTML. By default the program `markdown` is used, but you can change the name of the program using the `g:notes_markdown_program` option. To convert your note to HTML and open the generated web page in a browser, you can run:
+
+    :NoteToHtml
+
+Alternatively, to convert your note to HTML and display it in a new split window in Vim, you can run:
+
+    :NoteToHtml split
 
 Note that this command can be a bit slow, because the parser for the note taking syntax is written in Vim script (for portability) and has not been optimized for speed (yet).
 
@@ -246,6 +252,14 @@ Convert the current note to a [Markdown document] [markdown]. The vim-notes synt
 
 Note that this command can be a bit slow, because the parser for the note taking syntax is written in Vim script (for portability) and has not been optimized for speed (yet).
 
+### The `:NoteToMediawiki` command
+
+Convert the current note to a [Mediawiki document] [mediawiki]. This is similar to the `:NoteToMarkdown` command, but it produces wiki text that can be displayed on a Mediawiki site. That being said, the subset of wiki markup that vim-notes actually produces will probably work on other wiki sites. These are the notable transforations:
+
+ * The first line of the note is a title, but it isn't used in the Mediawiki syntax. It could have been put into a `= Title =` tag, but it doesn't really make sense in the context of a wiki. It would make the table of contents nest under the title for every document you create.
+
+ * Preformatted blocks are output into `<syntaxhighlight lang="..">` tags. This functionality is enabled on Mediawiki through the [SyntaxHighlight GeSHi extention] [geshi]. It is also supported on Wikipedia.
+
 ## Mappings
 
 The following key mappings are defined inside notes.
@@ -351,6 +365,7 @@ This software is licensed under the [MIT license] [mit].
 [download-notes]: http://peterodding.com/code/vim/downloads/notes.zip
 [edit]: http://vimdoc.sourceforge.net/htmldoc/editing.html#:edit
 [enc]: http://vimdoc.sourceforge.net/htmldoc/options.html#'encoding'
+[geshi]: http://www.mediawiki.org/wiki/Extension:SyntaxHighlight_GeSHi
 [gf]: http://vimdoc.sourceforge.net/htmldoc/editing.html#gf
 [gfm]: https://help.github.com/articles/github-flavored-markdown/
 [github-misc]: http://github.com/xolox/vim-misc
@@ -360,6 +375,7 @@ This software is licensed under the [MIT license] [mit].
 [levenshtein]: http://en.wikipedia.org/wiki/Levenshtein_distance
 [mapleader]: http://vimdoc.sourceforge.net/htmldoc/map.html#mapleader
 [markdown]: http://en.wikipedia.org/wiki/Markdown
+[mediawiki]: https://www.mediawiki.org/wiki/MediaWiki
 [mit]: http://en.wikipedia.org/wiki/MIT_License
 [modeline]: http://vimdoc.sourceforge.net/htmldoc/options.html#modeline
 [monaco]: http://en.wikipedia.org/wiki/Monaco_(typeface)

autoload/xolox/notes.vim

@@ -1,12 +1,12 @@
 " Vim auto-load script
 " Author: Peter Odding <peter@peterodding.com>
-" Last Change: November 27, 2014
+" Last Change: December 29, 2014
 " URL: http://peterodding.com/code/vim/notes/
 
 " Note: This file is encoded in UTF-8 including a byte order mark so
 " that Vim loads the script using the right encoding transparently.
 
-let g:xolox#notes#version = '0.29'
+let g:xolox#notes#version = '0.30'
 let g:xolox#notes#url_pattern = '\<\(mailto:\|javascript:\|\w\{3,}://\)\(\S*\w\)\+/\?'
 let s:scriptdir = expand('<sfile>:p:h')
 

autoload/xolox/notes/html.vim

@@ -1,13 +1,13 @@
 " Vim auto-load script
 " Author: Peter Odding <peter@peterodding.com>
-" Last Change: June 23, 2013
+" Last Change: December 29, 2014
 " URL: http://peterodding.com/code/vim/notes/
 
 if !exists('g:notes_markdown_program')
   let g:notes_markdown_program = 'markdown'
 endif
 
-function! xolox#notes#html#view() " {{{1
+function! xolox#notes#html#view(open_in) " {{{1
   " Convert the current note to a web page and show the web page in a browser.
   " Requires [Markdown] [markdown] to be installed; you'll get a warning if it
   " isn't.
@@ -28,12 +28,19 @@ function! xolox#notes#html#view() " {{{1
           \ 'date': strftime('%A %B %d, %Y at %H:%M'),
           \ 'filename': fnamemodify(filename, ':~'),
           \ })
-    let filename = s:create_temporary_file(note_title)
-    if writefile(split(styled_html, "\n"), filename) != 0
-      throw printf("Failed to write HTML file! (%s)", filename)
+    if a:open_in == "split"
+      " Open the generated HTML in a :split window.
+      vnew
+      call setline(1, split(styled_html, "\n"))
+      setlocal filetype=html
+    else
+      " Open the generated HTML in a web browser.
+      let filename = s:create_temporary_file(note_title)
+      if writefile(split(styled_html, "\n"), filename) != 0
+        throw printf("Failed to write HTML file! (%s)", filename)
+      endif
+      call xolox#misc#open#url('file://' . filename)
     endif
-    " Open the generated HTML in a web browser.
-    call xolox#misc#open#url('file://' . filename)
     call xolox#misc#timer#stop("notes.vim %s: Rendered HTML preview in %s.", g:xolox#notes#version, starttime)
   catch
     call xolox#misc#msg#warn("notes.vim %s: %s at %s", g:xolox#notes#version, v:exception, v:throwpoint)

autoload/xolox/notes/mediawiki.vim

@@ -0,0 +1,110 @@
+" Vim auto-load script
+" Author: Anthony Naddeo <anthony.naddeo@gmail.com>
+" Last Change: December 29, 2014
+" URL: https://github.com/naddeoa
+
+function! xolox#notes#mediawiki#view() " {{{1
+  " Convert the current note to a Mediawiki document and show the converted text.
+  let note_text = join(getline(1, '$'), "\n")
+  let mediawiki_text = xolox#notes#mediawiki#convert_note(note_text)
+  vnew
+  call setline(1, split(mediawiki_text, "\n"))
+  setlocal filetype=mediawiki
+endfunction
+
+function! xolox#notes#mediawiki#convert_note(note_text) " {{{1
+  " Convert a note's text to the [Mediawiki text format] [mediawiki]. The syntax
+  " used by vim-notes has a lot of similarities with Mediawiki, but there are
+  " some notable differences like the note title and the way code blocks are
+  " represented. This function takes the text of a note (the first argument)
+  " and converts it to the Mediawiki format, returning a string.
+  "
+  " [mediawiki]: https://www.mediawiki.org/wiki/MediaWiki
+  let starttime = xolox#misc#timer#start()
+  let blocks = xolox#notes#parser#parse_note(a:note_text)
+  call map(blocks, 'xolox#notes#mediawiki#convert_block(v:val)')
+  let mediawiki = join(blocks, "\n\n")
+  call xolox#misc#timer#stop("notes.vim %s: Converted note to Mediawiki syntax in %s.", g:xolox#notes#version, starttime)
+  return mediawiki
+endfunction
+
+function! xolox#notes#mediawiki#convert_block(block) " {{{1
+  " Convert a single block produced by `xolox#misc#notes#parser#parse_note()`
+  " (the first argument, expected to be a dictionary) to the [Mediawiki text
+  " format] [mediawiki]. Returns a string.
+  if a:block.type == 'title'
+    let text = s:make_urls_explicit(a:block.text)
+    return ""
+  elseif a:block.type == 'heading'
+    let marker = repeat('=', 1 + a:block.level)
+    let text = s:make_urls_explicit(a:block.text)
+    return printf("%s %s %s", marker, text, marker)
+  elseif a:block.type == 'code'
+    return printf('<syntaxhighlight lang="%s">%s</syntaxhighlight>', a:block.language, a:block.text)
+  elseif a:block.type == 'divider'
+    return '----'
+  elseif a:block.type == 'list'
+    let items = []
+    if a:block.ordered
+      for item in a:block.items
+        let indent = repeat('#', item.indent + 1)
+        let text = s:make_urls_explicit(item.text)
+        let text = s:highlight_task_markers(text)
+        if text =~# "DONE"
+          call add(items, printf("%s <del>%s</del>", indent, text))
+        else
+          call add(items, printf("%s %s", indent, text))
+        endif
+      endfor
+    else
+      for item in a:block.items
+        let indent = repeat('*', item.indent + 1)
+        let text = s:make_urls_explicit(item.text)
+        let text = s:highlight_task_markers(text)
+        if text =~# "DONE"
+          call add(items, printf("%s <del>%s</del>", indent, text))
+        else
+          call add(items, printf("%s %s", indent, text))
+        endif
+      endfor
+    endif
+    return join(items, "\n")
+  elseif a:block.type == 'block-quote'
+    let lines = []
+    for line in a:block.lines
+      let prefix = repeat('>', line.level)
+      call add(lines, printf('%s %s', prefix, line.text))
+    endfor
+    return join(lines, "\n")
+  elseif a:block.type == 'paragraph'
+    let text = s:make_urls_explicit(a:block.text)
+    if len(text) <= 50 && text =~ ':$'
+      let text = printf("'''%s'''", text)
+    endif
+    return text
+  else
+    let msg = "Encountered unsupported block: %s!"
+    throw printf(msg, string(a:block))
+  endif
+endfunction
+
+function! s:highlight_task_markers(text)
+  " Highlight `TODO`, `DONE` and `XXX` markers with color in the Mediawiki
+  " output similar to how the markers are highlighted by vim-notes.
+  let highlighted = a:text
+  let highlighted = substitute(highlighted, '\C\<XXX\>', '<span style="color:red">XXX</span>', "")
+  let highlighted = substitute(highlighted, '\C\<TODO\>', '<span style="color:red">TODO</span>', "")
+  let highlighted = substitute(highlighted, '\C\<DONE\>', '<span style="color:green">DONE</span>', "")
+  return highlighted
+endfunction
+
+function! s:make_urls_explicit(text) " {{{1
+  " In the vim-notes syntax, URLs are implicitly hyperlinks.
+  " In Mediawiki syntax they have to be wrapped in [[markers]].
+  return substitute(a:text, g:xolox#notes#url_pattern, '\= s:url_callback(submatch(0))', 'g')
+endfunction
+
+function! s:url_callback(url)
+  let label = substitute(a:url, '^\w\+:\(//\)\?', '', '')
+  return printf('[%s %s]', a:url, label)
+endfunction

doc/notes.txt

@@ -38,6 +38,7 @@ Contents ~
   11. The |:IndexTaggedNotes| command
   12. The |:NoteToHtml| command
   13. The |:NoteToMarkdown| command
+  14. The |:NoteToMediawiki| command
  5. Mappings                                                   |notes-mappings|
   1. Insert mode mappings                          |notes-insert-mode-mappings|
  6. Customizing the syntax highlighting of notes |customizing-syntax-highlighting-of-notes|
@@ -516,8 +517,16 @@ This command converts the current note to HTML. It works by first converting
 the current note to Markdown [13] and then using the 'markdown' program to
 convert that to HTML. It requires an external program to convert Markdown to
 HTML. By default the program 'markdown' is used, but you can change the name of
-the program using the |g:notes_markdown_program| option.
-
+the program using the |g:notes_markdown_program| option. To convert your note
+to HTML and open the generated web page in a browser, you can run:
+>
+  :NoteToHtml
+<
+Alternatively, to convert your note to HTML and display it in a new split
+window in Vim, you can run:
+>
+  :NoteToHtml split
+<
 Note that this command can be a bit slow, because the parser for the note
 taking syntax is written in Vim script (for portability) and has not been
 optimized for speed (yet).
@@ -543,6 +552,24 @@ Note that this command can be a bit slow, because the parser for the note
 taking syntax is written in Vim script (for portability) and has not been
 optimized for speed (yet).
 
+-------------------------------------------------------------------------------
+The *:NoteToMediawiki* command
+
+Convert the current note to a Mediawiki document [14]. This is similar to the
+|:NoteToMarkdown| command, but it produces wiki text that can be displayed on a
+Mediawiki site. That being said, the subset of wiki markup that vim-notes
+actually produces will probably work on other wiki sites. These are the notable
+transforations:
+
+- The first line of the note is a title, but it isn't used in the Mediawiki
+  syntax. It could have been put into a '= Title =' tag, but it doesn't
+  really make sense in the context of a wiki. It would make the table of
+  contents nest under the title for every document you create.
+
+- Preformatted blocks are output into '<syntaxhighlight lang="..">' tags.
+  This functionality is enabled on Mediawiki through the SyntaxHighlight
+  GeSHi extention [15]. It is also supported on Wikipedia.
+
 ===============================================================================
                                                                *notes-mappings*
 Mappings ~
@@ -630,14 +657,14 @@ Other plug-ins that work well with the notes plug-in ~
                                                                 *notes-utl.vim*
 utl.vim ~
 
-The utl.vim [14] universal text linking plug-in enables links between your
+The utl.vim [16] universal text linking plug-in enables links between your
 notes, other local files and remote resources like web pages.
 
 -------------------------------------------------------------------------------
                                                               *notes-shell.vim*
 shell.vim ~
 
-My shell.vim [15] plug-in also enables easy navigation between your notes and
+My shell.vim [17] plug-in also enables easy navigation between your notes and
 environment like local files and directories, web pages and e-mail addresses by
 providing key mappings and commands to e.g. open the file/URL under the text
 cursor. This plug-in can also change Vim to full screen which can be really
@@ -647,7 +674,7 @@ nice for large notes.
                                                                    *notes-voom*
 VOoM ~
 
-The VOoM [16] outlining plug-in should work well for notes if you use the
+The VOoM [18] outlining plug-in should work well for notes if you use the
 Markdown style headers starting with '#', however it has been reported that
 this combination may not always work so well in practice (sometimes losing
 notes!)
@@ -657,7 +684,7 @@ notes!)
 Txtfmt ~
 
 If the text formatting supported by the notes plug-in is not enough for you,
-consider trying the Txtfmt [17] (The Vim Highlighter) plug-in. To use the two
+consider trying the Txtfmt [19] (The Vim Highlighter) plug-in. To use the two
 plug-ins together, create the file 'after/ftplugin/notes.vim' inside your Vim
 profile with the following contents:
 >
@@ -673,7 +700,7 @@ absolute pathnames that most certainly won't match between e.g. Windows and
 Linux or even Windows and Cygwin. The best you can do is keep separate session
 scripts for different platforms (and I would certainly consider Cygwin a
 separate platform altogether :-). For more information please refer to issue
-#85 [18].
+#85 [20].
 
 ===============================================================================
                                                                 *notes-contact*
@@ -682,13 +709,13 @@ Contact ~
 If you have questions, bug reports, suggestions, etc. the author can be
 contacted at peter@peterodding.com. The latest version is available at
 http://peterodding.com/code/vim/notes/ and http://github.com/xolox/vim-notes.
-If you like the script please vote for it on Vim Online [19].
+If you like the script please vote for it on Vim Online [21].
 
 ===============================================================================
                                                                 *notes-license*
 License ~
 
-This software is licensed under the MIT license [20]. © 2014 Peter Odding
+This software is licensed under the MIT license [22]. © 2014 Peter Odding
 <peter@peterodding.com>.
 
 ===============================================================================
@@ -708,12 +735,14 @@ References ~
 [11] http://github.com/xolox/vim-notes
 [12] http://github.com/xolox/vim-misc
 [13] http://en.wikipedia.org/wiki/Markdown
-[14] http://www.vim.org/scripts/script.php?script_id=293
-[15] http://www.vim.org/scripts/script.php?script_id=3123
-[16] http://www.vim.org/scripts/script.php?script_id=2657
-[17] http://www.vim.org/scripts/script.php?script_id=2208
-[18] https://github.com/xolox/vim-session/issues/85
-[19] http://www.vim.org/scripts/script.php?script_id=3375
-[20] http://en.wikipedia.org/wiki/MIT_License
+[14] https://www.mediawiki.org/wiki/MediaWiki
+[15] http://www.mediawiki.org/wiki/Extension:SyntaxHighlight_GeSHi
+[16] http://www.vim.org/scripts/script.php?script_id=293
+[17] http://www.vim.org/scripts/script.php?script_id=3123
+[18] http://www.vim.org/scripts/script.php?script_id=2657
+[19] http://www.vim.org/scripts/script.php?script_id=2208
+[20] https://github.com/xolox/vim-session/issues/85
+[21] http://www.vim.org/scripts/script.php?script_id=3375
+[22] http://en.wikipedia.org/wiki/MIT_License
 
 vim: ft=help

plugin/notes.vim

@@ -37,7 +37,8 @@ command! -bar -bang MostRecentNote call xolox#notes#recent#edit(<q-bang>)
 command! -bar -count=1 ShowTaggedNotes call xolox#notes#tags#show_tags(<count>)
 command! -bar IndexTaggedNotes call xolox#notes#tags#create_index()
 command! -bar NoteToMarkdown call xolox#notes#markdown#view()
-command! -bar NoteToHtml call xolox#notes#html#view()
+command! -bar NoteToMediawiki call xolox#notes#mediawiki#view()
+command! -bar -nargs=? NoteToHtml call xolox#notes#html#view(<q-args>)
 
 " TODO Generalize this so we have one command + modifiers (like :tab)?
 command! -bar -bang -range NoteFromSelectedText call xolox#notes#from_selection(<q-bang>, 'edit')