bug(claude-code): enable_aibridge causes "Invalid count argument" on workspace creation

[shanewhite97]

Description

When using the claude-code module (v4.8.1) with enable_aibridge = true and the calling template adds depends_on to the module block (e.g. depends_on = [module.git-clone]), Terraform fails during plan with:

Error: Invalid count argument
on .terraform/modules/claude-code/main.tf line 290, in resource "coder_env" "claude_api_key":
  290:   count = local.claude_api_key != "" ? 1 : 0
The "count" value depends on resource attributes that cannot be determined until apply, so Terraform cannot predict how many instances will be created.

Without depends_on on the module call, the plan succeeds because data.coder_workspace_owner.me.session_token is resolved during the plan phase as expected.

Root Cause

When a caller adds depends_on to the module "claude-code" block, Terraform conservatively defers all data source reads inside the module to the apply phase (HashiCorp docs: "Terraform may treat more values as unknown '(known after apply)' because it is uncertain what changes will occur on the upstream object. This is especially likely when you use depends_on for modules.").

This causes data.coder_workspace_owner.me.session_token — which is normally known at plan time — to become unknown. The derived local:

claude_api_key = var.enable_aibridge ? data.coder_workspace_owner.me.session_token : var.claude_api_key

then also becomes unknown, and its use in count (line 290) fails because Terraform requires count to be fully resolved at plan time.

Suggested Fix

Replace the count expression with one that depends only on input variables (always known at plan time):

resource "coder_env" "claude_api_key" {
  count = (var.enable_aibridge || var.claude_api_key != "") ? 1 : 0
  # ...
}

This is semantically equivalent because:

• enable_aibridge = true → session_token is used (always non-empty) → env var should be created
• enable_aibridge = false and claude_api_key != "" → env var should be created
• enable_aibridge = false and claude_api_key == "" → env var should not be created

The module's existing validation already enforces that enable_aibridge and claude_api_key are mutually exclusive.

The value field can remain local.claude_api_key — only count and for_each must be deterministic at plan time.

Reproduction

1. Use claude-code module v4.8.1 with enable_aibridge = true
2. Add depends_on = [module.some-other-module] to the module "claude-code" block
3. Run terraform plan — fails with the above error
4. Remove depends_on — plan succeeds

Environment

• Module: claude-code v4.8.1
• Feature: enable_aibridge = true
• Trigger: depends_on on the module call

[35C4n0r]

@shanewhite97, can you share the template you are using (or the relevant parts/snippets of it)? I can't seem to reproduce this.

[35C4n0r]

Error: Invalid count argument
on .terraform/modules/claude-code/main.tf line 290, in resource "coder_env" "claude_api_key":
290: count = local.claude_api_key != "" ? 1 : 0
The "count" value depends on resource attributes that cannot be determined until apply, so Terraform cannot predict how many instances will be created.

Also do you get this error on this page on Build ?

[shanewhite97]

Hi @35C4n0r Thanks for your help on those other tickets by the way, great help :)

Building the template here works fine, but when spinning up a workspace:

Here is some of the code, let me know what else you need:

module "claude-code" {
  count    = local.enable_claude_code > 0 && data.coder_workspace.me.start_count > 0 ? 1 : 0
  source   = "registry.coder.com/coder/claude-code/coder"
  version  = "4.8.1"
  agent_id = coder_agent.main.id

  enable_aibridge  = true
  install_agentapi = true
  model            = var.claude_model
  report_tasks     = false
  workdir          = local.workspace_folder

  depends_on = [module.git-clone]
}```

[35C4n0r]

@shanewhite97, managed to reproduce it :D
can you confirm you have these blocks in your template or equivalent of this, where the default is false and then you create a workspace with value true ?

data "coder_parameter" "claude" {
  type = "bool"
  default = false
  name = "Enable ClaudeCode"
}

locals {
  enable_claude_code = data.coder_parameter.claude.value == "true" ? 1 : 0
}

PS: that's why we don't see the error in here: #812 (comment)
but only while creating the workspace.

[35C4n0r]

will push the fix tmrw :)

[35C4n0r]

@shanewhite97 I've updated the issue description, the issue was being caused by depends_on on the module call, not enable_aibridge = true alone. When a caller adds depends_on = [module.git-clone] to the module "claude-code" block, Terraform defers all data source reads inside the module to the apply phase, making data.coder_workspace_owner.me.session_token unknown at plan time.

[shanewhite97]

@35C4n0r Yes I can confirm. Sorry for the slow response, been working with a customer this week. Thank you very much 😄