bring over autoconf etc files from samtools unchanged

.gitignore

@@ -5,6 +5,15 @@ plugins/*.so
 plugins/*.dSYM
 plugins/*.P
 
+aclocal.m4
+autom4te.cache
+config.cache
+config.h
+config.log
+config.mk
+config.status
+configure
+
 /test/test-rbuf
 /test/test-regidx
 

config.h.in

@@ -0,0 +1,50 @@
+/* config.h.in -- template for config.h.  If you use configure, this file
+   provides #defines reflecting your configuration choices.  If you don't
+   run configure, suitable conservative defaults will be used.
+
+   This template file can be updated with autoheader, but do so carefully
+   as autoheader adds #defines such as PACKAGE_* that we don't want.  */
+
+/* Define to 1 if a SysV or X/Open compatible Curses library is present */
+#undef HAVE_CURSES
+
+/* Define to 1 if library supports color (enhanced functions) */
+#undef HAVE_CURSES_COLOR
+
+/* Define to 1 if library supports X/Open Enhanced functions */
+#undef HAVE_CURSES_ENHANCED
+
+/* Define to 1 if <curses.h> is present */
+#undef HAVE_CURSES_H
+
+/* Define to 1 if library supports certain obsolete features */
+#undef HAVE_CURSES_OBSOLETE
+
+/* Define to 1 if the Ncurses library is present */
+#undef HAVE_NCURSES
+
+/* Define to 1 if the NcursesW library is present */
+#undef HAVE_NCURSESW
+
+/* Define to 1 if <ncursesw/curses.h> is present */
+#undef HAVE_NCURSESW_CURSES_H
+
+/* Define to 1 if <ncursesw.h> is present */
+#undef HAVE_NCURSESW_H
+
+/* Define to 1 if <ncurses/curses.h> is present */
+#undef HAVE_NCURSES_CURSES_H
+
+/* Define to 1 if <ncurses.h> is present */
+#undef HAVE_NCURSES_H
+
+/* Enable large inode numbers on Mac OS X 10.5.  */
+#ifndef _DARWIN_USE_64_BIT_INODE
+# define _DARWIN_USE_64_BIT_INODE 1
+#endif
+
+/* Number of bits in a file offset, on hosts where this is settable. */
+#undef _FILE_OFFSET_BITS
+
+/* Define for large files, on AIX-style hosts. */
+#undef _LARGE_FILES

config.mk.in

@@ -0,0 +1,54 @@
+#  Optional configure Makefile overrides for samtools.
+#
+#    Copyright (C) 2015,2017 Genome Research Ltd.
+#
+#    Author: John Marshall <jm18@sanger.ac.uk>
+#
+# Permission is hereby granted, free of charge, to any person obtaining a copy
+# of this software and associated documentation files (the "Software"), to deal
+# in the Software without restriction, including without limitation the rights
+# to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+# copies of the Software, and to permit persons to whom the Software is
+# furnished to do so, subject to the following conditions:
+#
+# The above copyright notice and this permission notice shall be included in
+# all copies or substantial portions of the Software.
+#
+# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+# FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL
+# THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+# LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
+# FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
+# DEALINGS IN THE SOFTWARE.
+
+# This is @configure_input@
+#
+# If you use configure, this file overrides variables and augments rules
+# in the Makefile to reflect your configuration choices.  If you don't run
+# configure, the main Makefile contains suitable conservative defaults.
+
+prefix       = @prefix@
+exec_prefix  = @exec_prefix@
+bindir       = @bindir@
+datarootdir  = @datarootdir@
+mandir       = @mandir@
+
+CC       = @CC@
+CPPFLAGS = @CPPFLAGS@
+CFLAGS   = @CFLAGS@
+LDFLAGS  = @LDFLAGS@
+LIBS     = @LIBS@
+
+@Hsource@HTSDIR = @HTSDIR@
+@Hsource@include $(HTSDIR)/htslib.mk
+@Hsource@include $(HTSDIR)/htslib_static.mk
+@Hsource@HTSLIB = $(HTSDIR)/libhts.a
+@Hsource@HTSLIB_LIB = $(HTSLIB) $(HTSLIB_static_LIBS)
+@Hsource@HTSLIB_LDFLAGS = $(HTSLIB_static_LDFLAGS)
+@Hsource@BGZIP = $(HTSDIR)/bgzip
+HTSLIB_CPPFLAGS = @HTSLIB_CPPFLAGS@
+@Hinstall@HTSLIB_LDFLAGS = @HTSLIB_LDFLAGS@
+@Hinstall@HTSLIB_LIB = -lhts
+
+CURSES_LIB = @CURSES_LIB@

