batsim: 4.2.0

nur.nix

@@ -36,7 +36,8 @@ rec {
   batexpe = pkgs.callPackage ./pkgs/batexpe { };
 
   batsim-410 = pkgs.callPackage ./pkgs/batsim/batsim410.nix { inherit redox debug; simgrid = simgrid-334light; intervalset = intervalsetlight; };
-  batsim = batsim-410;
+  batsim-420 = pkgs.callPackage ./pkgs/batsim/batsim420.nix { inherit redox debug; simgrid = simgrid-334light; intervalset = intervalsetlight; };
+  batsim = batsim-420;
   batsim-docker = pkgs.callPackage ./pkgs/batsim/batsim-docker.nix { inherit batsim; };
 
   elastisim = pkgs.callPackage ./pkgs/elastisim { };

pkgs/batsim/batsim420.nix

@@ -0,0 +1,57 @@
+{ stdenv, lib, fetchFromGitLab
+, meson, ninja, pkgconfig
+, simgrid, intervalset, boost, rapidjson, redox, zeromq, docopt_cpp, pugixml
+, debug ? false
+}:
+
+stdenv.mkDerivation rec {
+  pname = "batsim";
+  version = "4.2.0";
+
+  src = fetchFromGitLab {
+    domain = "framagit.org";
+    owner = "batsim";
+    repo = pname;
+    rev = "v${version}";
+    sha256 = "sha256-RsjvPhuJL6S804/BZGpzl9qkCujWJxWK0isD4osekMI=";
+  };
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkgconfig
+  ];
+  # runtimeDeps is used to generate multi-layered docker contained
+  runtimeDeps = [
+    simgrid
+    intervalset
+    rapidjson
+    redox
+    zeromq
+    docopt_cpp
+    pugixml
+  ];
+  buildInputs = [
+    boost
+  ] ++ runtimeDeps;
+
+  ninjaFlags = [ "-v" ];
+  enableParallelBuilding = true;
+
+  mesonBuildType = if debug then "debug" else "release";
+  CXXFLAGS = if debug then "-O0" else "";
+  hardeningDisable = if debug then [ "fortify" ] else [];
+  dontStrip = debug;
+
+  meta = with lib; {
+    description = "An infrastructure simulator that focuses on resource management techniques.";
+    homepage = "https://framagit.org/batsim/batsim";
+    platforms = platforms.all;
+    license = licenses.lgpl3;
+    broken = false;
+
+    longDescription = ''
+      Batsim is an infrastructure simulator that enables the study of resource management techniques.
+    '';
+  };
+}