❓ [Question] Problem with cudnn dependency when compiling plugins on windows?

[pepinu]

❓ Question

I am trying to compile a windows dll for torch-tensorRT, however I get the following traceback:

ERROR: C:/users/48698/source/libraries/torch-tensorrt-1.0.0/core/plugins/BUILD:10:11: Compiling core/plugins/register_plugins.cpp failed: undeclared inclusion(s) in rule '//core/plugins:torch_tensorrt_plugins':
this rule is missing dependency declarations for the following files included by 'core/plugins/register_plugins.cpp':
'external/cuda/cudnn.h'
'external/cuda/cudnn_version.h'
'external/cuda/cudnn_ops_infer.h'
'external/cuda/cudnn_ops_train.h'
'external/cuda/cudnn_adv_infer.h'
'external/cuda/cudnn_adv_train.h'
'external/cuda/cudnn_cnn_infer.h'
'external/cuda/cudnn_cnn_train.h'
'external/cuda/cudnn_backend.h'

which is weird cause I do have the cudnn included, and can find the files under the C:\Program Files\NVIDIA GPU Computing Toolkit\CUDA\v11.6 path

I am new to Bazel, is there another way I could link those?

What you have already tried

Followed this guide: #856 to a t. I think I am linking cudnn in a weird way?

Environment

Build information about Torch-TensorRT can be found by turning on debug messages

• PyTorch Version (e.g., 1.0): 1.11.0
• OS (e.g., Linux): windows
• How you installed PyTorch (conda, pip, libtorch, source): libtorch
• Build command you used (if compiling from source):
• Are you using local sources or building from archives: local
• Python version: 3.9
• CUDA version: 11.6
• GPU models and configuration: 3070
• Any other relevant information:

Additional context

My torch-tensorrt-1.0.0/core/plugins/BUILD is as follows:

config_setting(
    name = "use_pre_cxx11_abi",
    values = {
        "define": "abi=pre_cxx11_abi",
    }
)

cc_library(
    name = "torch_tensorrt_plugins",
    hdrs = [
        "impl/interpolate_plugin.h",
        "impl/normalize_plugin.h",
        "plugins.h",

    ],
    srcs = [
        "impl/interpolate_plugin.cpp",
        "impl/normalize_plugin.cpp",
        "register_plugins.cpp",
    ],
    deps = [
        "@tensorrt//:nvinfer",
        "@tensorrt//:nvinferplugin",
        "//core/util:prelude",
    ] + select({
        ":use_pre_cxx11_abi":  ["@libtorch_pre_cxx11_abi//:libtorch"],
        "//conditions:default":  ["@libtorch//:libtorch"],
    }),
    alwayslink = True,
    copts = [
        "-pthread"
    ],
    linkopts = [
        "-lpthread",
    ]
)

load("@rules_pkg//:pkg.bzl", "pkg_tar")

pkg_tar(
    name = "include",
    package_dir = "core/plugins/",
    srcs = ["plugins.h"],
)

pkg_tar(
    name = "impl_include",
    package_dir = "core/plugins/impl",
    srcs = ["impl/interpolate_plugin.h",
            "impl/normalize_plugin.h"],
)


I could attach more build files if needed, but everything apart from the paths is the same as in the referenced issue.

[narendasan]

What does your WORKSPACE file and third_party/cudnn/BUILD files look like?

[pepinu]

WORKSPACE FILE:

workspace(name = "Torch-TensorRT")

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")
load("@bazel_tools//tools/build_defs/repo:git.bzl", "git_repository")

http_archive(
    name = "rules_python",
    sha256 = "778197e26c5fbeb07ac2a2c5ae405b30f6cb7ad1f5510ea6fdac03bded96cc6f",
    url = "https://github.com/bazelbuild/rules_python/releases/download/0.2.0/rules_python-0.2.0.tar.gz",
)

load("@rules_python//python:pip.bzl", "pip_install")

http_archive(
    name = "rules_pkg",
    sha256 = "038f1caa773a7e35b3663865ffb003169c6a71dc995e39bf4815792f385d837d",
    urls = [
        "https://mirror.bazel.build/github.com/bazelbuild/rules_pkg/releases/download/0.4.0/rules_pkg-0.4.0.tar.gz",
        "https://github.com/bazelbuild/rules_pkg/releases/download/0.4.0/rules_pkg-0.4.0.tar.gz",
    ],
)

load("@rules_pkg//:deps.bzl", "rules_pkg_dependencies")

rules_pkg_dependencies()

git_repository(
    name = "googletest",
    commit = "703bd9caab50b139428cea1aaff9974ebee5742e",
    remote = "https://github.com/google/googletest",
    shallow_since = "1570114335 -0400",
)

