Refactor NUT_ARG_WITH* et al in configure.ac and m4/* scripts

Makefile.am

@@ -642,7 +642,7 @@ SPELLCHECK_DIRS_MOST = \
 	spellcheck/docs/man \
 	spellcheck/conf \
 	spellcheck/data \
-	spellcheck/data/html \
+	spellcheck/data/htmlcgi \
 	spellcheck/scripts \
 	spellcheck/scripts/Solaris \
 	spellcheck/scripts/Windows \

NEWS.adoc

@@ -180,6 +180,20 @@ several `FSD` notifications into one executed action. [PR #3097]
      it), if not bundling with NUT-Monitor UI app. By default the respective
      interpreter's 'site-packages' or 'dist-packages' location will be used,
      so you may have to adjust search paths for any other values. [#3062]
+   * Streamlined handling of `--with-*` and `--enable-*` options using NUT 'm4'
+     macros; fixed reporting help for options whose defaults are evaluated.
+     [issue #3049, PR #3140]
+   * Automatic `--with-devd` could not detect the need to install a FreeBSD
+     devd configuration snippet file, because it expected a source that should
+     not have been there (probably a copy-paste typo in NUT v2.8.0). Also
+     fixed a missed compiler family dependency when handling `--enable-strip`,
+     a few logical mismatches of Solaris/illumos packaging options, and default
+     report vs. setting of `--enable-force-nut-version-header`. Rephrased and
+     updated many help messages. The `configure` script logs should now clarify
+     where CFLAGS/LIBS/LDFLAGS values come from ('pkg-config', 'default', user
+     provided 'confargs' etc.) [#3140]
+   * Added configure script options for 'libregex' tuning, just so it is on par
+     with our other optional dependencies. [#3140]
 
  - Fixed CI recipes for PyPI publication of PyNUT(Client) module to also
    include the source distribution (was posted for NUT v2.8.1 and v2.8.2

ci_build.sh

@@ -869,10 +869,13 @@ detect_platform_PKG_CONFIG_PATH_and_FLAGS() {
     BUILTIN_PKG_CONFIG_PATH="`$PKG_CONFIG --variable pc_path pkg-config`" || BUILTIN_PKG_CONFIG_PATH=""
     case "`echo "$CI_OS_NAME" | $TOLOWER`" in
         *openindiana*|*omnios*|*solaris*|*illumos*|*sunos*)
-            _ARCHES="${ARCH-}"
+            _ARCHES="${ARCH_TGT-}${ARCH-}${ARCH32-}${ARCH64-}"
             _BITS="${BITS-}"
             _ISA1=""
 
+            [ -n "${_BITS}" ] || \
+            _BITS="${ARCH_BITS-}"
+
             [ -n "${_BITS}" ] || \
             case "${CC}${CXX}${CFLAGS}${CXXFLAGS}${LDFLAGS}" in
                 *-m64*) _BITS=64 ;;

data/Makefile.am

@@ -1,6 +1,6 @@
 # Network UPS Tools: data
 
-SUBDIRS = html
+SUBDIRS = htmlcgi
 
 dist_data_DATA = cmdvartab
 nodist_data_DATA = driver.list

data/html/Makefile.am → data/htmlcgi/Makefile.am

@@ -1,11 +1,14 @@
-# Network UPS Tools: data/html
+# Network UPS Tools: data/htmlcgi
+
+EXTRA_DIST = README.adoc
 
 # install these only if configured --with-cgi
 if WITH_CGI
- dist_html_DATA = index.html bottom.html nut-banner.png
- nodist_html_DATA = header.html
+ dist_htmlcgi_DATA = index.html bottom.html nut-banner.png
+ nodist_htmlcgi_DATA = header.html
+else
+ EXTRA_DIST += index.html bottom.html nut-banner.png header.html.in
 endif
-EXTRA_DIST = README.adoc
 
 SPELLCHECK_SRC = README.adoc
 

docs/configure.txt

@@ -276,8 +276,8 @@ CGI client interface
 
 Build and install the optional CGI programs, HTML files, and sample
 CGI configuration files. This is not enabled by default, as they
-are only useful on web servers. See link:data/html/README[] for additional
-information on how to set up CGI programs.
+are only useful on web servers. See link:data/htmlcgi/README[] for
+additional information on how to set up CGI programs.
 
 NUT Scanner tool
 ~~~~~~~~~~~~~~~~

docs/nut.dict

@@ -1,4 +1,4 @@
-personal_ws-1.1 en 3564 utf-8
+personal_ws-1.1 en 3566 utf-8
 AAC
 AAS
 ABI
@@ -1817,6 +1817,7 @@ compareprocnames
 compat
 compilerPath
 conf
+confargs
 confdir
 config
 configparser
@@ -2211,6 +2212,7 @@ href
 htaccess
 htm
 html
+htmlcgi
 htmlpath
 http
 httpd

m4/nut_arg_with.m4

@@ -1,21 +1,220 @@
-dnl simplified declaration of some feature options
+dnl Simplified declaration of some feature options
+dnl Copyright (C)
+dnl     2006       Peter Selinger <selinger@users.sourceforge.net>
+dnl     2020-2025  Jim Klimov <jimklimov+nut@gmail.com>
+dnl Common arguments:
+dnl     $1 option name (part after `--with-`)
+dnl     $2 help bit in option name (except legacy short funcs)
+dnl     $2 or $3 help text (descriptive part)
+dnl     $3 or $4 default value
+dnl     $4 or $5 how to represent default in help text (for *_CUSTOM_DEFAULT_HELP)
+dnl Note that for some reason use of dollar-number gets expanded below,
+dnl but any other variable (e.g. $conftemp straight in help string) is not.
+dnl In fact, the generated configure script includes the help wall of text
+dnl much earlier than it includes lines that manipulate conftemp (unless it
+dnl gets somehow escaped to happen earlier), due to m4 diverts in autoconf code.
+dnl So we can use the "EXPAND" methods to convert static text, but not to display
+dnl any values determined and changed during `configure` shell script run-time.
+dnl See research in https://github.com/networkupstools/nut/issues/3049 for more.
+
+dnl Default expanded once to substitute current variables,
+dnl or remove backslashing of verbatim dollars, etc.
+dnl NOTE: Not sure if the fuss with uniquely named conftemp is worth it,
+dnl or is even remembered between calls. There seems to be 3 calls per name.
+AC_DEFUN([NUT_ARG_EXPAND],
+[[]m4_esyscmd_s(
+    [nut_conftemp_]m4_translit([$1], [-], [_])="$2" ;
+    eval [nut_conftemp_]m4_translit([$1], [-], [_])=\"\${[nut_conftemp_]m4_translit([$1], [-], [_])}\" ;
+    echo "${[nut_conftemp_]m4_translit([$1], [-], [_])}" ;
+    dnl # RUNS 3 TIMES # echo "$1 | $2 | [nut_conftemp_]m4_translit([$1], [-], [_])=${[nut_conftemp_]m4_translit([$1], [-], [_])}" >> arg.log ;
+)[]])
 
 dnl Working With External Software (might name a variant or other contextual arg)
 dnl https://www.gnu.org/software/autoconf/manual/autoconf-2.66/html_node/External-Software.html#External-Software
+dnl including concepts of the OS as external software (account names, paths...)
+
+dnl     $1 option name (part after `--with-`)
+dnl     $2 optional "=VALUE" for help tag (after $1)
+dnl     $3 help text (descriptive part)
+dnl     $4 default value
+dnl     $5 how to represent default in help text (for *_CUSTOM_DEFAULT_HELP)
+AC_DEFUN([NUT_ARG_WITH_CUSTOM_DEFAULT_HELP],
+[   AC_ARG_WITH([$1],
+        m4_ifval([$2],
+            [m4_ifval([$5],
+                [AS_HELP_STRING([--with-$1=$2], [$3 (default: $5)])],
+                [AS_HELP_STRING([--with-$1=$2], [$3 (default: $4)])])],
+            [m4_ifval([$5],
+                [AS_HELP_STRING([--with-$1], [$3 (default: $5)])],
+                [AS_HELP_STRING([--with-$1], [$3 (default: $4)])])]),
+        [[nut_with_]m4_translit([$1], [-], [_])="${withval}"],
+        [[nut_with_]m4_translit([$1], [-], [_])="$4"]
+    )
+])
+
+AC_DEFUN([NUT_ARG_WITH_EXPAND_DEFAULT_HELP],
+[
+    dnl Note: only 4 args expected
+    dnl NUT_ARG_EXPAND([$1], $3)
+    NUT_ARG_WITH_CUSTOM_DEFAULT_HELP([$1], [$2], [$3], [$4], NUT_ARG_EXPAND([with_$1], [$4]))
+])
+
+AC_DEFUN([NUT_ARG_WITH_EXPAND_DEFAULT_HELP_SINGLEQUOTE],
+[
+    dnl Variant for paths (likely using backslash-dollar in $4)
+    dnl Note: only 4 args expected
+    dnl Note: "resolved from" must be not bracketed
+    NUT_ARG_WITH_CUSTOM_DEFAULT_HELP([$1], [$2], [$3], [$4], resolved from NUT_ARG_EXPAND([with_$1], '[$4]'))
+])
+
 AC_DEFUN([NUT_ARG_WITH],
-[  AC_ARG_WITH($1,
-      AS_HELP_STRING([--with-$1], [$2 ($3)]),
-      [[nut_with_]m4_translit($1, [-], [_])="${withval}"],
-      [[nut_with_]m4_translit($1, [-], [_])="$3"]
-   )
+[
+    dnl Note: historicaly only 3 args were expected
+    dnl Now a second arg may be injected for optional "=VALUE" for help tag (after $1)
+    dnl Legacy behavior (for static values): default value
+    dnl and its help representation are the same (verbatim!)
+    m4_ifval([$4],
+        [NUT_ARG_WITH_CUSTOM_DEFAULT_HELP([$1], [$2], [$3], [$4], [$4])],
+        [NUT_ARG_WITH_CUSTOM_DEFAULT_HELP([$1], [], [$2], [$3], [$3])])
+])
+
+dnl Special common case for *-includes and *-libs optional parameters
+dnl (bracketed in help text to confer optionality)
+dnl Options same as NUT_ARG_WITH (4-arg version)
+AC_DEFUN([NUT_ARG_WITH_LIBOPTS],
+[
+    AC_ARG_WITH([$1],
+        [AS_HELP_STRING([@<:@--with-$1=$2@:>@], [$3 (default: $4)])],
+        [[nut_with_]m4_translit([$1], [-], [_])="${withval}"],
+        [[nut_with_]m4_translit([$1], [-], [_])="$4"]
+    )
+])
+
+AC_DEFUN([NUT_ARG_WITH_LIBOPTS_INVALID_YESNO],
+[
+    AC_ARG_WITH([$1],
+        [AS_HELP_STRING([@<:@--with-$1=$2@:>@], [$3 (default: $4)])],
+        [AS_CASE([${withval}],
+            [yes|no], [AC_MSG_ERROR([invalid option --with(out)-$1 - see docs/configure.txt])],
+                [[nut_with_]m4_translit([$1], [-], [_])="${withval}"]
+        )],
+        [[nut_with_]m4_translit([$1], [-], [_])="$4"]
+    )
+])
+
+dnl NOTE: The defaulting substituter may be not defined/renamed in some autoconf versions
+dnl m4_ifndef([m4_default], [m4_define([m4_default], [m4_ifval([[$1]], [[$1]], [[$2]])])])
+
+dnl Just the (normal-cased) third-party project name is required
+dnl   $1 project name
+dnl   $2 default value (optional)
+dnl   $3 project name spelling for help message (very optional)
+
+AC_DEFUN([NUT_ARG_WITH_LIBOPTS_INCLUDES],
+[
+    m4_ifval([$2],
+        [NUT_ARG_WITH_LIBOPTS_INVALID_YESNO([]m4_translit([$1], 'A-Z', 'a-z')[-includes], [CFLAGS|auto], [include flags for the ]m4_default([$3], [$1])[ library], [$2])],
+        [NUT_ARG_WITH_LIBOPTS_INVALID_YESNO([]m4_translit([$1], 'A-Z', 'a-z')[-includes], [CFLAGS|auto], [include flags for the ]m4_default([$3], [$1])[ library], [auto])])
+])
+
+dnl Technically LIBS and LDFLAGS are about the same for
+dnl most of our m4 code and legacy help messaging... so far.
+AC_DEFUN([NUT_ARG_WITH_LIBOPTS_LIBS],
+[
+    m4_ifval([$2],
+        [NUT_ARG_WITH_LIBOPTS_INVALID_YESNO([]m4_translit([$1], 'A-Z', 'a-z')[-libs], [LIBS|auto], [linker flags for the ]m4_default([$3], [$1])[ library], [$2])],
+        [NUT_ARG_WITH_LIBOPTS_INVALID_YESNO([]m4_translit([$1], 'A-Z', 'a-z')[-libs], [LIBS|auto], [linker flags for the ]m4_default([$3], [$1])[ library], [auto])])
 ])
 
-dnl Enable a feature (might name a variant), or yes/no
+AC_DEFUN([NUT_ARG_WITH_LIBOPTS_LIBS_AS_LDFLAGS],
+[
+    m4_ifval([$2],
+        [NUT_ARG_WITH_LIBOPTS_INVALID_YESNO([]m4_translit([$1], 'A-Z', 'a-z')[-libs], [LDFLAGS|auto], [linker flags for the ]m4_default([$3], [$1])[ library], [$2])],
+        [NUT_ARG_WITH_LIBOPTS_INVALID_YESNO([]m4_translit([$1], 'A-Z', 'a-z')[-libs], [LDFLAGS|auto], [linker flags for the ]m4_default([$3], [$1])[ library], [auto])])
+])
+
+AC_DEFUN([NUT_ARG_WITH_LIBOPTS_LDFLAGS],
+[
+    m4_ifval([$2],
+        [NUT_ARG_WITH_LIBOPTS_INVALID_YESNO([]m4_translit([$1], 'A-Z', 'a-z')[-ldflags], [LDFLAGS|auto], [linker flags for the ]m4_default([$3], [$1])[ library], [$2])],
+        [NUT_ARG_WITH_LIBOPTS_INVALID_YESNO([]m4_translit([$1], 'A-Z', 'a-z')[-ldflags], [LDFLAGS|auto], [linker flags for the ]m4_default([$3], [$1])[ library], [auto])])
+])
+
+dnl Help detect legacy <projectname>-config scripts, assigns "none" if disabled or not found
+dnl   $1 project name
+dnl   $2 m4 var to assign
+dnl   $3 program name(s) to try
+dnl   $4 default value
+dnl   $5 project name spelling for help message (very optional)
+AC_DEFUN([NUT_ARG_WITH_LIBOPTS_CONFIGSCRIPT_IMPLEM],
+[
+    dnl By default seek in PATH
+    NUT_ARG_WITH_LIBOPTS([]m4_translit([$1], 'A-Z', 'a-z')[-config], [/path/to/m4_translit([$1], 'A-Z', 'a-z')-config|auto|none], [path to program that reports ]m4_default([$5], [$1])[ configuration], [$4])
+    AS_CASE([[${nut_with_]m4_translit([$1], [-], [_])[_config}]],
+        [yes|auto|""], [AC_PATH_PROGS([$2], [$3], [none])],
+        [no|none], [$2="none"],
+            [$2=["${nut_with_]m4_translit([$1], [-], [_])[_config}"]]
+    )
+])
+
+dnl Part of stack, use or guess optional parameter $2 (m4 var name); pass others as is
+AC_DEFUN([NUT_ARG_WITH_LIBOPTS_CONFIGSCRIPT_IMPLEM_2],
+[
+    m4_ifval([$2],
+        [NUT_ARG_WITH_LIBOPTS_CONFIGSCRIPT_IMPLEM([$1], [$2], [$3], [$4], [$5])],
+        [NUT_ARG_WITH_LIBOPTS_CONFIGSCRIPT_IMPLEM([$1], m4_translit(m4_translit([$1], 'a-z', 'A-Z'), [-], [_])[_CONFIG], [$3], [$4], [$5])])
+])
+
+dnl Part of stack, use or guess optional parameter $3 (prog names); pass others as is
+AC_DEFUN([NUT_ARG_WITH_LIBOPTS_CONFIGSCRIPT_IMPLEM_3],
+[
+    m4_ifval([$3],
+        [NUT_ARG_WITH_LIBOPTS_CONFIGSCRIPT_IMPLEM_2([$1], [$2], [$3], [$4], [$5])],
+        [NUT_ARG_WITH_LIBOPTS_CONFIGSCRIPT_IMPLEM_2([$1], [$2], []m4_translit([$1], 'A-Z', 'a-z')[-config], [$4], [$5])])
+])
+
+dnl Just the (normal-cased) third-party project name is required
+dnl   $1 project name
+dnl   $2 m4 var to assign (optional)
+dnl   $3 program name(s) to try (optional)
+dnl   $4 default value (optional)
+dnl   $5 project name spelling for help message (very optional)
+AC_DEFUN([NUT_ARG_WITH_LIBOPTS_CONFIGSCRIPT],
+[
+    m4_ifval([$4],
+        [NUT_ARG_WITH_LIBOPTS_CONFIGSCRIPT_IMPLEM_3([$1], [$2], [$3], [$4], [$5])],
+        [NUT_ARG_WITH_LIBOPTS_CONFIGSCRIPT_IMPLEM_3([$1], [$2], [$3], [auto], [$5])])
+])
+
+dnl Enable a package feature/ability (might name a variant, or yes/no)
 dnl https://www.gnu.org/software/autoconf/manual/autoconf-2.66/html_node/Package-Options.html
+AC_DEFUN([NUT_ARG_ENABLE_CUSTOM_DEFAULT_HELP],
+[   AC_ARG_ENABLE([$1],
+        m4_ifval([$2],
+            [m4_ifval([$5],
+                [AS_HELP_STRING([--enable-$1=$2], [$3 (default: $5)])],
+                [AS_HELP_STRING([--enable-$1=$2], [$3 (default: $4)])])],
+            [m4_ifval([$5],
+                [AS_HELP_STRING([--enable-$1], [$3 (default: $5)])],
+                [AS_HELP_STRING([--enable-$1], [$3 (default: $4)])])]),
+        [[nut_enable_]m4_translit([$1], [-], [_])="${enableval}"],
+        [[nut_enable_]m4_translit([$1], [-], [_])="$4"]
+    )
+])
+
+AC_DEFUN([NUT_ARG_ENABLE_EXPAND_DEFAULT_HELP],
+[
+    NUT_ARG_ENABLE_CUSTOM_DEFAULT_HELP([$1], [$2], [$3], [$4], NUT_ARG_EXPAND([[enable_]$1], [$4]))
+])
+
+AC_DEFUN([NUT_ARG_ENABLE_EXPAND_DEFAULT_HELP_SINGLEQUOTE],
+[
+    NUT_ARG_ENABLE_CUSTOM_DEFAULT_HELP([$1], [$2], [$3], [$4], resolved from NUT_ARG_EXPAND([[enable_]$1], '[$4]'))
+])
+
 AC_DEFUN([NUT_ARG_ENABLE],
-[  AC_ARG_ENABLE($1,
-      AS_HELP_STRING([--enable-$1], [$2 ($3)]),
-      [[nut_enable_]m4_translit($1, [-], [_])="${enableval}"],
-      [[nut_enable_]m4_translit($1, [-], [_])="$3"]
-   )
+[
+    m4_ifval([$4],
+        [NUT_ARG_ENABLE_CUSTOM_DEFAULT_HELP([$1], [$2], [$3], [$4], [$4])],
+        [NUT_ARG_ENABLE_CUSTOM_DEFAULT_HELP([$1], [], [$2], [$3], [$3])])
 ])