Completion doesn't work with zsh

[iPalash]

Version

0.16.0

Description

The cli client completion doesn't work in zsh shell owning to some compatibility issues in the cortex completion script. Throws an error -> bad option: -t

Steps to reproduce

1. Run source source <(cortex completion) in a zsh shell

Expected behavior

cli autocomplete should work with zsh.

Actual behavior

Since the script failed, no autocomplete with cli in zsh

Screenshots

[deliahu]

@iPalash thanks for creating this issue! Currently we only support bash completion, but we will look into supporting zsh for our next release

[deliahu]

@iPalash I am working on adding this now; does this file work on your system? You should be able to copy-paste this into a file named _cortex in your fpath, or paste it into any file (e.g. cortex-completions.sh) and run source cortex-completions.sh.

#compdef _cortex cortex


function _cortex {
  local -a commands

  _arguments -C \
    "1: :->cmnds" \
    "*::arg:->args"

  case $state in
  cmnds)
    commands=(
      "deploy:create or update apis"
      "refresh:restart all replicas for an api (witout downtime)"
      "get:get information about apis"
      "logs:stream logs from an api"
      "predict:make a prediction request using a json file"
      "delete:delete an api"
      "cluster:manage a cluster"
      "version:print the cli and cluster versions"
      "env:manage environments"
      "completion:generate shell completion scripts"
      "help:Help about any command"
    )
    _describe "command" commands
    ;;
  esac

  case "$words[1]" in
  deploy)
    _cortex_deploy
    ;;
  refresh)
    _cortex_refresh
    ;;
  get)
    _cortex_get
    ;;
  logs)
    _cortex_logs
    ;;
  predict)
    _cortex_predict
    ;;
  delete)
    _cortex_delete
    ;;
  cluster)
    _cortex_cluster
    ;;
  version)
    _cortex_version
    ;;
  env)
    _cortex_env
    ;;
  completion)
    _cortex_completion
    ;;
  help)
    _cortex_help
    ;;
  esac
}

function _cortex_deploy {
  _arguments \
    '(-e --env)'{-e,--env}'[environment to use]:' \
    '(-f --force)'{-f,--force}'[override the in-progress api update]' \
    '(-y --yes)'{-y,--yes}'[skip prompts]'
}

function _cortex_refresh {
  _arguments \
    '(-e --env)'{-e,--env}'[environment to use]:' \
    '(-f --force)'{-f,--force}'[override the in-progress api update]'
}

function _cortex_get {
  _arguments \
    '(-e --env)'{-e,--env}'[environment to use]:' \
    '(-w --watch)'{-w,--watch}'[re-run the command every second]'
}

function _cortex_logs {
  _arguments \
    '(-e --env)'{-e,--env}'[environment to use]:'
}

function _cortex_predict {
  _arguments \
    '(-e --env)'{-e,--env}'[environment to use]:'
}

function _cortex_delete {
  _arguments \
    '(-e --env)'{-e,--env}'[environment to use]:' \
    '(-f --force)'{-f,--force}'[delete the api without confirmation]' \
    '(-c --keep-cache)'{-c,--keep-cache}'[keep cached data for the api]'
}


function _cortex_cluster {
  local -a commands

  _arguments -C \
    "1: :->cmnds" \
    "*::arg:->args"

  case $state in
  cmnds)
    commands=(
      "up:spin up a cluster"
      "info:get information about a cluster"
      "update:update a cluster"
      "down:spin down a cluster"
    )
    _describe "command" commands
    ;;
  esac

  case "$words[1]" in
  up)
    _cortex_cluster_up
    ;;
  info)
    _cortex_cluster_info
    ;;
  update)
    _cortex_cluster_update
    ;;
  down)
    _cortex_cluster_down
    ;;
  esac
}

function _cortex_cluster_up {
  _arguments \
    '(-c --config)'{-c,--config}'[path to a cluster configuration file]:filename:_files -g "yaml" -g "yml"' \
    '(-e --env)'{-e,--env}'[environment to configure]:' \
    '(-y --yes)'{-y,--yes}'[skip prompts]'
}

function _cortex_cluster_info {
  _arguments \
    '(-c --config)'{-c,--config}'[path to a cluster configuration file]:filename:_files -g "yaml" -g "yml"' \
    '(-e --env)'{-e,--env}'[environment to configure]:' \
    '(-d --debug)'{-d,--debug}'[save the current cluster state to a file]' \
    '(-y --yes)'{-y,--yes}'[skip prompts]'
}

function _cortex_cluster_update {
  _arguments \
    '(-c --config)'{-c,--config}'[path to a cluster configuration file]:filename:_files -g "yaml" -g "yml"' \
    '(-e --env)'{-e,--env}'[environment to configure]:' \
    '(-y --yes)'{-y,--yes}'[skip prompts]'
}

function _cortex_cluster_down {
  _arguments \
    '(-c --config)'{-c,--config}'[path to a cluster configuration file]:filename:_files -g "yaml" -g "yml"' \
    '(-y --yes)'{-y,--yes}'[skip prompts]'
}

function _cortex_version {
  _arguments \
    '(-e --env)'{-e,--env}'[environment to use]:'
}


function _cortex_env {
  local -a commands

  _arguments -C \
    "1: :->cmnds" \
    "*::arg:->args"

  case $state in
  cmnds)
    commands=(
      "configure:configure an environment"
      "list:list all configured environments"
      "default:set the default environment"
      "delete:delete an environment configuration"
    )
    _describe "command" commands
    ;;
  esac

  case "$words[1]" in
  configure)
    _cortex_env_configure
    ;;
  list)
    _cortex_env_list
    ;;
  default)
    _cortex_env_default
    ;;
  delete)
    _cortex_env_delete
    ;;
  esac
}

function _cortex_env_configure {
  _arguments \
    '(-p --provider)'{-p,--provider}'[set the provider without prompting]:' \
    '(-o --operator-endpoint)'{-o,--operator-endpoint}'[set the operator endpoint without prompting]:' \
    '(-k --aws-access-key-id)'{-k,--aws-access-key-id}'[set the aws access key id without prompting]:' \
    '(-s --aws-secret-access-key)'{-s,--aws-secret-access-key}'[set the aws secret access key without prompting]:' \
    '(-r --aws-region)'{-r,--aws-region}'[set the aws region without prompting]:'
}

function _cortex_env_list {
  _arguments
}

function _cortex_env_default {
  _arguments
}

function _cortex_env_delete {
  _arguments
}

function _cortex_completion {
  _arguments \
    '(-h --help)'{-h,--help}'[help for completion]'
}

function _cortex_help {
  _arguments
}

alias cx='cortex'

if compquote '' 2>/dev/null; then _cortex; else compdef _cortex cortex; fi

[deliahu]

@iPalash this has been released in v0.17.0 (here’s the full changelog)

[iPalash]

Thanks for the quick turnaround on this.