# External dependency for torch_tensorrt if you already have precompiled binaries.
#local_repository(
#    name = "torch_tensorrt",
#    path = "/opt/conda/lib/python3.8/site-packages/torch_tensorrt"
#)

# CUDA should be installed on the system locally
new_local_repository(
    name = "cuda",
    build_file = "@//third_party/cuda:BUILD",
    path = "C:/Program Files/NVIDIA GPU Computing Toolkit/CUDA/v11.6",
)

new_local_repository(
    name = "cublas",
    build_file = "@//third_party/cublas:BUILD",
    path =  "C:/Program Files/NVIDIA GPU Computing Toolkit/CUDA/v11.6",
)
#############################################################################################################
# Tarballs and fetched dependencies (default - use in cases when building from precompiled bin and tarballs)
#############################################################################################################

new_local_repository(
    name = "libtorch",
    path = "C:/Users/48698/source/libraries/pytorch/libtorch-win-shared-with-deps-1.10.2+cu113/libtorch",
    # path = "C:/Users/myUser/appdata/local/packages/pythonsoftwarefoundation.python.3.9_qbz5n2kfra8p0/localcache/local-packages/python39/site-packages/torch",
    build_file = "third_party/libtorch/BUILD"
)

new_local_repository(
    name = "libtorch_pre_cxx11_abi",
    path = "C:/Users/48698/source/libraries/pytorch/libtorch-win-shared-with-deps-1.10.2+cu113/libtorch",
    # path = "C:/Users/myUser/appdata/local/packages/pythonsoftwarefoundation.python.3.9_qbz5n2kfra8p0/localcache/local-packages/python39/site-packages/torch",
    build_file = "third_party/libtorch/BUILD"
)

new_local_repository(
    name = "cudnn",
    path = "C:/Program Files/NVIDIA GPU Computing Toolkit/CUDA/v11.6",
    build_file = "@//third_party/cudnn/local:BUILD"
)

new_local_repository(
   name = "tensorrt",
   path = "C:/Users/48698/source/libraries/tensorrt",
   build_file = "@//third_party/tensorrt/local:BUILD"
)
####################################################################################
# Locally installed dependencies (use in cases of custom dependencies or aarch64)
####################################################################################

# NOTE: In the case you are using just the pre-cxx11-abi path or just the cxx11 abi path
# with your local libtorch, just point deps at the same path to satisfy bazel.

# NOTE: NVIDIA's aarch64 PyTorch (python) wheel file uses the CXX11 ABI unlike PyTorch's standard
# x86_64 python distribution. If using NVIDIA's version just point to the root of the package
# for both versions here and do not use --config=pre-cxx11-abi

#new_local_repository(
#    name = "libtorch",
#    path = "/usr/local/lib/python3.6/dist-packages/torch",
#    build_file = "third_party/libtorch/BUILD"
#)

#new_local_repository(
#    name = "libtorch_pre_cxx11_abi",
#    path = "/usr/local/lib/python3.6/dist-packages/torch",
#    build_file = "third_party/libtorch/BUILD"
#)

#new_local_repository(
#    name = "cudnn",
#    path = "/usr/",
#    build_file = "@//third_party/cudnn/local:BUILD"
#)

#new_local_repository(
#   name = "tensorrt",
#   path = "/usr/",
#   build_file = "@//third_party/tensorrt/local:BUILD"
#)

third_party/cudnn/local/BUILD:

package(default_visibility = ["//visibility:public"])

config_setting(
    name = "aarch64_linux",
    constraint_values = [
        "@platforms//cpu:aarch64",
        "@platforms//os:linux",
    ],
)

config_setting(
    name = "windows",
    constraint_values = [
        "@platforms//os:windows",
    ],
)

cc_library(
    name = "cudnn_headers",
    hdrs = ["include/cudnn.h"] + glob([
        "include/cudnn+.h",
        "include/cudnn_*.h",
    ]),
    includes = ["include/"],
    visibility = ["//visibility:private"],
)

cc_import(
    name = "cudnn_lib",
    shared_library = select({
        ":aarch64_linux": "lib/aarch64-linux-gnu/libcudnn.so",
        ":windows": "bin/cudnn64_8.dll",  #Need to configure specific version for windows
        "//conditions:default": "lib/x86_64-linux-gnu/libcudnn.so",
    }),
    visibility = ["//visibility:private"],
)

cc_library(
    name = "cudnn",
    visibility = ["//visibility:public"],
    deps = [
        "cudnn_headers",
        "cudnn_lib",
    ],
)

third_party/cudnn/archive/BUILD:

package(default_visibility = ["//visibility:public"])

cc_library(
    name = "cudnn_headers",
    hdrs = glob(["include/cudnn*.h"]),
    includes = ["include/"],
    visibility = ["//visibility:private"],
)

