Update of the nix flake tooling (#1108)

CONTRIBUTING.md

@@ -17,17 +17,19 @@ At minimum, you will need to have these available in your development environmen
 
 You may also use [nix package manager](https://nixos.org/download.html) to get a reproducible, declarative and reliable development environment.
 
-Development shells options are available under `devShells` folder ([nix flakes](https://nixos.wiki/wiki/Flakes) required):
+Development shells options are available as different devShells commands in ([nix flakes](https://nixos.wiki/wiki/Flakes) required):
 
 - minimum, minimum development environment for building monorepo.
 - whitehat, additional ethereum development toolings including slither, echidna, etc.
-- spec, for developing of Superfluid haskell spec.
+- spec, for developing of Superfluid haskell spec,
+- full, everything included.
 
 To use them:
 
-- `nix develop path:flakes/minimum` or `npm run shell`
-- `nix develop path:flakes/whitehat` or `npm run shell:whitehat`
-- `nix develop path:flakes/spec` or `npm run shell:spec`
+- `nix develop .` or `npm run shell`
+- `nix develop .#whitehat` or `npm run shell:whitehat`
+- `nix develop .#spec` or `npm run shell:spec`
+- `nix develop .#full` or `npm run shell:full`
 
 ### Installing Dependencies
 

flake.nix

@@ -0,0 +1,72 @@
+{
+  description = "Flake commands (including dev shells) for working with the monorepo.";
+
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
+    flakeUtils.url = "github:numtide/flake-utils";
+    foundry.url = "github:shazow/foundry.nix";
+  };
+
+  outputs = { self, nixpkgs, flakeUtils, foundry } :
+  flakeUtils.lib.eachDefaultSystem (system:
+  let
+    pkgs = import nixpkgs { inherit system; };
+    # minimem development shell
+    minimumEVMDevInputs = with pkgs; [
+      # for nodejs ecosystem
+      yarn
+      nodejs-16_x
+      # for solidity development
+      foundry.defaultPackage.${system}
+    ];
+    # additional tooling for whitehat hackers
+    whitehatInputs = with pkgs; [
+      slither-analyzer
+      echidna
+    ];
+    # for developing specification
+    specInputs = with pkgs; [
+      # for nodejs ecosystem
+      yarn
+      gnumake
+      nodePackages.nodemon
+      # for haskell spec
+      cabal-install
+      haskell.compiler.ghc92
+      (haskell-language-server.override {
+        supportedGhcVersions = [ "924" ];
+      })
+      hlint
+      gnuplot
+      # sage math
+      sage
+      # yellow-paper pipeline
+      haskellPackages.lhs2tex
+      python39Packages.pygments
+      (texlive.combine {
+        inherit (texlive)
+        scheme-basic metafont
+        collection-latex collection-latexextra
+        collection-bibtexextra collection-mathscience
+        collection-fontsrecommended collection-fontsextra;
+      })
+    ];
+  in {
+    devShells.default = with pkgs; mkShell {
+      buildInputs = minimumEVMDevInputs;
+    };
+    devShells.whitehat = with pkgs; mkShell {
+      buildInputs = minimumEVMDevInputs
+        ++ whitehatInputs;
+    };
+    devShells.spec = with pkgs; mkShell {
+      buildInputs = specInputs;
+    };
+    devShells.full = with pkgs; mkShell {
+      buildInputs = minimumEVMDevInputs
+      ++ whitehatInputs
+      ++ specInputs;
+    };
+  });
+}
+