Missed constant folding through control flow

[GINN-Imp]

https://godbolt.org/z/K5K6f9918
https://alive2.llvm.org/ce/z/SicZdr
The reduced IR is derived from https://github.com/verilog-to-routing/vtr-verilog-to-routing/blob/356d0047122531ffd8b2b7410f7f3c8c17db78e6/abc/src/base/abci/abcOrchestration.c#L2666

For the following code, through control flow, it can be deduced that %1 is always false in block %6, but LLVM fails to leverage this fact to optimize store i1 %1, ptr %0, align 4

define noundef i32 @src(ptr %0, i1 %1, i1 %2) local_unnamed_addr {
  br i1 %2, label %4, label %5

4:
  br i1 %1, label %common.ret, label %5

5:
  br i1 %2, label %6, label %common.ret

common.ret:
  ret i32 0

6:
  store i1 %1, ptr %0, align 4
  br label %common.ret
}

opt -O3:

define noundef i32 @src(ptr writeonly captures(none) %0, i1 %1, i1 %2) local_unnamed_addr #0 {
  %.not = xor i1 %2, true
  %4 = select i1 %2, i1 %1, i1 false
  %brmerge3 = or i1 %4, %.not
  br i1 %brmerge3, label %common.ret, label %5

common.ret:
  ret i32 0

5:
  store i1 %1, ptr %0, align 4
  br label %common.ret
}

expected:

define noundef i32 @src(ptr writeonly captures(none) %0, i1 %1, i1 %2) local_unnamed_addr #0 {
  %.not = xor i1 %2, true
  %4 = select i1 %2, i1 %1, i1 false
  %brmerge3 = or i1 %4, %.not
  br i1 %brmerge3, label %common.ret, label %5

common.ret:
  ret i32 0

5:
  store i1 false, ptr %0, align 4
  br label %common.ret
}

[houngkoungting]

Hi @GINN-Imp , I'd like to look into this issue and see if I can implement a fix.
Assigning to myself if that’s alright.

[GINN-Imp]

Hi @GINN-Imp , I'd like to look into this issue and see if I can implement a fix. Assigning to myself if that’s alright.

Thanks a lot, I really appreciate you taking the time to look into this!

[GINN-Imp]

Hi @GINN-Imp , I'd like to look into this issue and see if I can implement a fix. Assigning to myself if that’s alright.

I don’t seem to have the permissions to assign this — you may need to @ someone who can.

[houngkoungting]

Hey @GINN-Imp, just curious Did you run ipsccp to fold the constant before checking the store?
--before-----------------
define i32 @main() {
%ptr = alloca i1
%res = call i32 @src(ptr %ptr, i1 false, i1 true)
ret i32 0
}
define internal noundef i32 @src(ptr %0, i1 %1, i1 %2) local_unnamed_addr {
br i1 %2, label %4, label %5
4:
br i1 %1, label %common.ret, label %5
5:
br i1 %2, label %6, label %common.ret
common.ret:
ret i32 0
6:
store i1 %1, ptr %0, align 4
br label %common.ret
}
--after-----opt -passes='ipsccp' -S test.ll------------
define i32 @main() {
%ptr = alloca i1, align 1
%res = call i32 @src(ptr %ptr, i1 false, i1 true)
ret i32 0
}
define internal i32 @src(ptr nonnull %0, i1 %1, i1 %2) local_unnamed_addr {
br label %4
4: ; preds = %3
br label %5
5: ; preds = %4
br label %6
common.ret: ; preds = %6
ret i32 poison
6: ; preds = %5
store i1 false, ptr %0, align 4
br label %common.ret
}

[GINN-Imp]

Hey @GINN-Imp, just curious Did you run ipsccp to fold the constant before checking the store?

I didn't specifically execute this pass. I used the default optimization pipeline opt -O3.

[houngkoungting]

Thanks for the clarification!

I just ran opt -passes=ipsccp on the reduced IR, and it does successfully fold store i1 %1 into store i1 false.

It looks like this optimization is missed in the default -O3 pipeline because IPSCCPPass isn't included there. This might be worth addressing—either by adjusting the pipeline or enhancing other passes like InstCombine to catch such cases.

Happy to help investigate further if needed.

[GINN-Imp]

It looks like this optimization is missed in the default -O3 pipeline because IPSCCPPass isn't included there. This might be worth addressing—either by adjusting the pipeline or enhancing other passes like InstCombine to catch such cases.

Thank you very much for your investigation. In fact, IPSCCPPass is included in the -O3 pipeline, but the code has already been transformed into the following form before IPSCCPPass:

define noundef i32 @src(ptr %0, i1 %1, i1 %2) local_unnamed_addr {
  %.not = xor i1 %2, true
  %.not1 = xor i1 %1, true
  %brmerge = select i1 %.not, i1 true, i1 %.not1
  %brmerge.not = xor i1 %brmerge, true
  %brmerge3 = or i1 %brmerge.not, %.not
  br i1 %brmerge3, label %common.ret, label %4

common.ret:                                       ; preds = %3, %4
  ret i32 0

4:                                                ; preds = %3
  store i1 %1, ptr %0, align 4
  br label %common.ret
}

Because of this earlier transformation, IPSCCP no longer has the opportunity to optimize the original pattern. It seems that the simplest approach might indeed be, as you suggested, to enhance InstCombine.