cc_import(
    name = "cudnn_lib",
    shared_library = "lib64/libcudnn.so",
    visibility = ["//visibility:private"],
)

cc_library(
    name = "cudnn",
    visibility = ["//visibility:public"],
    deps = [
        "cudnn_headers",
        "cudnn_lib",
    ],
)

As for the third_party/cudnn/BUILD - It seems I do not have such a file 😞

One thing worth mentioning, I've installed CUDNN through Nvidia installer which put it in C:\Program Files\NVIDIA\CUDNN\v8.3 path, I've tried setting this path in the workspace but to no avail, I copied all files to "C:/Program Files/NVIDIA GPU Computing Toolkit/CUDA/v11.6". so it looked like in #856.

I can share more build files/traces if needed.

[narendasan]

Yeah sorry, the file I was interested in was third_party/cudnn/local/BUILD. This seems mostly fine from a glance. I assume you installed cudnn via the exe and not the zip right? Is the path for the cudnn headers something like C:\Program Files\NVIDIA GPU Computing Toolkit\CUDA\v11.6\cuda\include\cudnn.h? I think what is happening is that maybe the cudnn and cuda files are getting mixed up by bazel if the installer overlays them. This is what the external/cuda/cudnn* signals to me because I would expect bazel to pull in cudnn resources under external/cudnn.

Perhaps the header inclusion rules in third_party/cuda/BUILD need to be more specific so cudnn headers don't get globbed with cuda headers

[pepinu]

Yeah, I used .exe for installation. I will investigate this glob mixup and report back

[pepinu]

Well, I've tried many things, from changing CUDNN folder to the same cuda has, moving headers to the cuda folder, moving them to different folders so it would catch it but to no avail. I think I don't understand how the bazel loads these headers, and where/how to manipulate the rules to make them attached to the build.

The error is persistent and the same, that no dependencies were found for this:

this rule is missing dependency declarations for the following files included by 'core/plugins/register_plugins.cpp':
  'external/cuda/cudnn.h'
  'external/cuda/cudnn_version.h'
  'external/cuda/cudnn_ops_infer.h'
  'external/cuda/cudnn_ops_train.h'
  'external/cuda/cudnn_adv_infer.h'
  'external/cuda/cudnn_adv_train.h'
  'external/cuda/cudnn_cnn_infer.h'
  'external/cuda/cudnn_cnn_train.h'
  'external/cuda/cudnn_backend.h'

I guess I understand how bazel links files here - should it be external/cudnn/cudnn.h, so the /cuda/ part is problematic, or it is pointed to correctly, but the files are not copied, hence cuda/cudnn* does not exist?

Can't I move these headers to some external/cuda folder? Like force it in one of the BUILD files?

I've also tried to add a dependency in core/plugins/BUILD to attach cudnn, but it does not help with the error 😢

Currently I've updated WORKSPACE file to point to the original CUDNN folder as follows:

workspace(name = "Torch-TensorRT")

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")
load("@bazel_tools//tools/build_defs/repo:git.bzl", "git_repository")

http_archive(
    name = "rules_python",
    sha256 = "778197e26c5fbeb07ac2a2c5ae405b30f6cb7ad1f5510ea6fdac03bded96cc6f",
    url = "https://github.com/bazelbuild/rules_python/releases/download/0.2.0/rules_python-0.2.0.tar.gz",
)

load("@rules_python//python:pip.bzl", "pip_install")

http_archive(
    name = "rules_pkg",
    sha256 = "038f1caa773a7e35b3663865ffb003169c6a71dc995e39bf4815792f385d837d",
    urls = [
        "https://mirror.bazel.build/github.com/bazelbuild/rules_pkg/releases/download/0.4.0/rules_pkg-0.4.0.tar.gz",
        "https://github.com/bazelbuild/rules_pkg/releases/download/0.4.0/rules_pkg-0.4.0.tar.gz",
    ],
)

load("@rules_pkg//:deps.bzl", "rules_pkg_dependencies")

rules_pkg_dependencies()

git_repository(
    name = "googletest",
    commit = "703bd9caab50b139428cea1aaff9974ebee5742e",
    remote = "https://github.com/google/googletest",
    shallow_since = "1570114335 -0400",
)

# External dependency for torch_tensorrt if you already have precompiled binaries.
#local_repository(
#    name = "torch_tensorrt",
#    path = "/opt/conda/lib/python3.8/site-packages/torch_tensorrt"
#)

# CUDA should be installed on the system locally
new_local_repository(
    name = "cuda",
    build_file = "@//third_party/cuda:BUILD",
    path = "C:/Program Files/NVIDIA GPU Computing Toolkit/CUDA/v11.6",
)

