Spiffs not work

[workpage2]

I am using esp32 + w5500. The output of the index.html file to the web site via spiffs does not work. Simple helloserver works. I used this construction in standard webserver.h + esp32 via WiFi. Everything works. Plz help.

#include <FS.h>  // Библиотека для работы с файловой системой
#include <SPIFFS.h>
#include <SPI.h>
#include <Ethernet.h>
bool tcp_session = false;
bool EthernetUsable = false;  // W5500 found??

#define W5500_RST_PORT   21
byte mac[] = {  0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED };
#define EthernetLinkUP_Retries  10  //

#include <EthernetWebServer.h>
EthernetWebServer HTTP(80);

void setup() 
{

Serial.begin(115200);                                                   // Инициализируем вывод данных на серийный порт со скоростью 9600 бод
  SPIFFS.begin();                                                       // Инициализируем работу с файловой системой                          

Serial.println("Used/default ESP32 pinout:");
Serial.print("MOSI:");
Serial.println(MOSI);
Serial.print("MISO:");
Serial.println(MISO);
Serial.print("SCK:");
Serial.println(SCK);
Serial.print("SS:");
Serial.println(SS);
//  Serial.println(RST);
Serial.print("Reset:");
Serial.println(W5500_RST_PORT);

SPI.begin();

Serial.println("Resetting WizNet for consistent results");
pinMode(W5500_RST_PORT, OUTPUT);
digitalWrite(W5500_RST_PORT, LOW);
delayMicroseconds(500);
digitalWrite(W5500_RST_PORT, HIGH);
delayMicroseconds(1000);

Ethernet.init(SS);

Serial.println("Starting ethernet");
Ethernet.begin(mac);
//Ethernet.begin(mac,ip);
//delay(1000);
vTaskDelay(1000 / portTICK_RATE_MS);

switch (Ethernet.hardwareStatus()) {
case EthernetNoHardware:
  Serial.println("Ethernet Hardware was not found, can't continue...");
  EthernetUsable = false;
  break;
case EthernetW5100:
  Serial.println("W5100 hardware found");
  EthernetUsable = true;
  break;
case EthernetW5200:
  Serial.println("W5200 hardware found");
  EthernetUsable = true;
  break;
case EthernetW5500:
  Serial.println("W5500 hardware found");
  EthernetUsable = true;
  break;
default:
  Serial.print("Undefined hardware found:");
  Serial.println(Ethernet.hardwareStatus());
  Serial.print("No Hardware value::");
  Serial.println(EthernetNoHardware);
  EthernetUsable = false;  // not acceptable

  break;
}

int retries = 0;
do {
//delay(500);
vTaskDelay(500 / portTICK_RATE_MS);

switch (Ethernet.linkStatus()) {
  case Unknown:
    Serial.println("Unknown link status");
    EthernetUsable = false;
    break;
  case LinkOFF:
    Serial.println("LinkOFF");
    EthernetUsable = false;
    break;
  case LinkON:
    Serial.println("LinkON");
    EthernetUsable = true;
    break;
  default:
    EthernetUsable = false;
    Serial.println("Undefined link status");
}
} while ( (Ethernet.linkStatus() != LinkON ) && retries++ < EthernetLinkUP_Retries );


if (EthernetUsable == true) {
// https://www.pjrc.com/arduino-ethernet-library-2-0-0/
Serial.print("LocalIP:");
Serial.println(Ethernet.localIP());

Serial.print("GW:");
Serial.println(Ethernet.gatewayIP());

Serial.print("Subnet Netmask:");
Serial.println(Ethernet.subnetMask());

Serial.print("DNS Server IP:");
Serial.println(Ethernet.dnsServerIP());

//Serial.print("MAC:");
//Serial.println(Ethernet.MACAddress());

}

HTTP.begin();

HTTP.on("/", [](){                                        
if(!handleFileRead(HTTP.uri()))                                       // Если функция handleFileRead (описана ниже) возвращает значение false в ответ на поиск файла в файловой системе
  HTTP.send(404, "text/plain", "Not Found");                        // возвращаем на запрос текстовое сообщение "File isn't found" с кодом 404 (не найдено)                  
});

HTTP.on("/index.html", [](){                                        
if(!handleFileRead(HTTP.uri()))                                       // Если функция handleFileRead (описана ниже) возвращает значение false в ответ на поиск файла в файловой системе
  HTTP.send(404, "text/plain", "Not Found");                        // возвращаем на запрос текстовое сообщение "File isn't found" с кодом 404 (не найдено)                  
});

HTTP.onNotFound([](){                                                 // Описываем действия при событии "Не найдено"
if(!handleFileRead(HTTP.uri()))                                       // Если функция handleFileRead (описана ниже) возвращает значение false в ответ на поиск файла в файловой системе
  HTTP.send(404, "text/plain", "Not Found");                        // возвращаем на запрос текстовое сообщение "File isn't found" с кодом 404 (не найдено)
});

}

