WL#13758 MySQL 5.7: Support linking with 3rd party OpenLDAP and Cyrus…

… SASL

We have recently upgraded to build with OpenSSL 1.1.1 on several
platforms.  This means that the "system" versions of libraries like
LDAP and SASL can no longer be used (they link with other versions of
SSL)

This patch is for 5.7: add cmake options WITH_LDAP and WITH_SASL,
assuming these have been built with the same version of SSL libraries
used for the server.  Look up static (.a) libraries for LDAP, LBER,
and SASL, and link these into appropriate plugins.

We also enable some tests which were previously skipped because of
bad feature tests.

Change-Id: If5deba8ae593b2c666ce12fab6ac7827e41b4f99

CMakeLists.txt

@@ -229,6 +229,8 @@ IF(WITH_DEFAULT_FEATURE_SET)
   INCLUDE(${CMAKE_SOURCE_DIR}/cmake/build_configurations/feature_set.cmake)
 ENDIF()
 
+INCLUDE(CMakePushCheckState)
+
 # Add macros
 INCLUDE(character_sets)
 INCLUDE(cpu_info)
@@ -237,6 +239,7 @@ INCLUDE(lz4)
 INCLUDE(libevent)
 INCLUDE(ssl)
 INCLUDE(sasl)
+INCLUDE(ldap)
 INCLUDE(rpc)
 INCLUDE(readline)
 INCLUDE(protobuf)
@@ -273,6 +276,9 @@ ENDIF()
 IF(NOT WITHOUT_SERVER)
   OPTION (WITH_UNIT_TESTS "Compile MySQL with unit tests" ON)
 ENDIF()
+OPTION(WITH_AUTHENTICATION_LDAP
+  "Report error if the LDAP authentication plugin cannot be built." OFF)
+
 OPTION(FORCE_UNSUPPORTED_COMPILER "Disable compiler version checks" OFF)
 MARK_AS_ADVANCED(WITHOUT_SERVER DISABLE_SHARED FORCE_UNSUPPORTED_COMPILER)
 
@@ -579,6 +585,8 @@ MYSQL_CHECK_LIBEVENT()
 MYSQL_CHECK_LZ4()
 # Add SASL library
 MYSQL_CHECK_SASL()
+# Add LDAP library
+MYSQL_CHECK_LDAP()
 # Add protoc and libprotobuf
 IF(NOT WITHOUT_SERVER)
   MYSQL_CHECK_PROTOBUF()

cmake/ldap.cmake

