Make it easier to package certain content in the root of a fat jar

[wilkinsona]

Spring Boot 1.4 has made using this technique for including a Java agent in a fat jar more difficult. The problem is that the agent's classes get repackaged into BOOT-INF/classes but they need to stay in the root of the jar.

You can work around it by using a separate module to consume the fat jar and add the agent to it but it'd be nice if users didn't have to jump through that extra hoop. One solution would be to add something to the build plugins that allow a user to mark certain classes as having to stay in the root of the jar.

[10168852]

in spring boot 1.4 we could have a deployable be a dependency to another project. Now it can't cause being a dependency maven isn't able to find the classes because they are located at BOOT-INF/classes

[snicoll]

@10168852 this is unrelated to this issue and I frankly consider this to be an improvement. Using a fat jar as a dependency means that you take the complete dependency tree with it. That deployable of yours must be quite large. Please have a look to this stackoverflow thread.

[wilkinsona]

#2268 is somewhat related to this

[reachym]

@wilkinsona We are facing the issue you mentioned above as we currently use the fat jar for Newrelic's javaagent. We recently upgraded to 1.4 version of Spring Boot and due to the different structure, it's not working anymore. Could you please elaborate a bit more on "You can work around it by using a separate module to consume the fat jar and add the agent to it"? I know it's probably unrelated here, but it would be great if you can provide the alternative while you are discussing the issue. Thanks!

[wilkinsona]

Here's an example with Gradle that doesn't require a separate module. The jarWithAgent task will produce a second jar that contains New Relic's agent alongside the fat jar:

buildscript {
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath 'org.springframework.boot:spring-boot-gradle-plugin:1.4.1.RELEASE'
    }
}

repositories {
    mavenCentral()
}

apply plugin: 'spring-boot'

springBoot {
    mainClass 'com.example.Main'
}

configurations {
    newrelic
}

dependencies {
    compile 'org.springframework.boot:spring-boot-starter-web'
    newrelic 'com.newrelic.agent.java:newrelic-agent:3.12.1'
}

task extractManifest(type: Copy) {
    dependsOn bootRepackage
    from(zipTree(jar.outputs.files.singleFile))
    include 'META-INF/MANIFEST.MF'
    into 'build/extracted'
}

task jarWithAgent(type: Jar) {
    dependsOn extractManifest
    classifier 'with-agent'
    entryCompression ZipEntryCompression.STORED
    from(
        zipTree(jar.outputs.files.singleFile),
        zipTree(configurations.newrelic.singleFile)
    )
    manifest {
        from new File(extractManifest.outputs.files.singleFile, '/META-INF/MANIFEST.MF')
        attributes([
            'Premain-Class': 'com.newrelic.bootstrap.BootstrapAgent',
            'Can-Redefine-Classes': 'true',
            'Can-Retransform-Classes': 'true'
        ])
    }
}

[marcosbarbero]

@wilkinsona is there at tip to achieve same thing using maven?

[wilkinsona]

Another use case for this is Cloud Foundry's pre-runtime hooks that need to be placed in the root of an application's directory. When you're pushing a fat jar, that means they need to go in the root of the archive. That's trickier in 1.4 as anything that was in src/main/resources will now be repackaged into BOOT-INF/classes.