void loop() {
HTTP.handleClient();  
}

bool handleFileRead(String path){                                       // Функция работы с файловой системой

//Serial.println(HTTP.uri());
if(path.endsWith("/")) path += "index.html";                          // Если устройство вызывается по корневому адресу, то должен вызываться файл index.html (добавляем его в конец адреса)
if(path.endsWith("/genaset")) path += ".html";
if(path.endsWith("/networksetting")) path += ".html";
String contentType = getContentType(path);                            // С помощью функции getContentType (описана ниже) определяем по типу файла (в адресе обращения) какой заголовок необходимо возвращать по его вызову
if(SPIFFS.exists(path)){                                              // Если в файловой системе существует файл по адресу обращения
File file = SPIFFS.open(path, "r");                                 //  Открываем файл для чтения
Serial.print("path=");
Serial.println(path);
Serial.print("filename=");
Serial.println(file.size());
Serial.print("content=");
Serial.println(contentType);
size_t sent = HTTP.streamFile(file, contentType);                   //  Выводим содержимое файла по HTTP, указывая заголовок типа содержимого contentType
file.close();                                                       //  Закрываем файл
return true;                                                        //  Завершаем выполнение функции, возвращая результатом ее исполнения true (истина)
}
return false;                                                         // Завершаем выполнение функции, возвращая результатом ее исполнения false (если не обработалось предыдущее условие)
}

String getContentType(String filename){                                 // Функция, возвращающая необходимый заголовок типа содержимого в зависимости от расширения файла
  if (filename.endsWith(".html")) return "text/html";                   // Если файл заканчивается на ".html", то возвращаем заголовок "text/html" и завершаем выполнение функции
  else if (filename.endsWith(".css")) return "text/css";                // Если файл заканчивается на ".css", то возвращаем заголовок "text/css" и завершаем выполнение функции
  else if (filename.endsWith(".js")) return "application/javascript";   // Если файл заканчивается на ".js", то возвращаем заголовок "application/javascript" и завершаем выполнение функции
  else if (filename.endsWith(".png")) return "image/png";               // Если файл заканчивается на ".png", то возвращаем заголовок "image/png" и завершаем выполнение функции
  else if (filename.endsWith(".jpg")) return "image/jpeg";              // Если файл заканчивается на ".jpg", то возвращаем заголовок "image/jpg" и завершаем выполнение функции
  else if (filename.endsWith(".gif")) return "image/gif";               // Если файл заканчивается на ".gif", то возвращаем заголовок "image/gif" и завершаем выполнение функции
  else if (filename.endsWith(".ico")) return "image/x-icon";            // Если файл заканчивается на ".ico", то возвращаем заголовок "image/x-icon" и завершаем выполнение функции
  return "text/plain";                                                  // Если ни один из типов файла не совпал, то считаем что содержимое файла текстовое, отдаем соответствующий заголовок и завершаем выполнение функции
}

[khoih-prog]

Hi,
The library is currently not intended and tested for ESP8266 and ESP32 as we normally use the their built-in WiFi features. And the issue also has nothing to do with this library.

1. Your issue can be conflicts between the Ethernet driver (using SPI) and SPIFFS (also using SPI). To verify this, you can start with the simplest code using both Ethernet and SPIFFS.
   If there is still problem, you can try these:

• Disable Ethernet by using Ethernet CS/SS whenever accessing SPIFFS
• If issue persists, open issue in related Ethernet library or ESP32/ESP8266

2. Use EEPROM if you still can not solve the issue.

3. You can have a look at ESP_FSWebServer to see SPIFFS and ESP32 are working very well together.

Sorry for not being able to help anymore as I'm so busy now. I'll definitely will have a look whenever I have time. Please post the result of your findings.

Regards,

[workpage2]

I made a small modification to check the simultaneous operation of spiffs and ethernet. I am reading a file into a string variable. And I bring to the site in a standard way. It works. Spiffs and ethernet work together. The "streamFile" function in the ethernetwebserver library does not work. At least on esp 32.
This cannot be seen as a permanent solution to the problem. Since the size of the string variable is only 2048 bytes.
You have a very good library, and I would like to use it. But without "streamFile" this is impossible to do.

