0.11.3

Monika After Story/game/definitions.rpy

@@ -5421,6 +5421,102 @@ init 2 python:
             return "An" if should_capitalize else "an"
         return "A" if should_capitalize else "a"
 
+    def mas_input(prompt, default="", allow=None, exclude="{}", length=None, with_none=None, pixel_width=None, screen="input", screen_kwargs={}):
+        """
+        Calling this function pops up a window asking the player to enter some
+        text.
+
+        IN:
+            prompt - a string giving a prompt to display to the player
+
+            default - a string giving the initial text that will be edited by the player
+                (Default: "")
+
+            allow - a string giving a list of characters that will
+                be allowed in the text
+                (Default: None)
+
+            exclude - if a character is present in this string, it is not
+                allowed in the text
+                (Default: "{}")
+
+            length - an integer giving the maximum length of the input string
+                (Default: None)
+
+            with_none - the transition to use
+                (Default: None)
+
+            pixel_width - if not None, the input is limited to being this many pixels wide,
+                in the font used by the input to display text
+                (Default: None)
+
+            screen - the name of the screen that takes input. If not given, the 'input'
+                screen is used
+                (Default: "input")
+
+            screen_kwargs - the keyword arguments to pass in to the screen
+                NOTE: passing in the prompt argument is not mandatory here
+                (Default: {})
+
+        OUT:
+            entered string
+        """
+        renpy.exports.mode("input")
+
+        roll_forward = renpy.exports.roll_forward_info()
+        if not isinstance(roll_forward, basestring):
+            roll_forward = None
+
+        # use previous data in rollback
+        if roll_forward is not None:
+            default = roll_forward
+
+        fixed = renpy.in_fixed_rollback()
+
+        if renpy.has_screen(screen):
+            widget_properties = { }
+            widget_properties["input"] = dict(default=default, length=length, allow=allow, exclude=exclude, editable=not fixed, pixel_width=pixel_width)
+
+            screen_kwargs["prompt"] = prompt
+
+            renpy.show_screen(screen, _transient=True, _widget_properties=widget_properties, **screen_kwargs)
+
+        else:
+
+            if screen != "input":
+                raise Exception("The '{}' screen does not exist.".format(screen))
+
+            renpy.ui.window(style="input_window")
+            renpy.ui.vbox()
+            renpy.ui.text(prompt, style="input_prompt")
+            inputwidget = renpy.ui.input(default, length=length, style="input_text", allow=allow, exclude=exclude)
+
+            # disable input in fixed rollback
+            if fixed:
+                inputwidget.disable()
+
+            renpy.ui.close()
+
+        renpy.exports.shown_window()
+
+        if not renpy.game.after_rollback:
+            renpy.loadsave.force_autosave(True)
+
+        # use normal "say" click behavior if input can't be changed
+        if fixed:
+            renpy.ui.saybehavior()
+
+        rv = renpy.ui.interact(mouse="prompt", type="input", roll_forward=roll_forward)
+        renpy.exports.checkpoint(rv)
+
+        if with_none is None:
+            with_none = renpy.config.implicit_with_none
+
+        if with_none:
+            renpy.game.interface.do_with(None, None)
+
+        return rv
+
 #EXTRA TEXT TAGS
 init python:
     def a_an_tag(tag, argument, contents):

Monika After Story/game/screens.rpy

@@ -477,14 +477,19 @@ image input_caret:
         linear 0.35 alpha 1
         repeat
 
-screen input(prompt):
+screen input(prompt, use_return_button=False, return_button_prompt="Nevermind.", return_button_value="cancel_input"):
     style_prefix "input"
 
-
     window:
+        if use_return_button:
+            textbutton return_button_prompt:
+                style "choice_button"
+                align (0.5, 0.5)
+                ypos -263
+                action Return(return_button_value)
+
         vbox:
-            xalign .5
-            yalign .5
+            align (0.5, 0.5)
             spacing 30
 
             text prompt style "input_prompt"
@@ -1396,7 +1401,7 @@ screen preferences():
                         action ToggleField(persistent, "_mas_sensitive_mode", True, False)
                         hovered tooltip.Action(layout.MAS_TT_SENS_MODE)
 
-                    if renpy.windows and store.mas_windowreacts.can_show_notifs:
+                    if store.mas_windowreacts.can_do_windowreacts:
                         textbutton _("Window Reacts"):
                             action ToggleField(persistent, "_mas_windowreacts_windowreacts_enabled", True, False)
                             hovered tooltip.Action(layout.MAS_TT_ACTV_WND)