new_local_repository(
    name = "cublas",
    build_file = "@//third_party/cublas:BUILD",
    path =  "C:/Program Files/NVIDIA GPU Computing Toolkit/CUDA/v11.6",
)
#############################################################################################################
# Tarballs and fetched dependencies (default - use in cases when building from precompiled bin and tarballs)
#############################################################################################################

new_local_repository(
    name = "libtorch",
    path = "C:/Users/48698/source/libraries/pytorch/libtorch-win-shared-with-deps-1.10.2+cu113/libtorch",
    # path = "C:/Users/myUser/appdata/local/packages/pythonsoftwarefoundation.python.3.9_qbz5n2kfra8p0/localcache/local-packages/python39/site-packages/torch",
    build_file = "third_party/libtorch/BUILD"
)

new_local_repository(
    name = "libtorch_pre_cxx11_abi",
    path = "C:/Users/48698/source/libraries/pytorch/libtorch-win-shared-with-deps-1.10.2+cu113/libtorch",
    # path = "C:/Users/myUser/appdata/local/packages/pythonsoftwarefoundation.python.3.9_qbz5n2kfra8p0/localcache/local-packages/python39/site-packages/torch",
    build_file = "third_party/libtorch/BUILD"
)

new_local_repository(
    name = "cudnn",
    path = "C:/Program Files/NVIDIA/CUDNN/v8.3",
    build_file = "@//third_party/cudnn/local:BUILD"
)

new_local_repository(
   name = "tensorrt",
   path = "C:/Users/48698/source/libraries/tensorrt",
   build_file = "@//third_party/tensorrt/local:BUILD"
)

Here's third_party/cuda/BUILD:

package(default_visibility = ["//visibility:public"])

config_setting(
    name = "windows",
    constraint_values = [
        "@platforms//os:windows",
    ],
)

cc_library(
    name = "cudart",
    srcs = select({
        ":windows": [
            "lib/x64/cudart.lib",
        ],
        "//conditions:default": [
            "lib64/libcudart.so",
        ],
    }),
    hdrs = glob([
        "include/**/*.h",
        "include/**/*.hpp",
        "include/**/*.inl",
    ]),
    includes = ["include/"],
)

cc_library(
    name = "nvToolsExt",
    srcs = select({
        ":windows": [
            "bin/nvToolsExt64_1.dll",
        ],
        "//conditions:default": [
            "lib64/libnvToolsExt.so.1",
        ],
    }),
)

cc_library(
    name = "cuda",
    srcs = select({
        ":windows": [
            "bin/*.dll",
        ],
        "//conditions:default": glob([
            "lib64/**/lib*.so",
        ]),
    }),
    hdrs = glob([
        "include/**/*.h",
        "include/**/*.hpp",
        "include/**/*.inl",
    ]),
    includes = ["include/"],
    linkopts = ["-Wl,-rpath,lib/"],
)

cc_library(
    name = "cublas",
    srcs = select({
        ":windows": glob([
            "lib/x64/cublas.lib",
        ]),
        "//conditions:default": glob([
            "lib64/**/*libcublas.so",
        ]),
    }),
    hdrs = glob([
        "include/**/*cublas*.h",
        "include/**/*.hpp",
        "include/**/*.inl",
    ]),
    includes = ["include/"],
    linkopts = ["-Wl,-rpath,lib/"],
)

and core/plugins/BUILD:

package(default_visibility = ["//visibility:public"])

config_setting(
    name = "use_pre_cxx11_abi",
    values = {
        "define": "abi=pre_cxx11_abi",
    }
)

cc_library(
    name = "torch_tensorrt_plugins",
    hdrs = [
        "impl/interpolate_plugin.h",
        "impl/normalize_plugin.h",
        "plugins.h",

    ],
    srcs = [
        "impl/interpolate_plugin.cpp",
        "impl/normalize_plugin.cpp",
        "register_plugins.cpp",
    ],
    deps = [
        "@tensorrt//:nvinfer",
        "@tensorrt//:nvinferplugin",
        "@cudnn",
        "//core/util:prelude",
    ] + select({
        ":use_pre_cxx11_abi":  ["@libtorch_pre_cxx11_abi//:libtorch"],
        "//conditions:default":  ["@libtorch//:libtorch"],
    }),
    alwayslink = True,
    copts = [
        "-pthread"
    ],
    linkopts = [
        "-lpthread",
    ]
)

load("@rules_pkg//:pkg.bzl", "pkg_tar")

pkg_tar(
    name = "include",
    package_dir = "core/plugins/",
    srcs = ["plugins.h"],
)

pkg_tar(
    name = "impl_include",
    package_dir = "core/plugins/impl",
    srcs = ["impl/interpolate_plugin.h",
            "impl/normalize_plugin.h"],
)

