archrelease: copy trunk to community-staging-x86_64

git-svn-id: file:///srv/repos/svn-community/svn@737377 9fca08f4-af9d-4005-b8df-a31f2cc04f65

haskell-doclayout/repos/community-staging-x86_64/PKGBUILD

@@ -0,0 +1,42 @@
+# Maintainer: Felix Yan <felixonmars@archlinux.org>
+
+_hkgname=doclayout
+pkgname=haskell-doclayout
+pkgver=0.3
+pkgrel=40
+pkgdesc="A prettyprinting library for laying out text documents"
+url="https://github.com/jgm/doclayout"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-safe')
+makedepends=('ghc' 'haskell-tasty' 'haskell-tasty-golden' 'haskell-tasty-hunit')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('ccb8c41977c5cea47294157c812a31b3be5bddc872915d8baf0d9063d597429606d83e4f7cf9e4aea9b1e1416cbcf732fbbcd71b6659de6510c661f9225d33d0')
+
+build() {
+    cd $_hkgname-$pkgver    
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}