Migration: Renamed MimeType to MediaType

[Jamie-SA]

Migration script for issue #434.

Write a query to update all existing gist:MimeType terms to gist:MediaType.

[Jamie-SA]

Starting point for a term replacement query:

PREFIX gist: <https://ontologies.semanticarts.com/gist/>

DELETE {
  ?target ?p1 ?o1 .
  ?s2 ?target ?o2 .
  ?s3 ?p3 ?target .
}
INSERT {
  ?replacement ?p1 ?o1 .
  ?s2 ?replacement ?o2 .
  ?s3 ?p3 ?replacement .
}
WHERE {
  values (?target ?replacement) {(gist:MimeType gist:MediaType)}
  OPTIONAL {?target ?p1 ?o1 .}
  OPTIONAL {?s2 ?target ?o2 .}
  OPTIONAL {?s3 ?p3 ?target .}
}

Pinging @sa-bpelakh for review.

[sa-bpelakh]

A couple of issues:

1. Need to be able to reach into named graphs. Unfortunately, since there is no universal behavior on whether default graph triples will be matched by graph ?g { ?s ?p ?o } (on AWS it gives you a default graph URI, on Stardog/Agraph, doesn't match at all), I would do this using two different queries for simplicity and performance.
2. It has been my experience that UNION performs better than OPTIONAL in this case, so the result would be

PREFIX gist: <https://ontologies.semanticarts.com/gist/>

DELETE {
  graph ?g1 { ?target ?p1 ?o1 }
  graph ?g2 { ?s2 ?target ?o2 }
  graph ?g3 { ?s3 ?p3 ?target }
}
INSERT {
  graph ?g1 { ?replacement ?p1 ?o1 }
  graph ?g2 { ?s2 ?replacement ?o2 }
  graph ?g3 { ?s3 ?p3 ?replacement }
}
WHERE {
  values (?target ?replacement) {(gist:MimeType gist:MediaType)}
  { graph ?g1 { ?target ?p1 ?o1 . } }
  UNION { graph ?g2 { ?s2 ?target ?o2 . } }
  UNION { graph ?g3 { ?s3 ?p3 ?target . } }
}

and the default graph migration, which will only work if named graphs are not matched unless referenced, as there is no way to stick a FROM DEFAULT on an UPDATE query.

PREFIX gist: <https://ontologies.semanticarts.com/gist/>

DELETE {
  ?target ?p1 ?o1 .
  ?s2 ?target ?o2 .
  ?s3 ?p3 ?target .
}
INSERT {
  ?replacement ?p1 ?o1 .
  ?s2 ?replacement ?o2 .
  ?s3 ?p3 ?replacement .
}
WHERE {
  values (?target ?replacement) {(gist:MimeType gist:MediaType)}
  {?target ?p1 ?o1 .}
  UNION {?s2 ?target ?o2 .}
  UNION {?s3 ?p3 ?target .}
}