bool handleFileRead(String path){                                       // Функция работы с файловой системой
  String temp;
  char temp2;
  //Serial.println(HTTP.uri());
  if(path.endsWith("/")) path += "index.html";                          // Если устройство вызывается по корневому адресу, то должен вызываться файл index.html (добавляем его в конец адреса)
  if(path.endsWith("/genaset")) path += ".html";
  if(path.endsWith("/networksetting")) path += ".html";
  String contentType = getContentType(path);                            // С помощью функции 
  getContentType (описана ниже) определяем по типу файла (в адресе обращения) какой заголовок необходимо возвращать по его вызову
  if(SPIFFS.exists(path)){                                              // Если в файловой системе существует файл по адресу обращения
    File file = SPIFFS.open(path, "r");                                 //  Открываем файл для чтения
    Serial.print("path=");
    Serial.println(path);
    Serial.print("filesize=");
    Serial.println(file.size());
    Serial.print("content=");
    Serial.println(contentType);
    while(file.available())
    {
        temp2=file.read();
        //Serial.write(temp2);
        temp=temp+temp2;
    }
    HTTP.send(200, contentType, temp); 
    //size_t sent = HTTP.streamFile(file, contentType);                   //  Выводим содержимое файла по HTTP, указывая заголовок типа содержимого contentType
    file.close();                                                       //  Закрываем файл
    return true;                                                        //  Завершаем выполнение функции, возвращая результатом ее исполнения true (истина)
  }
  return false;                                                         // Завершаем выполнение функции, возвращая результатом ее исполнения false (если не обработалось предыдущее условие)
}

[khoih-prog]

That's good news.
How do you connect W5500 to ESP32? Please give the pin-pin connections so that I can reproduce and test.
I'll try to test, find out the root cause and solve the issue to provide support to ESP32/ESP8266 in the very near future. Hopefully everything can be solved.

I already post the code to increase the 2K buffer to 4K/8K/16K in W5x00 in BlynkEthernet_WM: to increase Ethernet buffer.
You can give it a try.

Regards,

[workpage2]

MOSI:23
MISO:19
SCK:18
SS:5
RESET:21

[workpage2]

Good day. Any news?

[khoih-prog]

Did you try the new Ethernet lib with 2+K buffer fix as in

I already post the code to increase the 2K buffer to 4K/8K/16K in W5x00 in BlynkEthernet_WM: to increase Ethernet buffer.

I send 2+K strings using the modified Ethernet library OK. You can test using the examples in

BlynkEthernet_WM Library

Pls inform if this is OK.

I still haven't worked on your issue with ESP32 yet as the lib is not original made for ESPs. I'll do it soon.

The 2+K string problem can possibly happen because the way you use local var too large (you have to test to be sure if the heap/stack OK). I got similar problem with some boards and solve by moving very long local vars to global.

bool handleFileRead(String path)
{                                       
  // File system function
  String temp;
  ...
}

Try somethng like this to see if it's better

String temp;
bool handleFileRead(String path)
{                                       
   // File system function
  ...
}

[workpage2]

My webpage is over 60k. Increasing the buffer will not solve the problem. But tomorrow I will definitely try a global variable and write the result here.

[khoih-prog]

Also see in my ESP_WiFiManager Library

ESP_FSWebServer example

how to stream large files directly, without reading every byte into String buffer, with FSWebServer.

bool handleFileRead(String path) {
  DBG_OUTPUT_PORT.println("handleFileRead: " + path);
  if (path.endsWith("/")) {
    path += "index.htm";
  }
  String contentType = getContentType(path);
  String pathWithGz = path + ".gz";
  if (filesystem->exists(pathWithGz) || filesystem->exists(path)) {
    if (filesystem->exists(pathWithGz)) {
      path += ".gz";
    }
    File file = filesystem->open(path, "r");
    server.streamFile(file, contentType);
    file.close();
    return true;
  }
  return false;
}

But that is for ESP8266/ESP32WebServer. I still haven't tested with this EthernetServer library to see it's working or not.
You can try this with this EthernetWebServer library
The function prototype and implementation is

template<typename T> size_t streamFile(T &file, const String& contentType);
{
      setContentLength(file.size());
      if (String(file.name()).endsWith(".gz") &&
          contentType != "application/x-gzip" &&
          contentType != "application/octet-stream") {
        sendHeader("Content-Encoding", "gzip");
      }
      send(200, contentType, "");
      return _currentClient.write(file);
}

and use exactly the same to the previous example

EthernetWebServer server(80);
.....
bool handleFileRead(String path) {
  DBG_OUTPUT_PORT.println("handleFileRead: " + path);
  if (path.endsWith("/")) {
    path += "index.htm";
  }
  String contentType = getContentType(path);
  String pathWithGz = path + ".gz";
  if (filesystem->exists(pathWithGz) || filesystem->exists(path)) {
    if (filesystem->exists(pathWithGz)) {
      path += ".gz";
    }
    File file = filesystem->open(path, "r");
    server.streamFile(file, contentType);
    file.close();
    return true;
  }
  return false;
}

