Keyword search

[aharth]

Nice to see the publications office providing a SPARQL endpoint!

In our demo, we would like to use keyword search to find resources to explore.

Does the SPARQL endpoint offer keyword search functionality or is there a separate service available to perform keyword search over the data by any chance?

[victoriobentivogli]

Hello,

Currently we do not offer a keyword search in Cellar (our SPARQL endpoint) that matches the capabilities of the expert search on TED.

You can use regular expression filtering as an alternative.

Here an example taken from our Query Library (available on TED Open Data Service) and modified to include results where the Legal Name of a Buyer includes the text 'banque' (uppercase or lowercase, and in any part of the property):

PREFIX cccev: <http://data.europa.eu/m8g/>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX epo: <http://data.europa.eu/a4g/ontology#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>

SELECT DISTINCT ?publicationNumber ?legalName ?procedureType ?country

WHERE {

	FILTER (?publicationDate = "2024-11-04"^^xsd:date)
	FILTER (?formType = <http://publications.europa.eu/resource/authority/form-type/competition>)

  GRAPH ?g {
    ?notice
        epo:hasPublicationDate ?publicationDate ;
        epo:refersToProcedure [
            epo:hasProcedureType ?procedureTypeUri ;
            a epo:Procedure
        ] ;
        epo:hasNoticePublicationNumber ?publicationNumber ;
        epo:hasFormType ?formType ;
        epo:announcesRole [
            a epo:Buyer ;
            epo:playedBy [
                epo:hasLegalName ?legalName ;
                cccev:registeredAddress [
                    epo:hasCountryCode ?countryUri
                ]
            ]
        ]
    }
    
    ?procedureTypeUri a skos:Concept ;
        skos:prefLabel ?procedureType.
    FILTER (lang(?procedureType) = "en")

    ?countryUri dc:identifier ?country .
  
    FILTER (REGEX(?legalName, 'banque', 'i'))
} 

I hope this provides a viable alternative to your requirement.

Kind regards.