Bootstrap

.envrc

@@ -0,0 +1 @@
+use flake

.gitignore

@@ -0,0 +1,3 @@
+target
+result*
+.direnv

Cargo.toml

@@ -0,0 +1,3 @@
+[workspace]
+
+members = ["tinyboot"]

default.nix

@@ -0,0 +1,14 @@
+{ pkgsStatic, lib, ... }:
+let
+  cargoTOML = lib.importTOML ./tinyboot/Cargo.toml;
+in
+pkgsStatic.rustPlatform.buildRustPackage {
+  pname = cargoTOML.package.name;
+  version = cargoTOML.package.version;
+  src = ./.;
+  buildAndTestSubdir = "tinyboot";
+  cargoLock.lockFile = ./Cargo.lock;
+  postInstall = ''
+    ln -s $out/bin/tinyboot $out/init
+  '';
+}

flake.nix

@@ -0,0 +1,31 @@
+{
+  description = "A small '/init' for linuxboot";
+  inputs = {
+    nixpkgs.url = "nixpkgs/nixos-unstable";
+  };
+  outputs = inputs: with inputs;
+    let
+      forAllSystems = f: nixpkgs.lib.genAttrs [ "x86_64-linux" "aarch64-linux" ] (system: f {
+        inherit system;
+        pkgs = import nixpkgs { inherit system; overlays = [ self.overlays.default ]; };
+      });
+    in
+    {
+      overlays.default = final: prev: {
+        tinyboot = prev.callPackage ./. { };
+        tinyboot-initramfs = prev.callPackage ./initramfs.nix {
+          inherit (final) tinyboot;
+        };
+      };
+      devShells = forAllSystems ({ pkgs, ... }: {
+        default = pkgs.mkShell {
+          buildInputs = with pkgs; [ rustc cargo ];
+        };
+      });
+      packages = forAllSystems ({ pkgs, ... }: {
+        default = pkgs.tinyboot;
+        initramfs = pkgs.tinyboot-initramfs;
+        test = pkgs.callPackage ./test.nix { };
+      });
+    };
+}

initramfs.nix

@@ -0,0 +1,16 @@
+{ lib, buildEnv, runCommand, cpio, xz, pkgsStatic, tinyboot, compressed ? true, ... }:
+let
+  paths = [ /*tinyboot*/ pkgsStatic.busybox ];
+in
+runCommand "tinyboot-initramfs"
+{ nativeBuildInputs = [ cpio ] ++ (lib.optional compressed xz); } ''
+  mkdir -p root; ${lib.concatMapStringsSep "; " (p: "cp -r ${p}/. root") paths}
+  pushd root &&
+    find . -print0 | cpio --null --create --format=newc >../initramfs.cpio &&
+    popd
+  ${if compressed then ''
+  xz --check=crc32 --lzma2=dict=512KiB <initramfs.cpio >$out
+  '' else ''
+  cp initramfs.cpio $out
+  ''}
+''

test.nix

@@ -0,0 +1,14 @@
+{ nixosTest, lib, tinyboot-initramfs, ... }:
+nixosTest {
+  name = "tinyboot";
+  nodes.machine = {
+    virtualisation.qemu.options = lib.mkAfter [
+      "-initrd ${tinyboot-initramfs}"
+      "-append \"console=ttyS0 init=/init\""
+    ];
+  };
+  testScript = ''
+    machine.start()
+    machine.wait_for_console_text("Hello, world!")
+  '';
+}

tinyboot/Cargo.toml

@@ -0,0 +1,8 @@
+[package]
+name = "tinyboot"
+version = "0.1.0"
+edition = "2021"
+
+# See more keys and their definitions at https://doc.rust-lang.org/cargo/reference/manifest.html
+
+[dependencies]

tinyboot/src/main.rs

@@ -0,0 +1,3 @@
+fn main() {
+    println!("Hello, world!");
+}