configure.ac

@@ -0,0 +1,111 @@
+# Configure script for samtools, utilities for Sequence Alignment/Map files.
+#
+#    Copyright (C) 2015 Genome Research Ltd.
+#
+#    Author: John Marshall <jm18@sanger.ac.uk>
+#
+# Permission is hereby granted, free of charge, to any person obtaining a copy
+# of this software and associated documentation files (the "Software"), to deal
+# in the Software without restriction, including without limitation the rights
+# to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+# copies of the Software, and to permit persons to whom the Software is
+# furnished to do so, subject to the following conditions:
+#
+# The above copyright notice and this permission notice shall be included in
+# all copies or substantial portions of the Software.
+#
+# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+# FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL
+# THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+# LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
+# FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
+# DEALINGS IN THE SOFTWARE.
+
+dnl Process this file with autoconf to produce a configure script
+AC_INIT([Samtools], m4_esyscmd_s([make print-version]),
+        [samtools-help@lists.sourceforge.net], [], [http://www.htslib.org/])
+AC_PREREQ([2.63])  dnl This version introduced 4-argument AC_CHECK_HEADER
+AC_CONFIG_SRCDIR([bamtk.c])
+AC_CONFIG_HEADERS([config.h])
+
+m4_include([m4/ax_with_curses.m4])
+m4_include([m4/ax_with_htslib.m4])
+
+dnl Copyright notice to be copied into the generated configure script
+AC_COPYRIGHT([Portions copyright (C) 2015 Genome Research Ltd.
+
+This configure script is free software: you are free to change and
+redistribute it.  There is NO WARRANTY, to the extent permitted by law.])
+
+AC_PROG_CC
+
+AC_SYS_LARGEFILE
+
+AX_WITH_HTSLIB
+if test "$ax_cv_htslib" != yes; then
+  AC_MSG_ERROR([HTSlib development files not found
+
+Samtools uses HTSlib to parse bioinformatics file formats etc.  Building it
+requires an unpacked HTSlib source tree (which will be built in conjunction
+with samtools) or a previously-installed HTSlib.  In either case you may
+need to configure --with-htslib=DIR to locate the appropriate HTSlib.
+
+FAILED.  You must supply an HTSlib in order to build samtools successfully.])
+fi
+
+if test "$ax_cv_htslib_which" = source; then
+  Hsource=
+  Hinstall='#'
+else
+  Hsource='#'
+  Hinstall=
+fi
+AC_SUBST([Hsource])
+AC_SUBST([Hinstall])
+
+AC_ARG_WITH([curses],
+  [AS_HELP_STRING([--without-curses],
+                  [omit curses support, so no curses library needed])])
+
+if test "$with_curses" != no; then
+  AX_WITH_CURSES
+  if test "$ax_cv_curses" != yes; then
+    AC_MSG_ERROR([curses development files not found
+
+The 'samtools tview' command uses the curses text user interface library.
+Building samtools with tview requires curses/ncurses/etc development files
+to be installed on the build machine; you may need to ensure a package such
+as libncurses5-dev (on Debian or Ubuntu Linux) or ncurses-devel (on RPM-based
+Linux distributions) is installed.
+
+FAILED.  Either configure --without-curses or resolve this error to build
+samtools successfully.])
+  fi
+else
+  CURSES_LIB=
+  CURSES_CPPFLAGS=
+  AC_SUBST([CURSES_LIB])
+  AC_SUBST([CURSES_CPPFLAGS])
+fi
+
+save_LIBS=$LIBS
+zlib_devel=ok
+dnl Set a trivial non-empty INCLUDES to avoid excess default includes tests
+AC_CHECK_HEADER([zlib.h], [], [zlib_devel=missing], [;])
+AC_CHECK_LIB(z, inflate,  [], [zlib_devel=missing])
+LIBS=$save_LIBS
+
+if test $zlib_devel != ok; then
+  AC_MSG_ERROR([zlib development files not found
+
+Samtools uses compression routines from the zlib library <http://zlib.net>.
+Building samtools requires zlib development files to be installed on the build
+machine; you may need to ensure a package such as zlib1g-dev (on Debian or
+Ubuntu Linux) or zlib-devel (on RPM-based Linux distributions) is installed.
+
+FAILED.  This error must be resolved in order to build samtools successfully.])
+fi
+
+AC_CONFIG_FILES([config.mk])
+AC_OUTPUT