No Serial Monitor output from certain boards

[davejel]

Describe the problem

using serial monitor to show variables etc does not work i.e.
input string to serial input with the code below should give output on serial monitor, it outputs nothing
I tested this using Arduino 1.8.19 ----- works perfectly
then with Arduino 2.3.6 ------ no output to serial window

To reproduce

note !! return character set to carriage return for this to work

void setup() {
	Serial.begin(115200);
	while(!Serial);
	Serial.println("Serial started");
}

String kbdInput = "";
bool inptrdy = false;
//-------------------
void loop() {
	if(Serial.available()) {
		char c = Serial.read();
		if(c != 13) {
			kbdInput += c; // add c to string
		}
		else inptrdy = true;
		Serial.print("serial ok c: ");
		Serial.println(c);
		Serial.println("kbdInput: " + kbdInput);
		Serial.println("inputrdy: " + inptrdy);
	}
	if(inptrdy) {
		Serial.println("inptrdy true kbdInput: " + kbdInput);
		if(kbdInput == "c") {
			Serial.println("Keyboard commands:");
		}
		else if(kbdInput == "tables") { // print tables
			Serial.println("printTheTables()");
		}
		else if(kbdInput == "restart") { // restart node
			Serial.println("Power On Reset this node");
		}

		kbdInput = "";
		inptrdy = false;
	}
}

Expected behavior

the code above should give output in the serial window when prompted with serial input followed by return

Arduino IDE version

2.3.6

Operating system

Windows

Operating system version

11

Additional context

Related

• Garbage output in Serial Monitor when using ESP8266 via FTDI #427
• No output in Serial Monitor #1806
• Serial Monitor stops printing output #2618

Issue checklist

• I searched for previous reports in the issue tracker
• I verified the problem still occurs when using the latest nightly build
• My report contains all necessary details

[ritesh006]

Summary: Confirmed on Windows 11 + IDE 2.3.6 that Serial Monitor works; the behavior in the sketch was caused by two code issues rather than an IDE bug.

Findings

Serial.println("inputrdy: " + inptrdy); does pointer arithmetic on the string literal instead of printing the boolean, leading to truncated text and confusion.

The sketch only treated \r (CR) as end-of-line. If the Serial Monitor is set to LF or CR+LF, the input line isn’t detected.

Using while(!Serial); is fragile on some boards/OSes; a small startup delay is more reliable.

Fixes (verified)

Replace while(!Serial); with delay(1500);

Treat both \r and \n as EOL

Print the bool explicitly with a ternary

String kbdInput;
bool inptrdy = false;

void setup() {
  Serial.begin(115200);
  delay(1500);
  Serial.println("Serial started");
}

void loop() {
  while (Serial.available()) {
    char c = (char)Serial.read();
    if (c == '\r' || c == '\n') {
      if (kbdInput.length()) inptrdy = true;  // ignore empty lines
    } else {
      kbdInput += c;
    }
    Serial.print("serial ok c: ");
    if (c == '\r') Serial.println("\\r");
    else if (c == '\n') Serial.println("\\n");
    else Serial.println(c);
    Serial.println("kbdInput: " + kbdInput);
    Serial.print("inputrdy: "); Serial.println(inptrdy ? "true" : "false");
  }

  if (inptrdy) {
    Serial.println("inptrdy true kbdInput: " + kbdInput);
    if (kbdInput == "c")       Serial.println("Keyboard commands:");
    else if (kbdInput == "tables")  Serial.println("printTheTables()");
    else if (kbdInput == "restart") Serial.println("Power On Reset this node");
    kbdInput = ""; inptrdy = false;
  }
}

After these changes, Serial Monitor in IDE 2.3.6 behaves correctly here at 115200 baud with any line-ending setting (CR, LF, CRLF).
Environment: Windows 11, IDE 2.3.6, Arduino Uno/ESP-type boards (tested), Serial Monitor line ending CR/LF/CRLF.

[davejel]

@ritesh006
thank you for coming back to me
on some boards I have tested the original code did work, on others (ESP WROOM 32) it does not work

using your code this has not changed, some ESPWROOM32 do work, others do not work, there seems to be no rhyme or reason to it
on a non working board i have tested with New Line, Carriage Return and Both NL & CR

on a working board, I agree your code does work but then it also works with my original code and New Line
it seems that it has to be one of 3 things

1. the sketch code not being correct
2. a hardware fault
3. an IDE problem

exact same sketch works on some boards but not others leaving either hardware or IDE ????
as I am not an expert in either of these fields then I am not sure what to try next
but as I said before thank you for your help
Dave

[davejel]

@ritesh006
i have also reported this issue on https://esp32.com/viewtopic.php?t=31910
where other users have similar problems no one there has managed a solution yet...
Dave

[ritesh006]

now its working for you?

[davejel]

with boards which were not working your new code is still not working

[per1234]

Hi @davejel. Please try this experiment and then report the results in a comment here:

1. Copy and paste this code as a new sketch in Arduino IDE:

   void setup() {
     Serial.begin(115200);
   }
   
   void loop() {
     Serial.println("hello");
     delay(1000);
   }

2. Upload the sketch to one of the boards that produces the problem you reported.

3. Wait for the upload to finish successfully.

4. Make sure the baud rate menu at the top right corner of the Serial Monitor panel is set to "9600".

Do you now see the word "hello" being printed in the Serial Monitor's output field once a second?