Add a Syntastic plugin for Rust.

src/etc/vim/plugin/rust.vim

@@ -0,0 +1,22 @@
+" Vim syntastic plugin helper
+" Language:     Rust
+" Maintainer:   Andrew Gallant <jamslam@gmail.com>
+
+if exists("g:loaded_syntastic_rust_filetype")
+  finish
+endif
+let g:loaded_syntastic_rust_filetype = 1
+let s:save_cpo = &cpo
+set cpo&vim
+
+" This is to let Syntastic know about the Rust filetype.
+" It enables tab completion for the 'SyntasticInfo' command.
+" (This does not actually register the syntax checker.)
+if exists('g:syntastic_extra_filetypes')
+    call add(g:syntastic_extra_filetypes, 'rust')
+else
+    let g:syntastic_extra_filetypes = ['rust']
+endif
+
+let &cpo = s:save_cpo
+unlet s:save_cpo

src/etc/vim/syntax_checkers/rust/rustc.vim

@@ -0,0 +1,35 @@
+" Vim syntastic plugin
+" Language:     Rust
+" Maintainer:   Andrew Gallant <jamslam@gmail.com>
+"
+" See for details on how to add an external Syntastic checker:
+" https://github.com/scrooloose/syntastic/wiki/Syntax-Checker-Guide#external
+
+if exists("g:loaded_syntastic_rust_rustc_checker")
+    finish
+endif
+let g:loaded_syntastic_rust_rustc_checker = 1
+
+let s:save_cpo = &cpo
+set cpo&vim
+
+function! SyntaxCheckers_rust_rustc_GetLocList() dict
+    let makeprg = self.makeprgBuild({ 'args': '--parse-only' })
+
+    let errorformat  =
+        \ '%E%f:%l:%c: %\d%#:%\d%# %.%\{-}error:%.%\{-} %m,'   .
+        \ '%W%f:%l:%c: %\d%#:%\d%# %.%\{-}warning:%.%\{-} %m,' .
+        \ '%C%f:%l %m,' .
+        \ '%-Z%.%#'
+
+    return SyntasticMake({
+        \ 'makeprg': makeprg,
+        \ 'errorformat': errorformat })
+endfunction
+
+call g:SyntasticRegistry.CreateAndRegisterChecker({
+    \ 'filetype': 'rust',
+    \ 'name': 'rustc'})
+
+let &cpo = s:save_cpo
+unlet s:save_cpo