SPARQL null values for labels

[acassaignemondeca]

I have labels in my data but this query:

PREFIX skos:<http://www.w3.org/2004/02/skos/core#>
CONSTRUCT {
<http://www.eionet.europa.eu/gemet/concept/4799> <http://www.w3.org/2004/02/skos/core#broader> ?directBroader.
?broader <http://www.w3.org/2000/01/rdf-schema#label> ?broaderLabel1.
?broader <http://www.w3.org/2000/01/rdf-schema#label> ?broaderLabel2.
?broader <http://www.w3.org/1999/02/22-rdf-syntax-ns#type> ?broaderType.
?broader <http://www.w3.org/2004/02/skos/core#broader> ?broaderBroader.
}
FROM <gemet>
WHERE {
<http://www.eionet.europa.eu/gemet/concept/4799> <http://www.w3.org/2004/02/skos/core#broader> ?directBroader.
<http://www.eionet.europa.eu/gemet/concept/4799> skos:broader+ ?broader.
OPTIONAL { ?broader <http://www.w3.org/2004/02/skos/core#prefLabel> ?broaderLabel1. }
OPTIONAL { ?broader <http://www.w3.org/2000/01/rdf-schema#label> ?broaderLabel2. }
OPTIONAL { ?broader <http://www.w3.org/2004/02/skos/core#broader> ?broaderBroader. }
OPTIONAL { ?broader <http://www.w3.org/1999/02/22-rdf-syntax-ns#type> ?broaderType. }
}

gives me:

{
     "@id": "http://www.eionet.europa.eu/gemet/concept/1890",
     "http://www.w3.org/2000/01/rdf-schema#label": null,
     "http://www.w3.org/1999/02/22-rdf-syntax-ns#type": {
       "@id": "skos:Concept"
     },
     "skos:broader": {
       "@id": "http://www.eionet.europa.eu/gemet/concept/6323"
     }
   },
   {
     "@id": "http://www.eionet.europa.eu/gemet/concept/4799",
     "skos:broader": {
       "@id": "http://www.eionet.europa.eu/gemet/concept/1890"
     }
   },
   {
     "@id": "http://www.eionet.europa.eu/gemet/concept/5914",
     "http://www.w3.org/2000/01/rdf-schema#label": null,
     "http://www.w3.org/1999/02/22-rdf-syntax-ns#type": {
       "@id": "skos:Concept"
     },
     "skos:broader": {
       "@id": "http://www.eionet.europa.eu/gemet/concept/892"
     }
   },
   [...]

Label results are null.

[dpetran]

For this style of query where you unify multiple terms into a single variable you'll want to use UNION instead of OPTIONAL.

This version should produce the results you are looking for:

PREFIX skos:<http://www.w3.org/2004/02/skos/core#>
CONSTRUCT {
    <http://www.eionet.europa.eu/gemet/concept/4799> <http://www.w3.org/2004/02/skos/core#broader> ?directBroader.
    # > only use ?label in the CONSTRUCT template <
    ?broader <http://www.w3.org/2000/01/rdf-schema#label> ?label.
    ?broader <http://www.w3.org/1999/02/22-rdf-syntax-ns#type> ?broaderType.
    ?broader <http://www.w3.org/2004/02/skos/core#broader> ?broaderBroader.
}
FROM <gemet>
WHERE {
    <http://www.eionet.europa.eu/gemet/concept/4799> <http://www.w3.org/2004/02/skos/core#broader> ?directBroader.
    <http://www.eionet.europa.eu/gemet/concept/4799> skos:broader+ ?broader.
    # > Bind both skos:prefLabel and rdfs:label to ?label <
    { ?broader <http://www.w3.org/2004/02/skos/core#prefLabel> ?label. } UNION
    { ?broader <http://www.w3.org/2000/01/rdf-schema#label> ?label. }
    OPTIONAL { ?broader <http://www.w3.org/2004/02/skos/core#broader> ?broaderBroader. }
    OPTIONAL { ?broader <http://www.w3.org/1999/02/22-rdf-syntax-ns#type> ?broaderType. }
}