Build generate_ctest_json in try_compile()

rapids-cmake/test/detail/generate_resource_spec/CMakeLists.txt

@@ -0,0 +1,32 @@
+#=============================================================================
+# Copyright (c) 2024, NVIDIA CORPORATION.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#=============================================================================
+cmake_minimum_required(VERSION 3.23.1)
+project(generate_resource_spec ${lang})
+
+set(CMAKE_CUDA_ARCHITECTURES all)
+
+add_executable(generate_ctest_json generate_resource_spec.cpp)
+target_link_libraries(generate_ctest_json PRIVATE rt ${CMAKE_DL_LIBS})
+if(cuda_toolkit)
+  find_package(CUDAToolkit REQUIRED QUIET)
+  target_link_libraries(generate_ctest_json PRIVATE CUDA::cudart)
+  target_compile_definitions(generate_ctest_json PRIVATE HAVE_CUDA)
+endif()
+set_property(SOURCE generate_resource_spec.cpp PROPERTY LANGUAGE ${lang})
+
+add_custom_command(TARGET generate_ctest_json POST_BUILD
+                   COMMAND ${CMAKE_COMMAND} -E copy $<TARGET_FILE:generate_ctest_json>
+                           "${output_file}" COMMENT "Copying executable to destination")

rapids-cmake/test/detail/generate_resource_spec.cpp → rapids-cmake/test/detail/generate_resource_spec/generate_resource_spec.cpp

@@ -1,5 +1,5 @@
 /*
- * Copyright (c) 2022-2023, NVIDIA CORPORATION.
+ * Copyright (c) 2022-2024, NVIDIA CORPORATION.
  *
  * Licensed under the Apache License, Version 2.0 (the "License");
  * you may not use this file except in compliance with the License.

rapids-cmake/test/generate_resource_spec.cmake

@@ -62,32 +62,33 @@ function(rapids_test_generate_resource_spec DESTINATION filepath)
 ]=])
 
   include(${CMAKE_CURRENT_FUNCTION_LIST_DIR}/detail/default_names.cmake)
-  set(eval_file ${CMAKE_CURRENT_FUNCTION_LIST_DIR}/detail/generate_resource_spec.cpp)
   set(eval_exe ${PROJECT_BINARY_DIR}/rapids-cmake/${rapids_test_generate_exe_name})
   set(error_file ${PROJECT_BINARY_DIR}/rapids-cmake/detect_gpus.stderr.log)
 
   if(NOT EXISTS "${eval_exe}")
     find_package(CUDAToolkit QUIET)
     file(MAKE_DIRECTORY "${PROJECT_BINARY_DIR}/rapids-cmake/")
 
-    if(CUDAToolkit_FOUND)
-      set(cuda_include_options ${CUDAToolkit_INCLUDE_DIRS})
-      list(TRANSFORM cuda_include_options PREPEND "-I")
-      set(compile_options ${cuda_include_options} "-DHAVE_CUDA")
-    endif()
-    set(link_options ${CUDA_cudart_LIBRARY} -lpthread -lrt -ldl)
     set(compiler "${CMAKE_CXX_COMPILER}")
+    set(lang CXX)
     if(NOT DEFINED CMAKE_CXX_COMPILER)
       set(compiler "${CMAKE_CUDA_COMPILER}")
+      set(lang CUDA)
     endif()
 
-    execute_process(COMMAND "${compiler}" "${eval_file}" ${compile_options} ${link_options} -o
-                            "${eval_exe}" OUTPUT_VARIABLE compile_output
-                    ERROR_VARIABLE compile_output RESULT_VARIABLE result)
-
-    if(NOT result EQUAL 0)
+    try_compile(result PROJECT
+                generate_resource_spec SOURCE_DIR
+                "${CMAKE_CURRENT_FUNCTION_LIST_DIR}/detail/generate_resource_spec"
+                CMAKE_FLAGS "-DCMAKE_${lang}_COMPILER=${compiler}"
+                            "-DCUDAToolkit_ROOT=${CUDAToolkit_LIBRARY_ROOT}"
+                            "-Doutput_file=${eval_exe}"
+                            "-Dlang=${lang}"
+                            "-Dcuda_toolkit=${CUDAToolkit_FOUND}"
+                OUTPUT_VARIABLE compile_output)
+
+    if(NOT result)
       string(REPLACE "\n" "\n  " compile_output "${compile_output}")
-      message(FATAL_ERROR "rapids_test_generate_resource_spec failed to build detection executable.\nrapids_test_generate_resource_spec compile[${compiler} ${compile_options} ${link_options}] failure details are:\n  ${compile_output}"
+      message(FATAL_ERROR "rapids_test_generate_resource_spec failed to build detection executable.\nfailure details are:\n  ${compile_output}"
       )
     endif()
   endif()