@@ -0,0 +1,150 @@
+# Copyright (c) 2019, Oracle and/or its affiliates. All rights reserved.
+#
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License, version 2.0,
+# as published by the Free Software Foundation.
+#
+# This program is also distributed with certain software (including
+# but not limited to OpenSSL) that is licensed under separate terms,
+# as designated in a particular file or component or in included license
+# documentation.  The authors of MySQL hereby grant you an additional
+# permission to link the program and your derivative works with the
+# separately licensed software that they have included with MySQL.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License, version 2.0, for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program; if not, write to the Free Software
+# Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301  USA
+
+# cmake -DWITH_LDAP=system|</path/to/custom/installation>
+# system is the default
+
+INCLUDE (CheckIncludeFile)
+INCLUDE (CheckIncludeFiles)
+
+SET(WITH_LDAP_DOC "\nsystem (use the OS ldap library)")
+STRING_APPEND(WITH_LDAP_DOC ", \n</path/to/custom/installation>")
+
+STRING(REPLACE "\n" "| " WITH_LDAP_DOC_STRING "${WITH_LDAP_DOC}")
+
+MACRO(FIND_SYSTEM_LDAP)
+  IF(WIN32)
+    SET(LDAP_SYSTEM_LIBRARY Wldap32 CACHE INTERNAL
+      "LDAP library is /c/Windows/system32/Wldap32.dll"
+      )
+  ELSE()
+    FIND_LIBRARY(LDAP_SYSTEM_LIBRARY
+      NAMES ldap_r ldap
+      )
+    FIND_LIBRARY(LBER_SYSTEM_LIBRARY
+      NAMES lber
+      )
+  ENDIF()
+  IF(LDAP_SYSTEM_LIBRARY AND (WIN32 OR LBER_SYSTEM_LIBRARY))
+    SET(LDAP_LIBRARY ${LDAP_SYSTEM_LIBRARY})
+    SET(LBER_LIBRARY ${LBER_SYSTEM_LIBRARY})
+    MESSAGE(STATUS "LBER_LIBRARY ${LBER_LIBRARY}")
+    MESSAGE(STATUS "LDAP_LIBRARY ${LDAP_LIBRARY}")
+  ENDIF()
+
+  IF(WIN32)
+    # LDAP system header is Winldap.h and is in some Windows SDK
+  ELSE()
+    CMAKE_PUSH_CHECK_STATE()
+
+    # For Solaris 11.3 we need to explicitly search here:
+    IF(SOLARIS)
+      INCLUDE_DIRECTORIES(BEFORE SYSTEM /usr/include/openldap)
+      SET(CMAKE_REQUIRED_INCLUDES "/usr/include/openldap")
+    ENDIF()
+
+    CHECK_INCLUDE_FILE(lber.h HAVE_LBER_H)
+    CHECK_INCLUDE_FILE(ldap.h HAVE_LDAP_H)
+    CMAKE_POP_CHECK_STATE()
+  ENDIF()
+
+ENDMACRO()
+
+MACRO(FIND_CUSTOM_LDAP)
+  FIND_PATH(LDAP_INCLUDE_DIR
+    NAMES ldap.h
+    PATHS ${WITH_LDAP_PATH}/include
+    NO_DEFAULT_PATH
+    NO_CMAKE_ENVIRONMENT_PATH
+    NO_SYSTEM_ENVIRONMENT_PATH
+    )
+
+  # On mac this list is <.dylib;.so;.a>
+  # We prefer static libraries, so we reverse it here.
+  LIST(REVERSE CMAKE_FIND_LIBRARY_SUFFIXES)
+
+  FIND_LIBRARY(LDAP_CUSTOM_LIBRARY
+    NAMES ldap_r ldap
+    PATHS ${WITH_LDAP_PATH}/lib
+    NO_DEFAULT_PATH
+    NO_CMAKE_ENVIRONMENT_PATH
+    NO_SYSTEM_ENVIRONMENT_PATH
+    )
+  FIND_LIBRARY(LBER_CUSTOM_LIBRARY
+    NAMES lber
+    PATHS ${WITH_LDAP_PATH}/lib
+    NO_DEFAULT_PATH
+    NO_CMAKE_ENVIRONMENT_PATH
+    NO_SYSTEM_ENVIRONMENT_PATH
+    )
+
+  LIST(REVERSE CMAKE_FIND_LIBRARY_SUFFIXES)
+
+  IF(LDAP_INCLUDE_DIR)
+    INCLUDE_DIRECTORIES(BEFORE SYSTEM ${LDAP_INCLUDE_DIR})
+
+    CMAKE_PUSH_CHECK_STATE()
+    SET(CMAKE_REQUIRED_INCLUDES ${LDAP_INCLUDE_DIR})
+    CHECK_INCLUDE_FILE(lber.h HAVE_LBER_H)
+    CHECK_INCLUDE_FILE(ldap.h HAVE_LDAP_H)
+    CMAKE_POP_CHECK_STATE()
+  ENDIF()
+
+  IF(LDAP_CUSTOM_LIBRARY AND LBER_CUSTOM_LIBRARY)
+    SET(LDAP_LIBRARY ${LDAP_CUSTOM_LIBRARY})
+    SET(LBER_LIBRARY ${LBER_CUSTOM_LIBRARY})
+    GET_FILENAME_COMPONENT(LDAP_LIBRARY_EXT ${LDAP_LIBRARY} EXT)
+    IF(LDAP_LIBRARY_EXT STREQUAL ".a")
+      SET(STATIC_LDAP_LIBRARY 1)
+    ENDIF()
+    MESSAGE(STATUS "LDAP_LIBRARY ${LDAP_LIBRARY}")
+    MESSAGE(STATUS "LBER_LIBRARY ${LBER_LIBRARY}")
+  ENDIF()
+ENDMACRO()
+
+MACRO(MYSQL_CHECK_LDAP)
+  IF(NOT WITH_LDAP)
+    SET(WITH_LDAP "system" CACHE STRING ${WITH_LDAP_DOC_STRING} FORCE)
+  ENDIF()
+
+  # See if WITH_LDAP is of the form </path/to/custom/installation>
+  FILE(GLOB WITH_LDAP_HEADER ${WITH_LDAP}/include/ldap.h)
+  IF (WITH_LDAP_HEADER)
+    FILE(TO_CMAKE_PATH "${WITH_LDAP}" WITH_LDAP)
+    SET(WITH_LDAP_PATH ${WITH_LDAP})
+  ENDIF()
+
+  IF(WITH_LDAP STREQUAL "system")
+    FIND_SYSTEM_LDAP()
+  ELSE()
+    FIND_CUSTOM_LDAP()
+  ENDIF()
+
+  IF(WIN32 AND WITH_LDAP STREQUAL "system")
+    SET(LDAP_FOUND 1)
+  ELSEIF(HAVE_LBER_H AND HAVE_LDAP_H AND LDAP_LIBRARY AND LBER_LIBRARY)
+    SET(LDAP_FOUND 1)
+  ELSE()
+    SET(LDAP_FOUND 0)
+  ENDIF()
+
+ENDMACRO()

