add IFlowEVMNFTBridge contract interface & implement in FlowEVMBridge

cadence/contracts/bridge/FlowEVMBridge.cdc

@@ -9,6 +9,7 @@ import "EVM"
 import "BridgePermissions"
 import "ICrossVM"
 import "IEVMBridgeNFTMinter"
+import "IFlowEVMNFTBridge"
 import "CrossVMNFT"
 import "FlowEVMBridgeConfig"
 import "FlowEVMBridgeUtils"
@@ -25,7 +26,7 @@ import "FlowEVMBridgeTemplates"
 /// - FLIP #237: https://github.com/onflow/flips/pull/233
 ///
 access(all)
-contract FlowEVMBridge {
+contract FlowEVMBridge : IFlowEVMNFTBridge {
 
     /*************
         Events
@@ -323,6 +324,13 @@ contract FlowEVMBridge {
         Public Getters
     **************************/
 
+    /// Returns the EVM address associated with the provided type
+    ///
+    access(all)
+    view fun getAssociatedEVMAddress(with type: Type): EVM.EVMAddress? {
+        return FlowEVMBridgeConfig.getEVMAddressAssociated(with: type)
+    }
+
     /// Retrieves the bridge contract's COA EVMAddress
     ///
     /// @returns The EVMAddress of the bridge contract's COA orchestrating actions in FlowEVM

cadence/contracts/bridge/IFlowEVMNFTBridge.cdc

@@ -0,0 +1,109 @@
+import "FungibleToken"
+import "NonFungibleToken"
+
+import "EVM"
+
+import "FlowEVMBridgeConfig"
+import "FlowEVMBridgeUtils"
+
+access(all) contract interface IFlowEVMNFTBridge {
+
+    /*************
+        Events
+    **************/
+
+    /// Broadcasts an NFT was bridged from Cadence to EVM
+    access(all)
+    event BridgedNFTToEVM(
+        type: Type,
+        id: UInt64,
+        evmID: UInt256,
+        to: String,
+        evmContractAddress: String,
+        bridgeAddress: Address
+    )
+    /// Broadcasts an NFT was bridged from EVM to Cadence
+    access(all)
+    event BridgedNFTFromEVM(
+        type: Type,
+        id: UInt64,
+        evmID: UInt256,
+        caller: String,
+        evmContractAddress: String,
+        bridgeAddress: Address
+    )
+
+    /**************
+        Getters
+    ***************/
+
+    /// Returns the EVM address associated with the provided type
+    ///
+    access(all)
+    view fun getAssociatedEVMAddress(with type: Type): EVM.EVMAddress?
+
+    /********************************
+        Public Bridge Entrypoints
+    *********************************/
+
+    /// Public entrypoint to bridge NFTs from Cadence to EVM.
+    ///
+    /// @param token: The NFT to be bridged
+    /// @param to: The NFT recipient in FlowEVM
+    /// @param feeProvider: A reference to a FungibleToken Provider from which the bridging fee is withdrawn in $FLOW
+    ///
+    access(all)
+    fun bridgeNFTToEVM(
+        token: @{NonFungibleToken.NFT},
+        to: EVM.EVMAddress,
+        feeProvider: auth(FungibleToken.Withdraw) &{FungibleToken.Provider}
+    ) {
+        pre {
+            emit BridgedNFTToEVM(
+                type: token.getType(),
+                id: token.id,
+                evmID: 0,
+                to: FlowEVMBridgeUtils.getEVMAddressAsHexString(address: to),
+                evmContractAddress: FlowEVMBridgeUtils.getEVMAddressAsHexString(
+                    address: self.getAssociatedEVMAddress(with: token.getType())
+                        ?? panic("Could not find EVM Contract address associated with provided NFT")
+                ), bridgeAddress: self.account.address
+            )
+        }
+    }
+
+    /// Public entrypoint to bridge NFTs from EVM to Cadence
+    ///
+    /// @param owner: The EVM address of the NFT owner. Current ownership and successful transfer (via 
+    ///     `protectedTransferCall`) is validated before the bridge request is executed.
+    /// @param calldata: Caller-provided approve() call, enabling contract COA to operate on NFT in EVM contract
+    /// @param id: The NFT ID to bridged
+    /// @param evmContractAddress: Address of the EVM address defining the NFT being bridged - also call target
+    /// @param feeProvider: A reference to a FungibleToken Provider from which the bridging fee is withdrawn in $FLOW
+    /// @param protectedTransferCall: A function that executes the transfer of the NFT from the named owner to the
+    ///     bridge's COA. This function is expected to return a Result indicating the status of the transfer call.
+    ///
+    /// @returns The bridged NFT
+    ///
+    access(all)
+    fun bridgeNFTFromEVM(
+        owner: EVM.EVMAddress,
+        type: Type,
+        id: UInt256,
+        feeProvider: auth(FungibleToken.Withdraw) &{FungibleToken.Provider},
+        protectedTransferCall: fun (): EVM.Result
+    ): @{NonFungibleToken.NFT} {
+        post {
+            emit BridgedNFTFromEVM(
+                type: result.getType(),
+                id: result.id,
+                evmID: id,
+                caller: FlowEVMBridgeUtils.getEVMAddressAsHexString(address: owner),
+                evmContractAddress: FlowEVMBridgeUtils.getEVMAddressAsHexString(
+                    address: self.getAssociatedEVMAddress(with: result.getType())
+                        ?? panic("Could not find EVM Contract address associated with provided NFT")
+                ), bridgeAddress: self.account.address
+            )
+        }
+    }
+}