[Backport nixos-25.05] flake: add ci.buildbot output

buildbot-nix.toml

@@ -0,0 +1 @@
+attribute = "ci.buildbot"

flake/ci.nix

@@ -0,0 +1,43 @@
+{ lib, config, ... }:
+let
+  inherit (lib)
+    mapAttrs
+    types
+    ;
+
+  buildbotOpt = lib.mkOption {
+    type = types.lazyAttrsOf types.package;
+    default = { };
+    description = ''
+      A set of tests for [buildbot] to run.
+
+      [buildbot]: https://buildbot.nix-community.org
+    '';
+  };
+in
+{
+  perSystem = {
+    # Declare per-system CI options
+    options.ci = {
+      buildbot = buildbotOpt;
+    };
+  };
+
+  flake = {
+    # Declare top-level CI options
+    options.ci = {
+      buildbot = lib.mkOption {
+        type = types.lazyAttrsOf buildbotOpt.type;
+        default = { };
+        description = ''
+          See `perSystem.ci.buildbot` for description and examples.
+        '';
+      };
+    };
+
+    # Transpose per-system CI outputs to the top-level
+    config.ci = {
+      buildbot = mapAttrs (_: sysCfg: sysCfg.ci.buildbot) config.allSystems;
+    };
+  };
+}

flake/default.nix

@@ -8,6 +8,7 @@
 {
   imports = [
     ./flake-modules
+    ./ci.nix
     ./lib.nix
     ./legacy-packages.nix
     ./nixvim-configurations.nix
@@ -31,6 +32,7 @@
 
   # Specify which outputs are defined by which partitions
   partitionedAttrs = {
+    ci = "dev";
     checks = "dev";
     devShells = "dev";
     formatter = "dev";

flake/dev/devshell.nix

@@ -29,6 +29,7 @@
             {
               name = "checks";
               help = "Run all nixvim checks";
+              # TODO: run tests from the `ci` flake output too?
               command = ''
                 echo "=> Running all nixvim checks..."
 

flake/dev/package-tests.nix

@@ -4,5 +4,9 @@
     {
       # Test that all packages build fine when running `nix flake check`.
       checks = config.packages;
+
+      # Test that all packages build when running buildbot
+      # TODO: only test the docs on x86_64-linux
+      ci.buildbot = config.packages;
     };
 }

flake/dev/tests.nix

@@ -7,8 +7,15 @@
   perSystem =
     { pkgs, ... }:
     {
+      # TODO: consider whether all these tests are needed in the `checks` output
       checks = pkgs.callPackages ../../tests {
         inherit helpers self;
       };
+
+      # TODO: consider whether all these tests are needed to be built by buildbot
+      ci.buildbot = pkgs.callPackages ../../tests {
+        inherit helpers self;
+        allSystems = false;
+      };
     };
 }

tests/default.nix

@@ -5,6 +5,7 @@
   linkFarm,
   self, # The flake instance
   system ? pkgs.stdenv.hostPlatform.system,
+  allSystems ? true,
 }:
 let
   autoArgs = pkgs // {
@@ -31,8 +32,15 @@ let
   callTests = lib.callPackagesWith autoArgs;
 
   selfPackages = self.packages.${system};
+
+  # For tests that CI should only build on one system,
+  # This is true when on that system.
+  #
+  # TODO: consider refactoring tests/default.nix so that some tests are
+  # defined by it, while others are defined elsewhere...
+  buildForThisSystem = allSystems || system == "x86_64-linux";
 in
-{
+lib.optionalAttrs buildForThisSystem {
   extra-args-tests = callTest ./extra-args.nix { };
   extend = callTest ./extend.nix { };
   extra-files = callTest ./extra-files.nix { };
@@ -47,10 +55,12 @@ in
   lsp-all-servers = callTest ./lsp-servers.nix { };
 }
 # Expose some tests from the docs as flake-checks too
-// lib.optionalAttrs (selfPackages ? docs) {
+// lib.optionalAttrs (selfPackages ? docs && buildForThisSystem) {
   # Individual tests can be run using: nix build .#docs.user-configs.tests.<test>
   docs-user-configs = linkFarm "user-configs-tests" selfPackages.docs.user-configs.tests;
 }
+
+# These are always built on all systems, even when `allSystems = false`
 // callTests ./platforms { }
 # Tests generated from ./test-sources
 # Grouped as a number of link-farms in the form { test-1, test-2, ... test-N }