Monika After Story/game/script-affection.rpy

@@ -1970,20 +1970,22 @@ label monika_affection_nickname:
             label monika_affection_nickname_yes:
                 pass
 
+            show monika 1eua at t11 zorder MAS_MONIKA_Z
+
             $ done = False
-            m 1eua "Okay! Just type 'Nevermind' if you change your mind, [player]."
             while not done:
                 python:
-                    inputname = renpy.input(
+                    inputname = mas_input(
                         _("So what do you want to call me?"),
                         allow=" abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ-_",
-                        length=10
+                        length=10,
+                        screen_kwargs={"use_return_button": True}
                     ).strip(' \t\n\r')
 
                     lowername = inputname.lower()
 
                 # lowername isn't detecting player or m_name?
-                if lowername == "nevermind":
+                if lowername == "cancel_input":
                     m 1euc "Oh, I see."
                     m 1tkc "Well...that's a shame."
                     m 3eka "But that's okay. I like '[m_name]' anyway."

Monika After Story/game/script-brbs.rpy

@@ -566,6 +566,109 @@ label monika_idle_nap_callback:
         m 6ckc "..."
     return
 
+init 5 python:
+    addEvent(
+        Event(
+            persistent.event_database,
+            eventlabel="monika_idle_homework",
+            prompt="I'm going to do some homework",
+            category=['be right back'],
+            pool=True,
+            unlocked=True
+        ),
+        markSeen=True
+    )
+
+label monika_idle_homework:
+    if mas_isMoniNormal(higher=True):
+        m 1eub "Oh, okay!"
+        m 1hua "I'm proud of you for taking your studies seriously."
+        m 1eka "Don't forget to come back to me when you're done~"
+
+    elif mas_isMoniDis(higher=True):
+        m 2euc "Alright...{w=0.5}"
+        if random.randint(1,5) == 1:
+            m 2rkc "...Good luck with your homework, [player]."
+
+    else:
+        m 6ckc "..."
+
+    #Set up the callback label
+    $ mas_idle_mailbox.send_idle_cb("monika_idle_homework_callback")
+    #Then the idle data
+    $ persistent._mas_idle_data["monika_idle_homework"] = True
+    return "idle"
+
+label monika_idle_homework_callback:
+    if mas_isMoniDis(higher=True):
+        m 2esa "All done, [player]?"
+
+        if mas_isMoniNormal(higher=True):
+            m 2ekc "I wish I could've been there to help you, but there isn't much I can do about that just yet, sadly."
+            m 7eua "I'm sure we could both be a lot more efficient doing homework if we could work together."
+
+            if mas_isMoniAff(higher=True) and random.randint(1,5) == 1:
+                m 3rkbla "...Although, that's assuming we don't get {i}too{/i} distracted, ehehe..."
+
+            m 1eua "But anyway,{w=0.2} {nw}"
+            extend 3hua "now that you're done, let's enjoy some more time together."
+
+    else:
+        m 6ckc "..."
+    return
+
+init 5 python:
+    addEvent(
+        Event(
+            persistent.event_database,
+            eventlabel="monika_idle_working",
+            prompt="I'm going to work on something",
+            category=['be right back'],
+            pool=True,
+            unlocked=True
+        ),
+        markSeen=True
+    )
+
+label monika_idle_working:
+    if mas_isMoniNormal(higher=True):
+        m 1eua "Alright, [player]."
+        m 1eub "Don't forget to take a break every now and then!"
+
+        if mas_isMoniAff(higher=True):
+            m 3rkb "I wouldn't want my sweetheart to spend more time on [his] work than with me~"
+
+        m 1hua "Good luck with your work!"
+
+    elif mas_isMoniDis(higher=True):
+        m 2euc "Okay, [player]."
+
+        if random.randint(1,5) == 1:
+            m 2rkc "...Please come back soon..."
+
+    else:
+        m 6ckc "..."
+
+    #Set up the callback label
+    $ mas_idle_mailbox.send_idle_cb("monika_idle_working_callback")
+    #Then the idle data
+    $ persistent._mas_idle_data["monika_idle_working"] = True
+    return "idle"
+
+label monika_idle_working_callback:
+    if mas_isMoniNormal(higher=True):
+        m 1eub "Finished with your work, [player]?"
+        show monika 5hua at t11 zorder MAS_MONIKA_Z with dissolve
+        m 5hua "Then let's relax together, you've earned it~"
+
+    elif mas_isMoniDis(higher=True):
+        m 2euc "Oh, you're back..."
+        m 2eud "...Was there anything else you wanted to do, now that you're done with your work?"
+
+    else:
+        m 6ckc "..."
+    return
+
 #Rai's og game idle
 #label monika_idle_game:
 #    m 1eub "That sounds fun!"

Monika After Story/game/script-fun-facts.rpy

@@ -788,3 +788,69 @@ label mas_fun_fact_coffee_origin:
     m 3hub "...And I for one can certainly attest that the love of coffee has remained strong to this day!"
     call mas_fun_facts_end
     return
+
+init 5 python:
+    addEvent(
+        Event(
+            persistent._mas_fun_facts_database,
+            eventlabel="mas_fun_fact_synesthesia",
+        ),
+        code="FFF"
+    )
+
+label mas_fun_fact_synesthesia:
+    m 1esa "Okay, this one's pretty interesting..."
+    m 3eua "Some people experience a phenomenon known as {i}synesthesia{/i},{w=0.1} which is where something that stimulates one of our senses also triggers another sense simultaneously."
+    m 1hua "That's kind of a wordy explanation, ehehe...{w=0.2} Let's find an example!"
+    m 1eua "It says here that a common form of synesthesia is {i}grapheme–color synesthesia{/i},{w=0.1} which is where people 'experience' letters and numbers as colors."
+    m 3eua "Another kind is {i}spatial sequence synesthesia{/i},{w=0.1} which is where numbers and figures are 'seen' at specific locations in space."
+    m "Like, one number appears 'closer' or 'further' away than another number. {w=0.2}{nw}"
+    extend 3eub "It's kinda like a map!"
+    m 1eua "...And there's a whole bunch of other kinds of synesthesia too."
+    m 1esa "Researchers aren't really sure how prevalent it is--{w=0.1}some have suggested as much as 25 percent of the population experiences it, but I seriously doubt that since I'd never heard of it until now."
+    m 3eub "Probably the most accurate estimate so far is that it's just over 4 percent of people, so that's what I'll go with!"
+    m 1eua "Experiencing synesthesia sounds like it'd be pretty neat,{w=0.2} don't you think so [player]?"
+    #Call the end
+    call mas_fun_facts_end
+    return
+
+init 5 python:
+    addEvent(
+        Event(
+            persistent._mas_fun_facts_database,
+            eventlabel="mas_fun_fact_dream_faces",
+        ),
+        code="FFF"
+    )
+
+label mas_fun_fact_dream_faces:
+    m 3eub "Okay, got one!"
+    m 1eua "Supposedly, our minds don't invent new faces when we dream.{w=0.2} Every person you've met in your dreams is someone you've seen in real life at some point."
+    m 3wud "You don't even have to talk to them in real life!"
+    m 3eud "If you just walked past them while shopping or something, their face gets registered in your mind and they can appear in your dreams."
+    m 1hua "I think it's incredible how much info the brain can store!"
+    m 1ekbla "I wonder...{w=0.2}do you ever dream about me, [player]?"
+    #Call the end
+    call mas_fun_facts_end
+    return
+
+init 5 python:
+    addEvent(
+        Event(
+            persistent._mas_fun_facts_database,
+            eventlabel="mas_fun_fact_monochrome_dreams",
+        ),
+        code="FFF"
+    )
+
+label mas_fun_fact_monochrome_dreams:
+    m 3eua "Did you know that from 1915 to the 1950s, most people's dreams were in black and white?"
+    m 1esa "Nowadays, it's a relatively rare phenomenon for people with unimpaired vision."
+    m 3eua "Researchers have linked this to the fact that movies and shows were almost exclusively black and white back then."
+    m 3eud "...But I think that's kinda weird, because people still saw everything in color.{w=0.3} {nw}"
+    extend 3hksdlb "It's not like the world went black and white!"
+    m 1esd "It just goes to show that the content you absorb can have all kinds of effects on your mind, even if it's trivial."
+    m 3eua "I think if there's a lesson to be learned here, it's that we should be very careful about the kind of media we consume, okay [player]?"
+    #Call the end
+    call mas_fun_facts_end
+    return