Trac #27795: spkg-configure.m4 for perl_term_readline_gnu

this is a slightly non-standard perl module we happen to have an spkg
for, used in polymake interface.

On Debian this module is  in `libterm-readline-gnu-perl`.

URL: https://trac.sagemath.org/27795
Reported by: dimpase
Ticket author(s): Dima Pasechnik
Reviewer(s): Matthias Koeppe

build/pkgs/perl_term_readline_gnu/spkg-configure.m4

@@ -0,0 +1,13 @@
+SAGE_SPKG_CONFIGURE(
+    [perl_term_readline_gnu], [dnl direct testing for Term::ReadLine::Gnu does not work
+    AX_PROG_PERL_MODULES( Term::ReadLine, [dnl check that it's a GNU one
+      AC_MSG_CHECKING( Term::ReadLine module...)
+      $PERL -e "use Term::ReadLine; Term::ReadLine->get_all_function_names" > /dev/null 2>&1
+      if test $? -ne 0; then
+        AC_MSG_RESULT(non-GNU)
+        sage_spkg_install_perl_term_readline_gnu=yes
+      else
+        AC_MSG_RESULT(GNU)
+      fi
+     ],[sage_spkg_install_perl_term_readline_gnu=yes])
+])

m4/ax_prog_perl_modules.m4

@@ -0,0 +1,77 @@
+# ===========================================================================
+#   https://www.gnu.org/software/autoconf-archive/ax_prog_perl_modules.html
+# ===========================================================================
+#
+# SYNOPSIS
+#
+#   AX_PROG_PERL_MODULES([MODULES], [ACTION-IF-TRUE], [ACTION-IF-FALSE])
+#
+# DESCRIPTION
+#
+#   Checks to see if the given perl modules are available. If true the shell
+#   commands in ACTION-IF-TRUE are executed. If not the shell commands in
+#   ACTION-IF-FALSE are run. Note if $PERL is not set (for example by
+#   calling AC_CHECK_PROG, or AC_PATH_PROG), AC_CHECK_PROG(PERL, perl, perl)
+#   will be run.
+#
+#   MODULES is a space separated list of module names. To check for a
+#   minimum version of a module, append the version number to the module
+#   name, separated by an equals sign.
+#
+#   Example:
+#
+#     AX_PROG_PERL_MODULES( Text::Wrap Net::LDAP=1.0.3, ,
+#                           AC_MSG_WARN(Need some Perl modules)
+#
+# LICENSE
+#
+#   Copyright (c) 2009 Dean Povey <povey@wedgetail.com>
+#
+#   Copying and distribution of this file, with or without modification, are
+#   permitted in any medium without royalty provided the copyright notice
+#   and this notice are preserved. This file is offered as-is, without any
+#   warranty.
+
+#serial 8
+
+AU_ALIAS([AC_PROG_PERL_MODULES], [AX_PROG_PERL_MODULES])
+AC_DEFUN([AX_PROG_PERL_MODULES],[dnl
+
+m4_define([ax_perl_modules])
+m4_foreach([ax_perl_module], m4_split(m4_normalize([$1])),
+	  [
+	   m4_append([ax_perl_modules],
+		     [']m4_bpatsubst(ax_perl_module,=,[ ])[' ])
+          ])
+
+# Make sure we have perl
+if test -z "$PERL"; then
+AC_CHECK_PROG(PERL,perl,perl)
+fi
+
+if test "x$PERL" != x; then
+  ax_perl_modules_failed=0
+  for ax_perl_module in ax_perl_modules; do
+    AC_MSG_CHECKING(for perl module $ax_perl_module)
+
+    # Would be nice to log result here, but can't rely on autoconf internals
+    $PERL -e "use $ax_perl_module; exit" > /dev/null 2>&1
+    if test $? -ne 0; then
+      AC_MSG_RESULT(no);
+      ax_perl_modules_failed=1
+   else
+      AC_MSG_RESULT(ok);
+    fi
+  done
+
+  # Run optional shell commands
+  if test "$ax_perl_modules_failed" = 0; then
+    :
+    $2
+  else
+    :
+    $3
+  fi
+else
+  AC_MSG_WARN(could not find perl)
+fi])dnl