Add function to normalise a set of weight values so that they sum to 1

[delphidabbler]

The following routine is proposed:

function NormaliseByWeight(const Weights: array of Double):
  Types.TDoubleDynArray;
var
  Weight: Double;
  WeightSum: Double;
  Idx: Integer;
begin
  if (System.Length(Weights) = 0) then
    raise SysUtils.EArgumentException.Create('Array of weights is empty');
  WeightSum := 0.0;
  for Weight in Weights do
  begin
    if Math.Sign(Weight) = Math.NegativeValue then
      raise SysUtils.EArgumentException.Create('Weights must all be >= 0');
    WeightSum := WeightSum + Weight;
  end;
  if Math.IsZero(WeightSum) then
    raise SysUtils.EArgumentException.Create('Sum of weights can''t be zero');
  System.SetLength(Result, System.Length(Weights));
  for Idx := 0 to Pred(System.Length(Weights)) do
    Result[Idx] := Weights[Idx] / WeightSum;
end;

[delphidabbler]

A proposal for this function was original made in issue #31

[delphidabbler]

Also add a Rescale function that scales values to the interval [0..1].

[delphidabbler]

Also add a Rescale function that scales values to the interval [0..1].

Actually naming this RescaleRange.

[delphidabbler]

It may also be useful to add a function RangeOf that calculates and returns the length of the range of values in an array:

function RangeOf(const A: array of Double): Double; overload;
begin
  Assert(Length(A) > 0);
  var MinValue := A[0];
  var MaxValue := A[0];
  for var Elem in A do
  begin
    if Elem > MaxValue then
      MaxValue := Elem
    else if Elem < MinValue then
      MinValue := Elem;
  end;
  Result := MaxValue - MinValue;
  // Ensure that exactly zero is returned when MaxValue = MinValue
  if Math.IsZero(Result) then
    Result := 0.0;
end;

function RangeOf(const A: array of Integer): Integer; overload;
begin
  Assert(Length(A) > 0);
  var MinValue := A[0];
  var MaxValue := A[0];
  for var Elem in A do
  begin
    if Elem > MaxValue then
      MaxValue := Elem
    else if Elem < MinValue then
      MinValue := Elem;
  end;
  Result := MaxValue - MinValue;
end;