Powerful p-Groups Feature

doc/ref/groups.xml

@@ -349,12 +349,14 @@ as they depend on a parameter.
 <#Include Label="IsFinitelyGeneratedGroup">
 <#Include Label="IsSubsetLocallyFiniteGroup">
 <#Include Label="IsPGroup">
+<#Include Label="IsPowerfulPGroup">
 <#Include Label="PrimePGroup">
 <#Include Label="PClassPGroup">
 <#Include Label="RankPGroup">
 <#Include Label="IsPSolvable">
 <#Include Label="IsPNilpotent">
 
+
 </Section>
 
 

lib/grp.gd

@@ -434,8 +434,37 @@ InstallFactorMaintenance( IsPGroup,
 
 InstallTrueMethod( IsPGroup, IsGroup and IsTrivial );
 InstallTrueMethod( IsPGroup, IsGroup and IsElementaryAbelian );
+#############################################################################
+##
+#P  IsPowerfulPGroup( <G> ) . . . . . . . . . is a group a powerful p-group ?
+##
+##  <#GAPDoc Label="IsPowerfulPGroup">
+##  <ManSection>
+##  <Prop Name="IsPowerfulPGroup" Arg='G'/>
+##
+##  <Description>
+##  <Index Key="PowerfulPGroup">Powerful <M> p</M>-group</Index>
+##  A finite p-group <A>G</A> is said to be a Powerful <M>p</M>-group if the 
+##  commutator subgroup <M>[<A>G</A>,<A>G</A>]</M> is contained in
+##  <M><A>G</A>^{p}</M> if the prime <M>p</M> is odd, or if
+##  <M>[<A>G</A>,<A>G</A>]</M> is contained in <M><A>G</A>^{4}</M> 
+##  if<M> p = 2</M>. The subgroup <M><A>G</A>^{p}</M> is called the first 
+##  Agemo subgroup, (see&nbsp;<Ref Func="Agemo"/>).
+##  <Ref Prop="IsPowerfulPGroup"/> returns <K>true</K> if <A>G</A> is a 
+##  powerful <M>p</M>-group, and <K>false</K> otherwise. 
+##  <E>Note: </E>This function returns <K>true</K> if <A>G</A> is the trivial 
+##  group.
+##  </Description>
+##  </ManSection>
+##  <#/GAPDoc>
+##
+DeclareProperty( "IsPowerfulPGroup", IsGroup );
 
-
+#Quotients of powerful of powerful p groups are powerful
+InstallFactorMaintenance( IsPowerfulPGroup,
+    IsPowerfulPGroup, IsGroup, IsGroup );
+#abelian p-groups are powerful
+InstallTrueMethod( IsPowerfulPGroup, IsPGroup and IsAbelian );
 #############################################################################
 ##
 #A  PrimePGroup( <G> )

lib/grp.gi

@@ -236,6 +236,58 @@ InstallMethod( IsPGroup,
       return IS_PGROUP_FOR_NILPOTENT( G );
     fi;
     end );
+#############################################################################
+##
+#M  IsPowerfulPGroup( <G> ) . . . . . . . . . . is a group a powerful p-group ?
+##
+InstallMethod( IsPowerfulPGroup,
+    "use characterisation of powerful p-groups based on rank ",
+    [ IsGroup and HasRankPGroup and HasComputedOmegas ],
+     function( G )
+    local p;
+    if (IsTrivial(G)) then
+	return true;
+    else
+	p:=PrimePGroup(G);
+	#We use the less known characterisation of powerful p groups
+	# for p>3 by Jon Gonzalez-Sanchez, Amaia Zugadi-Reizabal
+	# can be found in 'A characterization of powerful p-groups'
+	if (p>3) then
+		if (RankPGroup(G)=Log(Order(Omega(G,p)),p)) then
+			return true;
+		else
+			return false;
+		fi;
+	else
+	TryNextMethod();
+	fi;
+    fi;
+
+
+
+    end);
+
+
+InstallMethod( IsPowerfulPGroup,
+    "generic method checks inclusion of commutator subgroup in agemo subgroup",
+    [ IsGroup ],
+     function( G )
+    local p;
+    if IsPGroup( G ) = false then
+      ErrorNoReturn( "<G> must be a p-group" );
+    elif IsTrivial(G) then
+      return true;
+
+    else
+
+      p:=PrimePGroup(G);
+      if p = 2 then 
+        return IsSubgroup(Agemo(G,2,2),DerivedSubgroup( G ));
+      else 
+        return IsSubgroup(Agemo(G,p), DerivedSubgroup( G ));
+      fi; 
+    fi;
+    end);                                              
 
 
 #############################################################################
@@ -1043,6 +1095,17 @@ function(G)
     return SubgroupNC(G, gen);
 end);
 
+InstallMethod( FrattiniSubgroup, "for powerful p-groups",
+            [ IsPGroup and IsPowerfulPGroup and HasComputedAgemos ],100,
+function(G)
+    local p;
+#If the group is powerful and has computed agemos, then no work needs
+#to be done, since FrattiniSubgroup(G)=Agemo(G,p) in this case
+#by properties of powerful p-groups.
+	p:=PrimePGroup(G);
+	return Agemo(G,p);
+end);
+
 InstallMethod( FrattiniSubgroup, "for nilpotent groups",
             [ IsGroup and IsNilpotentGroup ],
 function(G)

tst/testinstall/pgroups.tst

@@ -168,4 +168,36 @@ gap> ForAll(PrimeDivisors(s), p -> HasPrimePGroup(SylowSubgroup(G, p)));
 true
 gap> ForAll(PrimeDivisors(s), p -> p=PrimePGroup(SylowSubgroup(G, p)));
 true
+gap> G:=CyclicGroup(9);;
+gap> HasIsPowerfulPGroup(G);
+true
+gap> IsPowerfulPGroup(G);
+true
+gap> G:=CyclicGroup(10);;
+gap> IsPowerfulPGroup(G);
+Error, <G> must be a p-group
+gap> G:=SmallGroup(243,11);;
+gap> HasIsPowerfulPGroup(G);
+false
+gap> IsPowerfulPGroup(G);
+true
+gap> N:=NormalSubgroups(G)[3];;
+gap> H:=FactorGroup(G,N);;
+gap> HasIsPowerfulPGroup(H);
+true
+gap> IsPowerfulPGroup(H);
+true
+gap> myList:=AllSmallGroups(5^4);;
+gap> Length(Filtered(myList,g->IsPowerfulPGroup(g)));
+9
+gap> newList:=AllSmallGroups(5^4);;
+gap> for g in newList do
+> RankPGroup(g);
+> Agemo(g,5);
+> od;
+gap> Length(Filtered(newList,g->IsPowerfulPGroup(g)));
+9
+gap> myList:=AllSmallGroups(2^4);;
+gap> Length(Filtered(myList,g->IsPowerfulPGroup(g)));
+6
 gap> STOP_TEST("pgroups.tst", 10000);