Find a way to intelligently reorder the kill-ring on pop

[PythonNut]

We want to fix the issue described here: https://stackoverflow.com/questions/5823495/emacs-how-to-yank-the-last-yanked-text-regardless-of-subsequent-kills

[PythonNut]

The following code appears to work:

(defvar kill-ring-yank-index 0
  "Index into kill-ring of last yank-pop. The item yank-popped
  will be at the head of the kill ring, but if the next command
  is also yank-pop, it will be returned here first before this
  variable is incremented.")

(el-patch-defun current-kill (n &optional do-not-move)
  "Rotate the yanking point by N places, and then return that kill.
If N is zero and `interprogram-paste-function' is set to a
function that returns a string or a list of strings, and if that
function doesn't return nil, then that string (or list) is added
to the front of the kill ring and the string (or first string in
the list) is returned as the latest kill.

If N is not zero, and if `yank-pop-change-selection' is
non-nil, use `interprogram-cut-function' to transfer the
kill at the new yank point into the window system selection.

If optional arg DO-NOT-MOVE is non-nil, then don't actually
move the yanking point; just return the Nth kill forward."

  (let ((interprogram-paste (and (= n 0)
				 interprogram-paste-function
                                 (funcall interprogram-paste-function))))
    (if interprogram-paste
	(progn
	  ;; Disable the interprogram cut function when we add the new
	  ;; text to the kill ring, so Emacs doesn't try to own the
	  ;; selection, with identical text.
	  (let ((interprogram-cut-function nil))
	    (if (listp interprogram-paste)
                (mapc 'kill-new (nreverse interprogram-paste))
	      (kill-new interprogram-paste)))
	  (car kill-ring)
          (el-patch-add (setq kill-ring-yank-index 0)))
      (or kill-ring (error "Kill ring is empty"))
      (el-patch-add
        ;; Put the head of kill-ring back where we had
        ;; previously found it, and fetch the next element
        (if (eq 0 n)
            (setq kill-ring-yank-index 0)
          (setq kill-ring
                (-insert-at kill-ring-yank-index
                            (car kill-ring)
                            (cdr kill-ring))
                kill-ring-yank-index n)
          (when (>= kill-ring-yank-index (- (length kill-ring) 1))
            (setq kill-ring-yank-index (- (length kill-ring) 1))
            (user-error "Reached end of kill-ring"))
          (when (< kill-ring-yank-index 0)
            (setq kill-ring-yank-index 0)
            (user-error "Reached beginning of kill-ring"))
          (setq kill-ring (let ((new (nth kill-ring-yank-index
                                          kill-ring)))
                            (cons new (-remove-at kill-ring-yank-index
                                                  kill-ring)))))
        (message "kill-ring-index %d → %d" n kill-ring-yank-index))
      (let ((ARGth-kill-element
             (el-patch-swap
               (nthcdr (mod (- n (length kill-ring-yank-pointer))
                            (length kill-ring))
                       kill-ring)
               kill-ring)))
        (unless do-not-move
          (setq kill-ring-yank-pointer ARGth-kill-element)
          (when (and yank-pop-change-selection
                     (> n 0)
                     interprogram-cut-function)
            (funcall interprogram-cut-function (car ARGth-kill-element))))
        (car ARGth-kill-element)))))

The only strange thing is that M-y appears to do something even when not preceded by C-y

[PythonNut]

Apparently this behavior is to be expected.