Update on value change

src/Observables.jl

@@ -1,6 +1,6 @@
 module Observables
 
-export Observable, on, off, onany, connect!, obsid, async_latest, throttle
+export Observable, on, off, onany, connect!, obsid, observe_changes, async_latest, throttle
 
 import Base.Iterators.filter
 
@@ -477,6 +477,47 @@ Observable{$Int} with 0 listeners. Value:
     map!(f, Observable(f(arg1[], map(to_value, args)...)), arg1, args...; update=false)
 end
 
+"""
+    obs = observe_changes(arg::AbstractObservable, eq=(==))
+
+Returns an `Observable` which updates with the value of `arg` whenever the new value
+differs from the current value of `obs` according to the equality operator `eq`.
+
+# Example:
+```
+julia> obs = Observable(0);
+
+julia> obs_change = observe_changes(obs);
+
+julia> on(obs) do o
+           println("obs[] == \$o")
+       end;
+
+julia> on(obs_change) do o
+           println("obs_change[] == \$o")
+       end;
+
+julia> obs[] = 0;
+obs[] == 0
+
+julia> obs[] = 1;
+obs_change[] == 1
+obs[] == 1
+
+julia> obs[] = 1;
+obs[] == 1
+```
+"""
+function observe_changes(obs::AbstractObservable{T}, eq=(==)) where T
+    out = Observable{T}(obs[])
+    on(obs) do val
+        if !eq(val, out[])
+            out[] = val
+        end
+    end
+    out
+end
+
 """
     async_latest(observable::AbstractObservable, n=1)
 

test/runtests.jl

@@ -185,6 +185,29 @@ end
     @test c[] == 103
 end
 
+@testset "observe_changes" begin
+    o = Observable(0)
+    changes = observe_changes(o)
+    changes_approx = observe_changes(o, (x,y) -> abs(x-y) < 2)
+    @test eltype(changes) == eltype(changes_approx) == Int
+    @test changes[] == changes_approx[] == 0
+
+    values = Int[]
+    values_approx = Int[]
+    on(changes) do v
+        push!(values, v)
+    end
+    on(changes_approx) do v
+        push!(values_approx, v)
+    end
+
+    for i in 1:100
+        o[] = floor(Int, i/10)
+    end
+    @test values == 1:10
+    @test values_approx == 2:2:10
+end
+
 @testset "async_latest" begin
     o = Observable(0)
     cnt = Ref(0)