Add a skip keyword to walkdir function

[mgalenb]

Ive run into errors using Base.walkdir. These errors occur when I've tried to open directories that I don't have permissions for.

I modified walkdir() bellow:

function walkdir(root; topdown=true, follow_symlinks=false, onerror=throw, skip = ['#','.'])
    function _walkdir(chnl, root)
        tryf(f, p) = try
                if any(i->i==first(basename(p)),skip)
                    return
                else
                    f(p)
                end
            catch err
                isa(err, IOError) || rethrow()
                try
                    onerror(err)
                catch err2
                    close(chnl, err2)
                end
                return
            end
        content = tryf(readdir, root)
        content === nothing && return
        dirs = Vector{eltype(content)}()
        files = Vector{eltype(content)}()
        for name in content
            path = joinpath(root, name)

            # If we're not following symlinks, then treat all symlinks as files
            if (!follow_symlinks && something(tryf(islink, path), true)) || !something(tryf(isdir, path), false)
                push!(files, name)
            else
                push!(dirs, name)
            end
        end

        if topdown
            push!(chnl, (root, dirs, files))
        end
        for dir in dirs
            _walkdir(chnl, joinpath(root, dir))
        end
        if !topdown
            push!(chnl, (root, dirs, files))
        end
        nothing
    end
    return Channel{Tuple{String,Vector{String},Vector{String}}}(chnl -> _walkdir(chnl, root))
end

If this is not helpful then plz ignore.

[stevengj]

These errors occur when I've tried to open directories that I don't have permissions for.

Should there just be a flag to skip subdirectories for which we don't have read permission?

(Filtering by filename pattern seems more like a job for the Glob.jl package.)

[mgalenb]

yes that would make more sense, although im not sure how to do that

[stevengj]

Maybe just add a skipunreadable::Bool=false flag and change _walkdir(chnl, joinpath(root, dir)) to

dirpath = joinpath(root, dir)
skipunreadable && !istraverseable(dirpath) && continue
_walkdir(chnl, dirpath)

where

istraverseable(path::AbstractString) = isreadable(path) && isexecutable(path)

at least on Unix systems. Not sure about Windows?

Edit: On Windows, it looks like read permission is generally sufficient. There is a FILE_TRAVERSE bit that is analogous to the Unix execute bit, but it is not typically enforced:

By default, authorization for access to a file or directory is controlled strictly by the ACLs in the security descriptor associated with that file or directory. In particular, the security descriptor of a parent directory is not used to control access to any child file or directory. The FILE_TRAVERSE access right can be enforced by removing the BYPASS_TRAVERSE_CHECKING privilege from users. This is not recommended in the general case, as many programs do not correctly handle directory traversal errors. The primary use for the FILE_TRAVERSE access right on directories is to enable conformance to certain IEEE and ISO POSIX standards when interoperability with Unix systems is a requirement.

[mgalenb]

I can fork and test on windows if that would be helpful. I have never done a PR before