cmake/os/FreeBSD.cmake

@@ -1,5 +1,4 @@
-
-# Copyright (c) 2010, 2014, Oracle and/or its affiliates. All rights reserved.
+# Copyright (c) 2010, 2019, Oracle and/or its affiliates. All rights reserved.
 # 
 # This program is free software; you can redistribute it and/or modify
 # it under the terms of the GNU General Public License, version 2.0,
@@ -19,12 +18,19 @@
 #
 # You should have received a copy of the GNU General Public License
 # along with this program; if not, write to the Free Software
-# Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA 
+# Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301  USA 
 
-# This file includes FreeBSD specific options and quirks, related to system checks
+# This file includes FreeBSD specific options and quirks,
+# related to system checks
 
 INCLUDE(CheckCSourceRuns)
 
+SET(FREEBSD 1)
+
+# On FreeBSD some includes, e.g. sasl/sasl.h, is in /usr/local/include
+INCLUDE_DIRECTORIES(SYSTEM /usr/local/include)
+LIST(APPEND CMAKE_REQUIRED_INCLUDES "/usr/local/include")
+
 # We require at least Clang 3.3.
 IF(NOT FORCE_UNSUPPORTED_COMPILER)
   IF(CMAKE_C_COMPILER_ID MATCHES "Clang")

cmake/os/WindowsCache.cmake

@@ -1,4 +1,4 @@
-# Copyright (c) 2010, 2017, Oracle and/or its affiliates. All rights reserved.
+# Copyright (c) 2010, 2019, Oracle and/or its affiliates. All rights reserved.
 #
 # This program is free software; you can redistribute it and/or modify
 # it under the terms of the GNU General Public License, version 2.0,
@@ -69,7 +69,6 @@ SET(HAVE_SYS_PARAM_H CACHE  INTERNAL "")
 SET(HAVE_FNMATCH_H CACHE  INTERNAL "")
 SET(HAVE_SYS_UN_H CACHE  INTERNAL "")
 SET(HAVE_VIS_H CACHE INTERNAL "")
-SET(HAVE_SASL_SASL_H CACHE  INTERNAL "")
 
 # Libevent
 SET(HAVE_DEVPOLL CACHE  INTERNAL "")