[narendasan]

I guess I understand how bazel links files here - should it be external/cudnn/cudnn.h, so the /cuda/ part is problematic, or it is pointed to correctly, but the files are not copied, hence cuda/cudnn* does not exist?

I would expect it to be external/cudnn/cudnn.h, the external/cuda/ implies that cuda BUILD file is bringing it in and is confusing bazel at least from what I can tell.

Perhaps something to try is to modify the third_party/cuda/BUILD glob rules to exclude cudnn headers explicitly (https://bazel.build/reference/be/functions#glob). Something like whats below for all package entries in the BUILD file

cc_library(
    name = "cuda",
    srcs = select({
        ":windows": [
            "bin/*.dll",
        ],
        "//conditions:default": glob([
            "lib64/**/lib*.so",
        ]),
    }),
    hdrs = glob([
        "include/**/*.h",
        "include/**/*.hpp",
        "include/**/*.inl",
    ],
    exclude=[
         "include/**/*cudnn*.h"
    ]),
    includes = ["include/"],
    linkopts = ["-Wl,-rpath,lib/"],
)

Alternatively what is happening is that the includes argument of cuda targets is what is causing the issue. The includes argument is equivalent to -I for gcc, i.e. a search directory for headers. So bazel might be detecting that headers from C:/Program Files/NVIDIA GPU Computing Toolkit/CUDA/v11.6/include satisfy cudnn.h used in the plugin source code but has not been declared by a target. A test for this might be to remove the includes argument from the cuda BUILD targets and see what happens (though this might break other things). If this is the case maybe what might be best is to do what we do for cublas where there is a linux location which is part of the CUDA toolkit repo and for jetson there is a separate location and build file and we condition on platform to choose where the dependency comes from. So in this case maybe adding a cuda/cudnn target might be the best next step.

Hopefully one of these at least changes the error so its clearer what the next step is.

Finally have you tried using http_archive to include a zip file and let bazel unpack and set it up similar to our defaults for linux? (https://bazel.build/rules/lib/repo/http?hl=en) We set this as the default because its more likely to work out of the box (though if you have a specific system configuration, its understandable why this isnt an option).

[pepinu]

Thanks for the suggestions. I've tried to exclude the headers as mentioned but to no avail.
I've downloaded the repo once again just to be sure I did the steps correctly from the scratch and went with the http_archive() as bazel would install cudnn
I thought the best and simplest way would be to go with the http_archive which I implemented, but the error stayed the same, although with some DEBUG info connected to sha256 not being passed as an argument in the http_archive I think:

C:\Users\48698\source\libraries\new\Torch-TensorRT-1.0.0\Torch-TensorRT-1.0.0>bazel build //:libtorchtrt --compilation_mode opt --python_path="C:/Users/48698/anaconda3/python.exe"
DEBUG: Rule 'cudnn' indicated that a canonical reproducible form can be obtained by modifying arguments sha256 = "9e36eef803f1cf9ab24846dc133a3014fdc548775ee29073e8466d415957a1c0"
DEBUG: Repository cudnn instantiated at:
  C:/users/48698/source/libraries/new/torch-tensorrt-1.0.0/torch-tensorrt-1.0.0/WORKSPACE:69:13: in <toplevel>
Repository rule http_archive defined at:
  C:/users/48698/_bazel_48698/dw6ogrhx/external/bazel_tools/tools/build_defs/repo/http.bzl:353:31: in <toplevel>
INFO: Analyzed target //:libtorchtrt (1 packages loaded, 31 targets configured).
INFO: Found 1 target...
ERROR: C:/users/48698/source/libraries/new/torch-tensorrt-1.0.0/torch-tensorrt-1.0.0/core/plugins/BUILD:10:11: Compiling core/plugins/register_plugins.cpp failed: undeclared inclusion(s) in rule '//core/plugins:torch_tensorrt_plugins':
this rule is missing dependency declarations for the following files included by 'core/plugins/register_plugins.cpp':
  'external/cuda/cudnn.h'
  'external/cuda/cudnn_version.h'
  'external/cuda/cudnn_ops_infer.h'
  'external/cuda/cudnn_ops_train.h'
  'external/cuda/cudnn_adv_infer.h'
  'external/cuda/cudnn_adv_train.h'
  'external/cuda/cudnn_cnn_infer.h'
  'external/cuda/cudnn_cnn_train.h'
  'external/cuda/cudnn_backend.h'

I attach my new WORKSPACE file below:

workspace(name = "Torch-TensorRT")

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")
load("@bazel_tools//tools/build_defs/repo:git.bzl", "git_repository")

http_archive(
    name = "rules_python",
    sha256 = "778197e26c5fbeb07ac2a2c5ae405b30f6cb7ad1f5510ea6fdac03bded96cc6f",
    url = "https://github.com/bazelbuild/rules_python/releases/download/0.2.0/rules_python-0.2.0.tar.gz",
)

load("@rules_python//python:pip.bzl", "pip_install")

http_archive(
    name = "rules_pkg",
    sha256 = "038f1caa773a7e35b3663865ffb003169c6a71dc995e39bf4815792f385d837d",
    urls = [
        "https://mirror.bazel.build/github.com/bazelbuild/rules_pkg/releases/download/0.4.0/rules_pkg-0.4.0.tar.gz",
        "https://github.com/bazelbuild/rules_pkg/releases/download/0.4.0/rules_pkg-0.4.0.tar.gz",
    ],
)

load("@rules_pkg//:deps.bzl", "rules_pkg_dependencies")

rules_pkg_dependencies()

git_repository(
    name = "googletest",
    commit = "703bd9caab50b139428cea1aaff9974ebee5742e",
    remote = "https://github.com/google/googletest",
    shallow_since = "1570114335 -0400",
)

# External dependency for torch_tensorrt if you already have precompiled binaries.

# CUDA should be installed on the system locally
new_local_repository(
    name = "cuda",
    build_file = "@//third_party/cuda:BUILD",
    path = "C:/Program Files/NVIDIA GPU Computing Toolkit/CUDA/v11.6",
)

new_local_repository(
    name = "cublas",
    build_file = "@//third_party/cublas:BUILD",
    path =  "C:/Program Files/NVIDIA GPU Computing Toolkit/CUDA/v11.6",
)
#############################################################################################################
# Tarballs and fetched dependencies (default - use in cases when building from precompiled bin and tarballs)
#############################################################################################################

new_local_repository(
    name = "libtorch",
    path = "C:/Users/48698/source/libraries/pytorch/libtorch-win-shared-with-deps-1.10.2+cu113/libtorch",
    build_file = "@//third_party/libtorch:BUILD"
)

new_local_repository(
    name = "libtorch_pre_cxx11_abi",
    path = "C:/Users/48698/source/libraries/pytorch/libtorch-win-shared-with-deps-1.10.2+cu113/libtorch",
    build_file = "@//third_party/libtorch:BUILD"

)

# Download these tarballs manually from the NVIDIA website
# Either place them in the distdir directory in third_party and use the --distdir flag
# or modify the urls to "file:///<PATH TO TARBALL>/<TARBALL NAME>.tar.gz

http_archive(
    name = "cudnn",
    build_file = "@//third_party/cudnn/archive:BUILD",
    urls = [
        "https://developer.download.nvidia.com/compute/redist/cudnn/v8.3.2/local_installers/11.5/cudnn-windows-x86_64-8.3.2.44_cuda11.5-archive.zip",   
    ],
)

http_archive(
    name = "rules_pkg",
    sha256 = "038f1caa773a7e35b3663865ffb003169c6a71dc995e39bf4815792f385d837d",
    urls = [
        "https://mirror.bazel.build/github.com/bazelbuild/rules_pkg/releases/download/0.4.0/rules_pkg-0.4.0.tar.gz",
        "https://github.com/bazelbuild/rules_pkg/releases/download/0.4.0/rules_pkg-0.4.0.tar.gz",
    ],
)

new_local_repository(
   name = "tensorrt",
   path = "C:/Users/48698/source/libraries/tensorrt",
   build_file = "@//third_party/tensorrt/local:BUILD"
)

####################################################################################
# Locally installed dependencies (use in cases of custom dependencies or aarch64)
####################################################################################

# NOTE: In the case you are using just the pre-cxx11-abi path or just the cxx11 abi path
# with your local libtorch, just point deps at the same path to satisfy bazel.

# NOTE: NVIDIA's aarch64 PyTorch (python) wheel file uses the CXX11 ABI unlike PyTorch's standard
# x86_64 python distribution. If using NVIDIA's version just point to the root of the package
# for both versions here and do not use --config=pre-cxx11-abi

#new_local_repository(
#    name = "libtorch",
#    path = "/usr/local/lib/python3.6/dist-packages/torch",
#    build_file = "third_party/libtorch/BUILD"
#)

#new_local_repository(
#    name = "libtorch_pre_cxx11_abi",
#    path = "/usr/local/lib/python3.6/dist-packages/torch",
#    build_file = "third_party/libtorch/BUILD"
#)

#new_local_repository(
#    name = "cudnn",
#    path = "/usr/",
#    build_file = "@//third_party/cudnn/local:BUILD"
#)

#new_local_repository(
#   name = "tensorrt",
#   path = "/usr/",
#   build_file = "@//third_party/tensorrt/local:BUILD"
#)

#########################################################################
# Testing Dependencies (optional - comment out on aarch64)
#########################################################################
pip_install(
    name = "torch_tensorrt_py_deps",
    requirements = "//py:requirements.txt",
)

pip_install(
    name = "py_test_deps",
    requirements = "//tests/py:requirements.txt",
)

pip_install(
    name = "pylinter_deps",
    requirements = "//tools/linter:requirements.txt",
)

also with exclusion in cuda/BUILD:

package(default_visibility = ["//visibility:public"])

config_setting(
    name = "windows",
    constraint_values = [
        "@platforms//os:windows",
    ],
)

cc_library(
    name = "cudart",
    srcs = select({
        ":windows": [
            "lib/x64/cudart.lib",
        ],
        "//conditions:default": [
            "lib64/libcudart.so",
        ],
    }),
    hdrs = glob([
        "include/**/*.h",
        "include/**/*.hpp",
        "include/**/*.inl",
    ]),
    includes = ["include/"],
)

cc_library(
    name = "nvToolsExt",
    srcs = select({
        ":windows": [
            "bin/nvToolsExt64_1.dll",
        ],
        "//conditions:default": [
            "lib64/libnvToolsExt.so.1",
        ],
    }),
)

cc_library(
    name = "cuda",
    srcs = select({
        ":windows": [
            "bin/*.dll",
        ],
        "//conditions:default": glob([
            "lib64/**/lib*.so",
        ]),
    }),
    hdrs = glob([
        "include/**/*.h",
        "include/**/*.hpp",
        "include/**/*.inl",
    ],
    exclude=[
         "include/**/*cudnn*.h"
    ]),
    includes = ["include/"],
    linkopts = ["-Wl,-rpath,lib/"],
)

cc_library(
    name = "cublas",
    srcs = select({
        ":windows": glob([
            "lib/x64/cublas.lib",
        ]),
        "//conditions:default": glob([
            "lib64/**/*libcublas.so",
        ]),
    }),
    hdrs = glob([
        "include/**/*cublas*.h",
        "include/**/*.hpp",
        "include/**/*.inl",
    ]),
    includes = ["include/"],
    linkopts = ["-Wl,-rpath,lib/"],
)

and the cudnn/archive/BUILD:

package(default_visibility = ["//visibility:public"])

cc_library(
    name = "cudnn_headers",
    hdrs = glob(["include/cudnn*.h"]),
    includes = ["include/"],
    visibility = ["//visibility:private"],
)

cc_import(
    name = "cudnn_lib",
    shared_library = "bin/cudnn64_8.dll",
    visibility = ["//visibility:private"],
)

cc_library(
    name = "cudnn",
    visibility = ["//visibility:public"],
    deps = [
        "cudnn_headers",
        "cudnn_lib",
    ],
)

This, I think points to the problem being connected to a misconfiguration between the BUILD / WORKSPACE files not with the library being wrongly installed. However, I am still at a loss how to proceed 😞

Maybe there is some tinkering to be done within plugin BUILD files?

[narendasan]

Hmm, yeah i feel like the issue is the includes = ["include/"], in the cuda target. Perhaps its just worth creating a cuda/cudnn target and using that over the original third_party/cudnn. This might be easier.

So this would be something like:
In //third_party/cuda/BUILD:

cc_library(
    name = "cudnn",
    srcs = select({
        ":windows": [
            "bin/cudnn*.dll",
        ],
        "//conditions:default": glob([
            "lib64/**/libcudnn*.so",
        ]),
    }),
    hdrs = glob([
        "include/**/cudnn*.h",
        "include/**/cudnn*.hpp",
        "include/**/cudnn*.inl",
    ]),
    includes = ["include/"],
    linkopts = ["-Wl,-rpath,lib/"],
)

Then in instances where @cudnn//:cudnn appears as a dependency like in the TensorRT BUILD file you would change that build file from something like

cc_library(
    name = "nvinfer",
    visibility = ["//visibility:public"],
    deps = [
        "nvinfer_headers",
        "nvinfer_lib",
        "@cuda//:cudart",
        "@cudnn",
    ] + select({
        ":windows": ["@cuda//:cublas"],
        "//conditions:default": ["@cuda//:cublas"],
    }),

to

cc_library(
    name = "nvinfer",
    visibility = ["//visibility:public"],
    deps = [
        "nvinfer_headers",
        "nvinfer_lib",
        "@cuda//:cudart",
    ] + select({
        ":windows": [
             "@cuda//:cublas", 
             "@cuda//:cudnn",
         ],
        "//conditions:default": [
               "@cuda//:cublas",
               "@cudnn//:cudnn"
         ],
    }),

[pepinu]

Alright, I added the changes as you proposed, but the error is still persisting.

I went to C:/users/48698/source/libraries/new/torch-tensorrt-1.0.0/torch-tensorrt-1.0.0/core/plugins/BUILD
and tried a few things, when I comment nvinfer and nvinfer plugin from deps, the error does not change at all, which is very confusing to me. The nvinfer should have in itself already the dependencies resolved, yet somehow Bazel does not see them. From tensorrt/local/BUILD:

... 

cc_library(
    name = "nvinfer",
    visibility = ["//visibility:public"],
    deps = [
        "nvinfer_headers",
        "nvinfer_lib",
        "@cuda//:cudart",
        "@cuda//:cublas",
        "@cuda//:cudnn",
    ],
)
...

If I explicitly add @cuda as one of the torch_tensorrt_plugins dependencies (no idea if that is something that should or should not be done) there goes another error connected to https://github.com/NVIDIA/Torch-TensorRT/blob/master/third_party/cuda/BUILD#L44 this line, saying that * is an illegal symbol.

FATAL: bazel crashed due to an internal error. Printing stack trace:
java.lang.RuntimeException: Unrecoverable error while evaluating node 'FILE_STATE:[<absolute root>]/[C:/Program Files/NVIDIA GPU Computing Toolkit/CUDA/v11.6/bin/*.dll]' (requested by nodes 'FILE:[C:/users/48698/_bazel_48698/dw6ogrhx/external/cuda]/[bin/*.dll]')
        at com.google.devtools.build.skyframe.AbstractParallelEvaluator$Evaluate.run(AbstractParallelEvaluator.java:674)
        at com.google.devtools.build.lib.concurrent.AbstractQueueVisitor$WrappedRunnable.run(AbstractQueueVisitor.java:382)
        at java.base/java.util.concurrent.ThreadPoolExecutor.runWorker(Unknown Source)
        at java.base/java.util.concurrent.ThreadPoolExecutor$Worker.run(Unknown Source)
        at java.base/java.lang.Thread.run(Unknown Source)
Caused by: java.nio.file.InvalidPathException: Illegal char <*> at index 61: C:\Program Files\NVIDIA GPU Computing Toolkit\CUDA\v11.6\bin\*.dll

When engulfed by the glob() function, it starts compiling but with the final error:

C:\Users\48698\source\libraries\new\Torch-TensorRT-1.0.0\Torch-TensorRT-1.0.0>bazel build //:libtorchtrt --compilation_mode opt --python_path="C:/Users/48698/anaconda3/python.exe"
Starting local Bazel server and connecting to it...
ERROR: C:/users/48698/source/libraries/new/torch-tensorrt-1.0.0/torch-tensorrt-1.0.0/cpp/lib/BUILD:34:10: for cpp/lib/cudnn64_8.dll, previous action: action 'Copying Execution Dynamic Library', attempted action: action 'Copying Execution Dynamic Library'
ERROR: Analysis of target '//:libtorchtrt' failed; build aborted:
INFO: Elapsed time: 3.449s
INFO: 0 processes.
FAILED: Build did NOT complete successfully (61 packages loaded, 2882 targets configured)

adding @cuda//:cudnn to torch_tensorrt_plugins does not change the error - its the same as at the beginning.

I've also tried moving tenorrt installation from the local to archive one and did everything from scratch to match your description with cudnn as a separate target of cuda. To be sure I did it correctly I specifically ran 2 Bazel builds with unchanged @cudnn nvinfer dep to see if it crashes, which it does:

once moved to @cuda/cudnn it works as intended and stops at the initial error.

Also, I've found the folder where Bazel puts all headers dependencies, and I am more confused, since cudnn*.h are all there, with an error saying there is a problem:

just to be clear - this folder has many more header files, I just picked the ones that it says are missing.

Now I am suspecting that for some reason nvinfer is not passing it's own dependencies (cudnn included) up to the //core/plugins:BUILD which looks as follows:

cc_library(
    name = "torch_tensorrt_plugins",
    hdrs = [
        "impl/interpolate_plugin.h",
        "impl/normalize_plugin.h",
        "plugins.h",

    ],
    srcs = [
        "impl/interpolate_plugin.cpp",
        "impl/normalize_plugin.cpp",
        "register_plugins.cpp",
    ],
    deps = [
        "@tensorrt//:nvinfer",
        "@tensorrt//:nvinferplugin",
        "//core/util:prelude",
    ] + select({
        ":use_pre_cxx11_abi":  ["@libtorch_pre_cxx11_abi//:libtorch"],
        "//conditions:default":  ["@libtorch//:libtorch"],
    }),
    alwayslink = True,
    copts = [
        "-pthread"
    ],
    linkopts = [
        "-lpthread",
    ]
)

[jonahclarsen]

Any updates? I am currently working through the same issue