Switch from flycheck to flymake (but with flymake-flycheck)

README.md

@@ -28,9 +28,9 @@ in the approximate order of how much I use them, from most to least:
 
 In particular, there's a nice config for *autocompletion* with
 [company](https://company-mode.github.io/), and
-[flycheck](http://www.flycheck.org) is used to immediately highlight
-syntax errors in Ruby, Python, Javascript, Haskell and a number of
-other languages.
+`flymake` (re-using backends from [flycheck](http://www.flycheck.org))
+is used to immediately highlight syntax errors in Ruby, Python,
+Javascript, Haskell and a number of other languages.
 
 ## Supported Emacs versions
 

init.el

@@ -60,7 +60,7 @@
 (require 'init-grep)
 (require 'init-uniquify)
 (require 'init-ibuffer)
-(require 'init-flycheck)
+(require 'init-flymake)
 
 (require 'init-recentf)
 (require 'init-minibuffer)

lisp/init-flymake.el

@@ -0,0 +1,41 @@
+;;; init-flymake.el --- Configure Flymake global behaviour -*- lexical-binding: t -*-
+;;; Commentary:
+;;; Code:
+
+(with-eval-after-load 'flymake
+  (defun sanityinc/eldoc-flymake-first ()
+    "Gives flymake's eldoc function priority in the minibuffer."
+    (when flymake-mode
+      (setq-local eldoc-documentation-functions
+                  (cons 'flymake-eldoc-function
+                        (delq 'flymake-eldoc-function eldoc-documentation-functions)))))
+
+  (add-hook 'flymake-mode-hook 'sanityinc/eldoc-flymake-first))
+
+
+;; Use flycheck checkers with flymake, to extend its coverage
+(when (maybe-require-package 'flymake-flycheck)
+  ;; Disable flycheck checkers for which we have flymake equivalents
+  (with-eval-after-load 'flycheck
+    (setq-default flycheck-disabled-checkers
+                  (append (default-value 'flycheck-disabled-checkers)
+                          '(emacs-lisp emacs-lisp-checkdoc emacs-lisp-package))))
+
+  (defun sanityinc/enable-flymake-flycheck ()
+    (setq-local flymake-diagnostic-functions
+                (append flymake-diagnostic-functions
+                        (flymake-flycheck-all-chained-diagnostic-functions))))
+
+  (add-hook 'flymake-mode-hook 'sanityinc/enable-flymake-flycheck)
+  (add-hook 'prog-mode-hook 'flymake-mode)
+  (add-hook 'text-mode-hook 'flymake-mode))
+
+(with-eval-after-load 'flymake
+  ;; Provide some flycheck-like bindings in flymake mode to ease transition
+  (define-key flymake-mode-map (kbd "C-c ! n") 'flymake-goto-next-error)
+  (define-key flymake-mode-map (kbd "C-c ! p") 'flymake-goto-prev-error)
+  (define-key flymake-mode-map (kbd "C-c ! c") 'flymake-start))
+
+
+(provide 'init-flymake)
+;;; init-flymake.el ends here

lisp/init-lisp.el

@@ -270,11 +270,8 @@ there is no current file, eval the current buffer."
   (add-hook 'emacs-lisp-mode-hook 'highlight-quoted-mode))
 
 
-(when (maybe-require-package 'flycheck)
-  (require-package 'flycheck-package)
-  (with-eval-after-load 'flycheck
-    (with-eval-after-load 'elisp-mode
-      (flycheck-package-setup))))
+(when (maybe-require-package 'package-lint-flymake)
+  (add-hook 'emacs-lisp-mode-hook #'package-lint-flymake-setup))