[flang] Unexpected compile time failure when resolving a reference to a defined assignment `ASSIGNMENT(=)`

[DanielCChen]

Consider the following code:

module m
  type dt
    integer i
  contains
    generic :: ASSIGNMENT(=) => assign
    procedure, pass :: assign => myassign
    generic :: ASSIGNMENT(=) => otherassign               !! If commented out, it compiles successfully
    procedure, pass :: otherassign => myassign            !! If commented out, it compiles successfully
  end type
contains
  subroutine myassign(x,y)
    class(dt), intent(out) :: x
    integer, intent(in) :: y
    x%i = y + 1
  end subroutine

  subroutine sub
    type(dt) xdt
    xdt = 5
  end subroutine
end module

Flang complains:

error: Semantic errors in assign08.f
./assign08.f:19:5: error: No intrinsic or user-defined ASSIGNMENT(=) matches operand types TYPE(dt) and INTEGER(4)
      xdt = 5
      ^^^^^^^

[llvmbot]

@llvm/issue-subscribers-flang-frontend

Author: Daniel Chen (DanielCChen)

Consider the following code: ``` module m type dt integer i contains generic :: ASSIGNMENT(=) => assign procedure, pass :: assign => myassign generic :: ASSIGNMENT(=) => otherassign !! If commented out, it compiles successfully procedure, pass :: otherassign => myassign !! If commented out, it compiles successfully end type contains subroutine myassign(x,y) class(dt), intent(out) :: x integer, intent(in) :: y x%i = y + 1 end subroutine

subroutine sub
type(dt) xdt
xdt = 5
end subroutine
end module

Flang complains:

error: Semantic errors in assign08.f
./assign08.f:19:5: error: No intrinsic or user-defined ASSIGNMENT(=) matches operand types TYPE(dt) and INTEGER(4)
xdt = 5
^^^^^^^

</details>

[klausler]

Where is otherassign defined?

EDIT: never mind, I see it

[klausler]

The error message will be improved, but the program is not valid. The assignment in question can be resolved to multiple specific bindings, and is ambiguous in a way that would be dangerous if either of them were to be overridden to a distinct subroutine in an extended type.

[DanielCChen]

The error message will be improved, but the program is not valid. The assignment in question can be resolved to multiple specific bindings, and is ambiguous in a way that would be dangerous if either of them were to be overridden to a distinct subroutine in an extended type.

1. The multiple specific binding all point to the same specific module procedure. They all get the same characteristics. The following example is compiled fine with Flang

module m
  type dt
    integer i
  contains
    procedure, pass :: assign => myassign
    procedure, pass :: otherassign => myassign
  end type
contains
  subroutine myassign(x,y)
    class(dt), intent(out) :: x
    integer, intent(in) :: y
    x%i = y + 1
  end subroutine
end

2. I am not sure how override would affect this. The overriding procedure would be a different specific module procedure that its passed-object would have the type of the extending type.

[klausler]

module m
  type t1
    integer n
   contains
    procedure :: binding1 => assign1
    procedure :: binding2 => assign1
    generic :: assignment(=) => binding1, binding2
  end type
  type, extends(t1) :: t2
   contains
    procedure :: binding2 => assign2
  end type
 contains
  subroutine assign1(lhs, rhs)
    class(t1), intent(out) :: lhs
    integer, intent(in) :: rhs
    lhs%n = rhs
  end
  subroutine assign2(lhs, rhs)
    class(t2), intent(out) :: lhs
    integer, intent(in) :: rhs
    lhs%n = rhs + 1
  end
end

program test
  use m
  type(t2) x
  x = 1 ! binding1 or binding2?
end

[DanielCChen]

module m
  type t1
    integer n
   contains
    procedure :: binding1 => assign1
    procedure :: binding2 => assign1
    generic :: assignment(=) => binding1, binding2
  end type
  type, extends(t1) :: t2
   contains
    procedure :: binding2 => assign2
  end type
 contains
  subroutine assign1(lhs, rhs)
    class(t1), intent(out) :: lhs
    integer, intent(in) :: rhs
    lhs%n = rhs
  end
  subroutine assign2(lhs, rhs)
    class(t2), intent(out) :: lhs
    integer, intent(in) :: rhs
    lhs%n = rhs + 1
  end
end

program test
  use m
  type(t2) x
  x = 1 ! binding1 or binding2?
end

Our implementation is doing first-one-wins as oppose to look up all the available binding names. If binding1 is specified first, we call assign1. If binding2 is specified first, we call assign2 instead.
I see your point now. Thanks!