[khoih-prog]

It seems that ESP32 WebServer has severe bug in handling large file, using either SPIFFS or FFat.
So this is not something relating to Filesystem, I think, but the WebServer and/or other system code.

You can test using ESP32 FSBrowser example using the data in this directory

Test data for ESP_FSWebServer

FS File: /CanadaFlag_1.png, size: 40.25KB
FS File: /CanadaFlag_2.png, size: 8.12KB
FS File: /CanadaFlag_3.jpg, size: 10.89KB

Testing files

• CanadaFlag_1.png file size 40.25KB will hang the system.

• CanadaFlag_2.png file size 8.12KB is OK

• CanadaFlag_3.jpg file size 10.89KB is OK

You can upload the files to ESP32 filesystem (SPIFFS or FFat) as follows

1. upload the contents of the data folder with MkSPIFFS Tool ("ESP32 Sketch Data Upload" in Tools menu in Arduino IDE) or
2. you can upload the contents of a folder if you change dir into the local folder and run the following command in Ubuntu
$  for file in `ls -A1`; do curl -F "file=@$PWD/$file" esp32fs.local/edit; done

Testing the similar example for ESP8266 is OK with that large file using these examples

1. ESP_FSWebServer example for ESP8266
2. ESP8266 FSBrowser example

It's possibly some bugs in ESP32 WebServer / system library code, but I don't have time to follow up with this.

You can open an issue in ESP32 support, mentioned details about your test with

1. ESP32 FSBrowser example => ESP32 WebServer hangs up

2. ESP8266 FSBrowser example => ESP8266 WebServer displays OK and still survives

I'm sorry I can't spend more time on this matter. Please open issue on ESP32, and give me a link / update.

[workpage2]

I tried using global variables. This also does not work.
I also found this: sirleech/Webduino#69 .
I think there is a conflict on the spi bus. Tell me how to send data from a file one byte or a small packet? That would solve the problem.

[khoih-prog]

I already update the version to v1.0.6 to support ESP32 and ESP8266. Your contribution is noted in README by initiating the work on ESP32/ESP8266.

Thanks to Vladimir to initiate the work on ESP32 in Spiffs not work Issue #2

[workpage2]

I checked the new library 1.0.6
SPIFFS does not work. (streamFile)

[khoih-prog]

I don't expect v1.0.6 to work in your case. Just for normal smaller file applications only.

About SPI

The SPI bus is designed for 1 master and multiple slaves and you have to check if

1. The CS/SS are separate for each slave. Did you check if you do correctly?
2. The SPI driver / firmware are written not fully correctly, not taking care of multiple-slave scenarios or permitting one slave to monopolize the bus => other slaves will be dead while waiting for attention. I'm afraid this is the case.
3. Hardwarewise, a tri-state chip for MOSI/MISO signals of the SPI slave so you can share the SPI bus with other devices. Whenever the SPI slave is not selected by CS/SS, the slave's MOSI/MISO input/output must be in tri-state mode to avoid interference with SPI communications.

That's why the ESP8266 is working OK with the same hardware / software, while ESP32 can't.

Did you have time to verify the ESP32 and ESP8266 examples in my previous posts

1. ESP32 FSBrowser example
2. ESP_FSWebServer example for ESP8266
3. ESP8266 FSBrowser example

to have some ideas, then post issue on ESP32 so that someone will have a look?

You can also have some easy try with ESP8266 using the same code / W5500 and SPIFFS to see how it handles large files.

[khoih-prog]

Hi @workpage2 , @tcpipchip

Good news. I think I find out the problem now.

As you see in

Each SPI slave must use a different CS/SS pin, and pin SS in ESP32 has been use by Flash/SPIFFS/EEPROM and defined as SPISS. That's why we have all conflict issues so far. Sending a small piece of data might be OK, but larger data will create SPI bus conflict problem.
Just change the pin to another one. I tested with GPIO13 and OK (many more other pins can be OK as well)

//KH for ESP32
#elif defined(ESP32)
//pin SS already defined in ESP32 as pin 5, don't use this as conflict with SPIFFS, EEPROM, etc.
// Use in GPIO13
#warning w5100.cpp Use ESP32, change SS_PIN_DEFAULT to GPIO13, MOSI(23), MISO(19), SCK(18)
#define SS_PIN_DEFAULT  13    //SS
///////

Please test and inform me the result.