Add is_internal_chrome_cleaner_build argument

All direct references to internal-only build artifacts and settings are now in
build files in chrome_cleaner_internal. The main build files pull in internal
build files only if is_internal_chrome_cleaner_build is set.

Renames targets that only have foo.h in sources to foo_header, which is more
clear.

Also converts GN source_set targets that only have deps to group targets.

R=proberge

Bug: 830892
Change-Id: I46a00e00f836a3f3654809797f4d8d9f4b4ed39b
Reviewed-on: https://chromium-review.googlesource.com/c/chromium/src/+/1536209
Commit-Queue: Joe Mason <joenotcharles@google.com>
Reviewed-by: proberge <proberge@chromium.org>
Cr-Commit-Position: refs/heads/master@{#643985}

chrome/chrome_cleaner/BUILD.gn

@@ -5,7 +5,7 @@
 import("//chrome/chrome_cleaner/chrome_cleaner_args.gni")
 import("//testing/test.gni")
 
-source_set("engine_definitions") {
+group("engine_definitions") {
   if (is_official_chrome_cleaner_build) {
     deps = [
       "//chrome_cleaner_internal:engine_definitions",
@@ -18,15 +18,43 @@ source_set("engine_definitions") {
   }
 }
 
+group("engine_target_factory") {
+  if (is_internal_chrome_cleaner_build) {
+    deps = [
+      "//chrome_cleaner_internal:engine_target_factory",
+    ]
+  } else {
+    deps = [
+      "//chrome/chrome_cleaner/engines/target:dummy_engine_delegate_factory",
+    ]
+  }
+}
+
+# This library should only be included in executable targets.
+static_library("other_executable_definitions") {
+  sources = [
+    "//chrome/chrome_cleaner/logging/other_logging_definitions.cc",
+    "//chrome/chrome_cleaner/settings/other_settings_definitions.cc",
+  ]
+
+  deps = [
+    "//chrome/chrome_cleaner/logging:logging_definitions",
+    "//chrome/chrome_cleaner/logging:noop_logging",
+    "//chrome/chrome_cleaner/proto:shared_pup_enums_proto",
+    "//chrome/chrome_cleaner/settings:settings_definitions",
+  ]
+}
+
 test("chrome_cleaner_unittests") {
   sources = [
+    "//chrome/chrome_cleaner/test/test_main.cc",
     "//chrome/chrome_cleaner/test/unit_test_override_command_line.cc",
-    "test/test_main.cc",
   ]
 
   deps = [
     # Dependencies of the test harness.
     ":engine_definitions",
+    ":engine_target_factory",
     ":other_executable_definitions",
     "//base",
     "//base/test:test_support",
@@ -35,12 +63,10 @@ test("chrome_cleaner_unittests") {
     "//chrome/chrome_cleaner/logging:common",
     "//chrome/chrome_cleaner/os:cleaner_os",
     "//chrome/chrome_cleaner/os:common_os",
-    "//chrome/chrome_cleaner/os:common_os",
     "//chrome/chrome_cleaner/pup_data:pup_data_base",
     "//chrome/chrome_cleaner/settings:settings_types",
     "//chrome/chrome_cleaner/test:test_pup_data",
     "//chrome/chrome_cleaner/test:test_util",
-    "//chrome/chrome_cleaner/test:test_uws_catalog",
     "//sandbox/win:sandbox",
     "//testing/gtest",
 
@@ -70,19 +96,8 @@ test("chrome_cleaner_unittests") {
     "//chrome/chrome_cleaner/ui:unittest_sources",
     "//chrome/chrome_cleaner/zip_archiver:unittest_sources",
   ]
-}
 
-# This library should only be included in executable targets.
-static_library("other_executable_definitions") {
-  sources = [
-    "//chrome/chrome_cleaner/logging/other_logging_definitions.cc",
-    "//chrome/chrome_cleaner/settings/other_settings_definitions.cc",
-  ]
-
-  deps = [
-    "//chrome/chrome_cleaner/logging:logging_definitions",
-    "//chrome/chrome_cleaner/logging:noop_logging",
-    "//chrome/chrome_cleaner/proto:shared_pup_enums_proto",
-    "//chrome/chrome_cleaner/settings:settings_definitions",
-  ]
+  if (is_internal_chrome_cleaner_build) {
+    deps += [ "//chrome_cleaner_internal:unittest_sources" ]
+  }
 }

chrome/chrome_cleaner/chrome_cleaner_args.gni

@@ -3,7 +3,15 @@
 # found in the LICENSE file.
 
 declare_args() {
+  # If this is true, the build will look for extra Google-internal resources.
+  is_internal_chrome_cleaner_build = false
+
   # If this is true, builds an official release of the Chrome Cleanup Tool
-  # (requires extra Google-internal resources).
+  # (requires is_internal_chrome_cleaner_build=true).
   is_official_chrome_cleaner_build = false
 }
+
+if (is_official_chrome_cleaner_build) {
+  assert(is_internal_chrome_cleaner_build,
+         "Official build needs internal resources")
+}

chrome/chrome_cleaner/crash/BUILD.gn

@@ -30,7 +30,7 @@ source_set("crashpad_lib") {
     "//chrome/chrome_cleaner/constants:common_strings",
     "//chrome/chrome_cleaner/logging:common",
     "//chrome/chrome_cleaner/os:common_os",
-    "//chrome/chrome_cleaner/settings:engine_settings",
+    "//chrome/chrome_cleaner/settings:engine_settings_header",
     "//chrome/chrome_cleaner/settings:settings",
     "//chrome/chrome_cleaner/settings:settings_types",
     "//third_party/crashpad/crashpad/client",

chrome/chrome_cleaner/engines/broker/BUILD.gn

@@ -54,10 +54,7 @@ source_set("common") {
   if (!is_official_chrome_cleaner_build) {
     # Unofficial builds allow loading some target-only code in the broker, for
     # testing.
-    deps += [
-      "//chrome/chrome_cleaner/engines/target:common",
-      "//chrome/chrome_cleaner/engines/target:engine_delegate_factory",
-    ]
+    deps += [ "//chrome/chrome_cleaner/engines/target:common" ]
   }
 }
 
@@ -86,7 +83,7 @@ source_set("cleaner_sandbox_interface") {
     "//chrome/chrome_cleaner/chrome_utils:chrome_util_lib",
     "//chrome/chrome_cleaner/constants:common_strings",
     "//chrome/chrome_cleaner/engines/common:common",
-    "//chrome/chrome_cleaner/engines/common:resources",
+    "//chrome/chrome_cleaner/engines/common:resources_header",
     "//chrome/chrome_cleaner/os:cleaner_os",
     "//chrome/chrome_cleaner/os:common_os",
     "//chrome/chrome_cleaner/pup_data:pup_data_base",

chrome/chrome_cleaner/engines/common/BUILD.gn

@@ -13,15 +13,15 @@ source_set("common") {
   ]
 
   deps = [
-    ":resources",
+    ":resources_header",
     "//base",
     "//chrome/chrome_cleaner/os:common_os",
     "//chrome/chrome_cleaner/strings",
     "//sandbox/win:sandbox",
   ]
 }
 
-source_set("resources") {
+source_set("resources_header") {
   sources = [
     "engine_resources.h",
   ]
@@ -41,7 +41,7 @@ source_set("dummy_engine_resources") {
   ]
 
   deps = [
-    ":resources",
+    ":resources_header",
     "//chrome/chrome_cleaner/pup_data:pup_data_base",
     "//chrome/chrome_cleaner/test:test_uws_catalog",
   ]

chrome/chrome_cleaner/engines/controllers/BUILD.gn

@@ -112,7 +112,7 @@ source_set("engine_cleaner_lib") {
     "//chrome/chrome_cleaner/engines/broker:cleaner_sandbox_interface",
     "//chrome/chrome_cleaner/engines/broker:common",
     "//chrome/chrome_cleaner/engines/common:common",
-    "//chrome/chrome_cleaner/engines/common:resources",
+    "//chrome/chrome_cleaner/engines/common:resources_header",
     "//chrome/chrome_cleaner/ipc:chrome_prompt_ipc",
     "//chrome/chrome_cleaner/ipc:mojo_task_runner",
     "//chrome/chrome_cleaner/ipc:sandbox",
@@ -190,7 +190,7 @@ source_set("unittest_sources") {
     "//chrome/chrome_cleaner/test:test_util",
     "//chrome/chrome_cleaner/test:test_uws_catalog",
     "//chrome/chrome_cleaner/ui:cleaner_ui",
-    "//components/chrome_cleaner/public/interfaces:interfaces",
+    "//components/chrome_cleaner/public/interfaces",
     "//components/chrome_cleaner/test:test_name_helper",
     "//sandbox/win:sandbox",
     "//testing/gmock",

chrome/chrome_cleaner/engines/target/BUILD.gn

@@ -2,8 +2,6 @@
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
-import("//chrome/chrome_cleaner/chrome_cleaner_args.gni")
-
 source_set("common") {
   sources = [
     "cleaner_engine_requests_proxy.cc",
@@ -14,7 +12,6 @@ source_set("common") {
     "engine_commands_impl.h",
     "engine_delegate.cc",
     "engine_delegate.h",
-    "engine_delegate_factory.h",
     "engine_file_requests_proxy.cc",
     "engine_file_requests_proxy.h",
     "engine_requests_proxy.cc",
@@ -34,7 +31,7 @@ source_set("common") {
     "//chrome/chrome_cleaner/constants:common_strings",
     "//chrome/chrome_cleaner/crash:crash_keys",
     "//chrome/chrome_cleaner/engines/common:common",
-    "//chrome/chrome_cleaner/engines/common:resources",
+    "//chrome/chrome_cleaner/engines/common:resources_header",
     "//chrome/chrome_cleaner/interfaces:engine_sandbox_interface",
     "//chrome/chrome_cleaner/ipc:mojo_task_runner",
     "//chrome/chrome_cleaner/ipc:sandbox",
@@ -49,27 +46,31 @@ source_set("common") {
   ]
 }
 
-source_set("dummy_engine_delegate_factory") {
+source_set("engine_delegate_factory_header") {
   sources = [
-    "dummy_engine_delegate_factory.cc",
+    "engine_delegate_factory.h",
   ]
 
   deps = [
     ":common",
-    ":test_engine_delegate",
+    "//base",
+  ]
+
+  public_deps = [
+    "//chrome/chrome_cleaner/logging/proto:shared_data_proto",
   ]
 }
 
-source_set("engine_delegate_factory") {
-  if (is_official_chrome_cleaner_build) {
-    deps = [
-      "//chrome_cleaner_internal:engine_delegate_factory",
-    ]
-  } else {
-    deps = [
-      ":dummy_engine_delegate_factory",
-    ]
-  }
+source_set("dummy_engine_delegate_factory") {
+  sources = [
+    "dummy_engine_delegate_factory.cc",
+  ]
+
+  deps = [
+    ":engine_delegate_factory_header",
+    ":test_engine_delegate",
+    "//base",
+  ]
 }
 
 source_set("test_engine_delegate") {
@@ -103,7 +104,7 @@ source_set("test_support") {
     "//chrome/chrome_cleaner/engines/broker:common",
     "//chrome/chrome_cleaner/engines/broker:interface_metadata_observer",
     "//chrome/chrome_cleaner/engines/common:common",
-    "//chrome/chrome_cleaner/engines/common:resources",
+    "//chrome/chrome_cleaner/engines/common:resources_header",
     "//chrome/chrome_cleaner/ipc:ipc_test_util",
     "//chrome/chrome_cleaner/os:cleaner_os",
     "//chrome/chrome_cleaner/os:common_os",
@@ -128,7 +129,7 @@ source_set("unittest_sources") {
     "//base/test:test_config",
     "//base/test:test_support",
     "//chrome/chrome_cleaner/engines/common:common",
-    "//chrome/chrome_cleaner/engines/common:resources",
+    "//chrome/chrome_cleaner/engines/common:resources_header",
     "//chrome/chrome_cleaner/ipc:ipc_test_util",
     "//chrome/chrome_cleaner/ipc:mojo_task_runner",
     "//chrome/chrome_cleaner/os:cleaner_os",

chrome/chrome_cleaner/ipc/BUILD.gn

@@ -43,7 +43,7 @@ source_set("sandbox") {
     "//chrome/chrome_cleaner/constants:common_strings",
     "//chrome/chrome_cleaner/crash:crashpad_lib",
     "//chrome/chrome_cleaner/os:common_os",
-    "//chrome/chrome_cleaner/settings:engine_settings",
+    "//chrome/chrome_cleaner/settings:engine_settings_header",
     "//chrome/chrome_cleaner/settings:settings",
     "//chrome/chrome_cleaner/settings:settings_types",
     "//components/chrome_cleaner/public/constants:constants",

chrome/chrome_cleaner/logging/BUILD.gn

@@ -45,7 +45,7 @@ source_set("common") {
     "//chrome/chrome_cleaner/os:common_os",
     "//chrome/chrome_cleaner/proto:shared_pup_enums_proto",
     "//chrome/chrome_cleaner/pup_data:pup_data_base",
-    "//chrome/chrome_cleaner/settings:engine_settings",
+    "//chrome/chrome_cleaner/settings:engine_settings_header",
     "//chrome/chrome_cleaner/settings:settings",
     "//chrome/chrome_cleaner/settings:settings_types",
     "//components/chrome_cleaner/public/constants:constants",
@@ -85,6 +85,18 @@ source_set("dummy_api_keys") {
   ]
 }
 
+group("api_keys") {
+  if (is_internal_chrome_cleaner_build) {
+    deps = [
+      "//chrome/chrome_cleaner_internal/logging:api_keys",
+    ]
+  } else {
+    deps = [
+      ":dummy_api_keys",
+    ]
+  }
+}
+
 static_library("cleaner_logging") {
   sources = [
     "cleaner_logging_service.cc",
@@ -96,6 +108,7 @@ static_library("cleaner_logging") {
   ]
 
   deps = [
+    ":api_keys",
     ":api_keys_header",
     "//base",
     "//chrome/chrome_cleaner/chrome_utils:chrome_util_lib",
@@ -113,12 +126,6 @@ static_library("cleaner_logging") {
     "//components/chrome_cleaner/public/constants:constants",
   ]
 
-  if (is_official_chrome_cleaner_build) {
-    deps += [ "//chrome_cleaner_internal/logging:api_keys" ]
-  } else {
-    deps += [ ":dummy_api_keys" ]
-  }
-
   public_deps = [
     ":common",
   ]
@@ -131,6 +138,7 @@ static_library("reporter_logging") {
   ]
 
   deps = [
+    ":api_keys",
     ":api_keys_header",
     "//base",
     "//chrome/chrome_cleaner/chrome_utils:chrome_util_lib",
@@ -145,12 +153,6 @@ static_library("reporter_logging") {
     "//components/chrome_cleaner/public/constants:constants",
   ]
 
-  if (is_official_chrome_cleaner_build) {
-    deps += [ "//chrome_cleaner_internal/logging:api_keys" ]
-  } else {
-    deps += [ ":dummy_api_keys" ]
-  }
-
   public_deps = [
     ":common",
   ]

chrome/chrome_cleaner/settings/BUILD.gn

@@ -2,7 +2,7 @@
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
-source_set("engine_settings") {
+source_set("engine_settings_header") {
   sources = [
     "engine_settings.h",
   ]
@@ -19,7 +19,7 @@ source_set("dummy_engine_settings") {
   ]
 
   deps = [
-    ":engine_settings",
+    ":engine_settings_header",
   ]
 }
 
@@ -43,7 +43,7 @@ source_set("settings") {
   ]
 
   public_deps = [
-    ":engine_settings",
+    ":engine_settings_header",
     ":settings_definitions",
     "//chrome/chrome_cleaner/logging/proto:shared_data_proto",
     "//mojo/public/cpp/platform",
@@ -88,7 +88,7 @@ source_set("unittest_sources") {
   ]
 
   deps = [
-    ":engine_settings",
+    ":engine_settings_header",
     ":settings",
     ":settings_definitions",
     "//base:base",

chrome/chrome_cleaner/test/BUILD.gn

@@ -2,6 +2,12 @@
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
+import("//chrome/chrome_cleaner/chrome_cleaner_args.gni")
+
+if (is_internal_chrome_cleaner_build) {
+  import("//chrome/chrome_cleaner_internal/internal_test_args.gni")
+}
+
 # Targets used by tests.
 
 shared_library("empty_dll") {