Add a network defined resource (#30)

* add systemd::network defined resource

* manage systemd-networkd in init.pp

README.md

@@ -79,3 +79,18 @@ Or provide the configuration file yourself. Systemd reloading and restarting of
   source => "puppet:///modules/${module_name}/foo.conf",
 }
 ```
+
+### network
+
+systemd-networkd is able to manage your network configuration. We provide a
+defined resource which can write the interface configurations. systemd-networkd
+needs to be restarted to apply the configs. The defined resource can do this
+for you, besides managing the service itself.
+
+```puppet
+::systemd::network{'eth0.network':
+  source          => "puppet:///modules/${module_name}/eth0.network",
+  manage_service  => true,
+  restart_service => true,
+}
+```

manifests/init.pp

@@ -3,6 +3,7 @@
 class systemd (
   $service_limits          = {},
   Boolean $manage_resolved = true,
+  Boolean $manage_networkd = true,
 ){
 
   Exec {
@@ -32,4 +33,11 @@
       target => '/run/systemd/resolve/resolv.conf',
     }
   }
+
+  if $manage_networkd {
+    service{'systemd-networkd':
+      ensure => 'running',
+      enable => true,
+    }
+  }
 }

manifests/network.pp

@@ -0,0 +1,30 @@
+# -- Define: systemd::network
+# Creates network config for systemd-networkd
+define systemd::network (
+  Enum['file', 'absent'] $ensure         = file,
+  Stdlib::Absolutepath $path             = '/etc/systemd/network',
+  Optional[String] $content              = undef,
+  Optional[String] $source               = undef,
+  Optional[Stdlib::Absolutepath] $target = undef,
+  Boolean $restart_service               = true,
+){
+
+  include ::systemd
+
+  if $restart_service {
+    $notify = Service['systemd-networkd']
+  } else {
+    $notify = undef
+  }
+
+  file { "${path}/${name}":
+    ensure  => $ensure,
+    content => $content,
+    source  => $source,
+    target  => $target,
+    owner   => 'root',
+    group   => 'root',
+    mode    => '0444',
+    notify  => $notify,
+  }
+}