Add wrap files for xtensor-0.20.4

meson.build

@@ -0,0 +1,37 @@
+project('xtensor', 'cpp',
+        version:'0.20.4',
+        license:'BSD-3-Clause',
+        default_options : ['warning_level=3', 'cpp_std=c++14'])
+
+xtl_dep = dependency('xtl',
+    version: ['>=0.6.2', '<1.0.0'],
+    fallback : ['xtl', 'xtl_dep'],
+    required: false)
+
+json_dep = dependency('nlohmann_json',
+    version:'>=3.1.1',
+    fallback : ['nlohmann_json', 'nlohmann_json_dep'],
+    required: false)
+
+required_deps_found = xtl_dep.found()
+
+if get_option('XTENSOR_USE_XSIMD')
+    xsimd_dep = dependency('xsimd',
+        version: ['>=7.0.0', '<8.0.0'],
+        fallback : ['xsimd', 'xsimd_dep'],
+        required: false)
+    xtensor_cpp_arg = ['-DXTENSOR_USE_XSIMD']
+    required_deps_found = required_deps_found and xsimd_dep.found()
+else
+    xsimd_dep = dependency('', required: false) # aka "not found"
+    xtensor_cpp_arg = []
+endif
+
+if required_deps_found
+    xtensor_dep = declare_dependency(
+        include_directories:include_directories('include', is_system: true),
+        dependencies: [xtl_dep, json_dep, xsimd_dep],
+        compile_args: xtensor_cpp_arg)
+else
+    xtensor_dep = dependency('', required: false) # aka "not found"
+endif

meson_options.txt

@@ -0,0 +1 @@
+option('XTENSOR_USE_XSIMD', type: 'boolean', value: false, description: 'simd acceleration for xtensor')

upstream.wrap

@@ -0,0 +1,6 @@
+[wrap-file]
+directory=xtensor-0.20.4
+
+source_url=https://github.com/QuantStack/xtensor/archive/0.20.4.zip
+source_filename=xtensor-0.20.4.zip
+source_hash=7f142bb367ec14a058ae3290364407c9b4afd414d3be01b1827d4260545fa528