Callback onTxDone and Better Random

API.md

@@ -117,6 +117,24 @@ LoRa.endPacket(async);
 
 Returns `1` on success, `0` on failure.
 
+### Tx Done
+
+**WARNING**: Not supported on the Arduino MKR WAN 1300 board! 
+
+### Register callback
+
+Register a callback function for when a packet transmission finish.
+
+```arduino
+LoRa.onTxDone(onTxDone);
+
+void onTxDone() {
+ // ...
+}
+```
+
+ * `onTxDone` - function to call when a packet transmission finish.
+
 ## Receiving data
 
 ### Parsing packet

examples/LoRaSimpleGateway/LoRaSimpleGateway.ino

@@ -53,6 +53,7 @@ void setup() {
   Serial.println();
 
   LoRa.onReceive(onReceive);
+  LoRa.onTxDone(onTxDone);
   LoRa_rxMode();
 }
 
@@ -83,8 +84,7 @@ void LoRa_sendMessage(String message) {
   LoRa_txMode();                        // set tx mode
   LoRa.beginPacket();                   // start packet
   LoRa.print(message);                  // add payload
-  LoRa.endPacket();                     // finish packet and send it
-  LoRa_rxMode();                        // set rx mode
+  LoRa.endPacket(true);                 // finish packet and send it
 }
 
 void onReceive(int packetSize) {
@@ -96,7 +96,11 @@ void onReceive(int packetSize) {
 
   Serial.print("Gateway Receive: ");
   Serial.println(message);
+}
 
+void onTxDone() {
+  Serial.println("TxDone");
+  LoRa_rxMode();
 }
 
 boolean runEvery(unsigned long interval)

examples/LoRaSimpleNode/LoRaSimpleNode.ino

@@ -53,6 +53,7 @@ void setup() {
   Serial.println();
 
   LoRa.onReceive(onReceive);
+  LoRa.onTxDone(onTxDone);
   LoRa_rxMode();
 }
 
@@ -83,8 +84,7 @@ void LoRa_sendMessage(String message) {
   LoRa_txMode();                        // set tx mode
   LoRa.beginPacket();                   // start packet
   LoRa.print(message);                  // add payload
-  LoRa.endPacket();                     // finish packet and send it
-  LoRa_rxMode();                        // set rx mode
+  LoRa.endPacket(true);                 // finish packet and send it
 }
 
 void onReceive(int packetSize) {
@@ -96,7 +96,11 @@ void onReceive(int packetSize) {
 
   Serial.print("Node Receive: ");
   Serial.println(message);
+}
 
+void onTxDone() {
+  Serial.println("TxDone");
+  LoRa_rxMode();
 }
 
 boolean runEvery(unsigned long interval)

examples/LoRaSimpleRandomSeed/LoRaSimpleRandomSeed.ino

@@ -0,0 +1,65 @@
+/*
+  LoRa Simple Random Seed
+
+  This code generate a randomSeed using the LoRa Module.
+
+  created 03 October 2018
+  by Luiz H. Cassettari
+*/
+
+#include <SPI.h>              // include libraries
+#include <LoRa.h>
+
+const long frequency = 915E6;  // LoRa Frequency
+
+const int csPin = 10;          // LoRa radio chip select
+const int resetPin = 9;        // LoRa radio reset
+const int irqPin = 2;          // change for your board; must be a hardware interrupt pin
+
+uint32_t seed = 0;
+
+void setup() {
+  Serial.begin(9600);                   // initialize serial
+  while (!Serial);
+
+  LoRa.setPins(csPin, resetPin, irqPin);
+
+  if (!LoRa.begin(frequency)) {
+    Serial.println("LoRa init failed. Check your connections.");
+    while (true);                       // if failed, do nothing
+  }
+
+  Serial.println("LoRa init succeeded.");
+  Serial.println();
+  Serial.println("LoRa Simple Random");
+  Serial.println("'LoRa.random()' only works when the module is on receive mode");
+  Serial.println("This code generate a randomSeed using the LoRa Module");
+  Serial.println();
+
+  LoRa.receive();
+
+  // Generate a random seed with 32 bits
+  seed = (uint32_t) LoRa.random() << 24 |
+         (uint32_t) LoRa.random() << 16 |
+         (uint32_t) LoRa.random() << 8 |
+         (uint32_t) LoRa.random();
+
+  LoRa.sleep();
+
+  randomSeed(seed);
+  Serial.print("Random Seed : ");
+  Serial.println(seed);
+  Serial.println();
+}
+
+void loop() {
+  for (int i = 0; i < 16; i++) {
+    byte b = random();
+    if (b < 0x10) 
+      Serial.print('0');
+    Serial.print(b, HEX);
+    Serial.print(" ");
+  }
+  Serial.println();
+  delay(1000);
+}

keywords.txt

@@ -31,6 +31,7 @@ peek	KEYWORD2
 flush	KEYWORD2
 
 onReceive	KEYWORD2
+onTxDone	KEYWORD2
 receive	KEYWORD2
 idle	KEYWORD2
 sleep	KEYWORD2

src/LoRa.cpp

@@ -64,7 +64,8 @@ LoRaClass::LoRaClass() :
   _frequency(0),
   _packetIndex(0),
   _implicitHeaderMode(0),
-  _onReceive(NULL)
+  _onReceive(NULL),
+  _onTxDone(NULL)
 {
   // overide Stream timeout value
   setTimeout(0);
@@ -171,13 +172,14 @@ int LoRaClass::beginPacket(int implicitHeader)
 
 int LoRaClass::endPacket(bool async)
 {
+
+  if ((async) && (_onTxDone))
+      writeRegister(REG_DIO_MAPPING_1, 0x40); // DIO0 => TXDONE
+
   // put in TX mode
   writeRegister(REG_OP_MODE, MODE_LONG_RANGE_MODE | MODE_TX);
 
-  if (async) {
-    // grace time is required for the radio
-    delayMicroseconds(150);
-  } else {
+  if (!async) {
     // wait for TX done
     while ((readRegister(REG_IRQ_FLAGS) & IRQ_TX_DONE_MASK) == 0) {
       yield();
@@ -347,8 +349,24 @@ void LoRaClass::onReceive(void(*callback)(int))
 
   if (callback) {
     pinMode(_dio0, INPUT);
+#ifdef SPI_HAS_NOTUSINGINTERRUPT
+    SPI.usingInterrupt(digitalPinToInterrupt(_dio0));
+#endif
+    attachInterrupt(digitalPinToInterrupt(_dio0), LoRaClass::onDio0Rise, RISING);
+  } else {
+    detachInterrupt(digitalPinToInterrupt(_dio0));
+#ifdef SPI_HAS_NOTUSINGINTERRUPT
+    SPI.notUsingInterrupt(digitalPinToInterrupt(_dio0));
+#endif
+  }
+}
+
+void LoRaClass::onTxDone(void(*callback)())
+{
+  _onTxDone = callback;
 
-    writeRegister(REG_DIO_MAPPING_1, 0x00);
+  if (callback) {
+    pinMode(_dio0, INPUT);
 #ifdef SPI_HAS_NOTUSINGINTERRUPT
     SPI.usingInterrupt(digitalPinToInterrupt(_dio0));
 #endif
@@ -363,6 +381,9 @@ void LoRaClass::onReceive(void(*callback)(int))
 
 void LoRaClass::receive(int size)
 {
+
+  writeRegister(REG_DIO_MAPPING_1, 0x00); // DIO0 => RXDONE
+
   if (size > 0) {
     implicitHeaderMode();
 
@@ -582,7 +603,12 @@ void LoRaClass::setOCP(uint8_t mA)
 
 byte LoRaClass::random()
 {
-  return readRegister(REG_RSSI_WIDEBAND);
+  static byte result = 0;
+  for(int i = 0; i < 8; i++) {
+    result = (result << 1) | (result >> 7); // Spread randomness around / rotate left 
+    result ^= readRegister(REG_RSSI_WIDEBAND); // XOR preserves randomness
+  }
+  return result;
 }
 
 void LoRaClass::setPins(int ss, int reset, int dio0)
@@ -634,21 +660,30 @@ void LoRaClass::handleDio0Rise()
   writeRegister(REG_IRQ_FLAGS, irqFlags);
 
   if ((irqFlags & IRQ_PAYLOAD_CRC_ERROR_MASK) == 0) {
-    // received a packet
-    _packetIndex = 0;
 
-    // read packet length
-    int packetLength = _implicitHeaderMode ? readRegister(REG_PAYLOAD_LENGTH) : readRegister(REG_RX_NB_BYTES);
+    if ((irqFlags & IRQ_RX_DONE_MASK) != 0) {
+      // received a packet
+      _packetIndex = 0;
 
-    // set FIFO address to current RX address
-    writeRegister(REG_FIFO_ADDR_PTR, readRegister(REG_FIFO_RX_CURRENT_ADDR));
+      // read packet length
+      int packetLength = _implicitHeaderMode ? readRegister(REG_PAYLOAD_LENGTH) : readRegister(REG_RX_NB_BYTES);
+
+      // set FIFO address to current RX address
+      writeRegister(REG_FIFO_ADDR_PTR, readRegister(REG_FIFO_RX_CURRENT_ADDR));
+
+      if (_onReceive) {
+        _onReceive(packetLength);
+      }
 
-    if (_onReceive) {
-      _onReceive(packetLength);
+      // reset FIFO address
+      writeRegister(REG_FIFO_ADDR_PTR, 0);
     }
 
-    // reset FIFO address
-    writeRegister(REG_FIFO_ADDR_PTR, 0);
+    else if ((irqFlags & IRQ_TX_DONE_MASK) != 0) {
+      if (_onTxDone) {
+        _onTxDone();
+      }
+    }
   }
 }
 

src/LoRa.h

@@ -51,6 +51,7 @@ class LoRaClass : public Stream {
 
 #ifndef ARDUINO_SAMD_MKRWAN1300
   void onReceive(void(*callback)(int));
+  void onTxDone(void(*callback)());
 
   void receive(int size = 0);
 #endif
@@ -111,6 +112,7 @@ class LoRaClass : public Stream {
   int _packetIndex;
   int _implicitHeaderMode;
   void (*_onReceive)(int);
+  void (*_onTxDone)();
 };
 
 extern LoRaClass LoRa;