Passing viewables between windows

[dlesnoff]

I would like to improve my understanding of viewables.
I am developing a game in which a new window enable to select the parameters for a new game. The game itself occurs in the main initial window.

I would like to change the parameters of the viewable used by the main window. The only approach I found was to use a global variable.
Can we avoid a global variable and pass new parameters when opening or quitting a window? Below is a minimal example similar to what I have:

import owlkettle, sequtils

var counter: int = 0

viewable App:
  counter: int = 0

viewable ChangeCounter:
  selected: int = 0
  items: seq[string] = mapIt(0..<100, "Option " & $it)

method view(app: ChangeCounterState): Widget =
    result = gui:
        Window:
            title = "Change Counter"
            defaultSize = (200, 60)
            Box(orient = OrientY, spacing = 6, margin = 12):
                Box(spacing = 6) {.expand: false.}:
                    Label:
                        text = "Drop Down"
                        xAlign = 0
                        
                    DropDown {.expand: false.}:
                        items = app.items
                        selected = app.selected
                        proc select(item: int) =
                            app.selected = item
                            counter = app.selected
                    
                    Button {.expand: false.}:
                        text = "OK"
                        style = [ButtonSuggested]
                        proc clicked() =
                            app.closeWindow()

method view(app: AppState): Widget =
  result = gui:
    Window:
      title = "Counter"
      defaultSize = (200, 60)
      Box(orient=OrientY, spacing=12):
        Button {.expand: false.}:
          text = "-"
          proc clicked() =
            app.counter -= 1
        Label(text = $app.counter)
        Button {.expand: false.}:
          text = "+"
          style = [ButtonSuggested]
          proc clicked() =
            app.counter += 1

      HeaderBar {.addTitlebar.}:               
        Button {.addRight.}:
          text = "Counter Value"
          style = [ButtonSuggested]
          proc clicked() =
            discard app.open: gui:
              ChangeCounter()
            app.counter = counter

brew(gui(App()))

The main window has a counter which can be updated (extracted from the counter.nim example).
The second window enables to select a specific value for the counter. For this I use the global variable counter. When I quit the second window, I update the application counter with the value of the global variable.

Can I avoid the use of the global variable?

[can-lehmann]

You have 2 options:

1. RECOMMENDED If you want to share a lot of state, you probably want to use a proper architecture for your app. I recommend using a Model/View architecture, where you have a Model = ref object ... that stores your applications state, and each viewable has a model: Model field which it uses as its "data source". Here is an extremely contrived example of this: [FR] Docs for components/modular organization of code. #39 (comment)

2. If you just want to share a small amount of state between the ChangeCounter dialog and the App, you can just read it back once the dialog is closed:

proc clicked() =
  let (res, state) = app.open: gui:
    ChangeCounter()
  app.counter = ChangeCounterState(state).selected

[can-lehmann]

If you want to provide the user an option to discard their changes in the dialog, you probably want to use the second option.

[dlesnoff]

Thank you!