StaticArrays 1.5.13 breaks unit tests in other packages.

[ufechner7]

The latest version of StaticArrays is causing a lot of failures in the unit tests of the package KiteModels, see for example:
https://github.com/ufechner7/KiteModels.jl/actions/runs/4157073359/jobs/7191296947

The issues disappeared when downgrading to 1.5.12 as I did in the current master version of KiteModels.

One type of error are memory allocations that appear with 1.5.14, but not with 1.5.12 or older versions.

[ufechner7]

I mean, if StaticArrays allocate I would say they are broken... The whole point of this package is to provide arrays that do NOT allocate. Some more unit tests needed in this package...

[ufechner7]

One of the functions that allocate when using 1.5.14:

@inline function calc_particle_forces!(s, pos1, pos2, vel1, vel2, spring, segments, d_tether, rho, i)
    l_0 = spring.length # Unstressed length
    k = spring.c_spring * s.stiffness_factor  # Spring constant
    c = spring.damping                        # Damping coefficient    
    segment = pos1 - pos2
    rel_vel = vel1 - vel2
    av_vel = 0.5 * (vel1 + vel2)
    norm1 = norm(segment)
    unit_vector = segment / norm1

    k1 = 0.25 * k # compression stiffness kite segments
    k2 = 0.1 * k  # compression stiffness tether segments
    c1 = 6.0 * c  # damping kite segments
    spring_vel   = unit_vector ⋅ rel_vel
    if (norm1 - l_0) > 0.0
        if i > segments  # kite springs
             s.spring_force .= (k *  (norm1 - l_0) + (c1 * spring_vel)) * unit_vector 
        else
             s.spring_force .= (k *  (norm1 - l_0) + (c * spring_vel)) * unit_vector
        end
    elseif i > segments # kite spring
        s.spring_force .= (k1 *  (norm1 - l_0) + (c * spring_vel)) * unit_vector
    else
        s.spring_force .= (k2 *  (norm1 - l_0) + (c * spring_vel)) * unit_vector
    end

    s.v_apparent .= s.v_wind_tether - av_vel
    if s.set.version == 1
        area = norm1 * d_tether
    else
        area = norm1 * s.set.d_line * 0.001
    end
    v_app_perp = s.v_apparent - s.v_apparent ⋅ unit_vector * unit_vector
    half_drag_force = (-0.25 * rho * s.set.cd_tether * norm(v_app_perp) * area) * v_app_perp 

    @inbounds s.forces[spring.p1] .+= half_drag_force + s.spring_force
    @inbounds s.forces[spring.p2] .+= half_drag_force - s.spring_force
    if i == 1 s.last_force .= s.forces[spring.p1] end
    nothing
end

I can try to create a MWE tomorrow...

[mateuszbaran]

Norm calculation by itself doesn't allocate any memory in StaticArrays.jl, I checked that with @benchmark (on Julia 1.8). What could have happened here is that the new norm code is slightly more involved and there is nonzero chance that inlining the new code into a complex function may interfere with some Julia optimization that elided an unrelated allocation but that's hard to track. If you can make an MWE I could look into it.

[ufechner7]

Simplified test. Probably it can be simplified further:

# unittest for StaticArrays
using StaticArrays, LinearAlgebra, BenchmarkTools, Test

const KVec3    = MVector{3, Float64}

Base.@kwdef mutable struct KPS4{S, T, P}
    v_apparent::T =       zeros(S, 3)
end

const kps4 = KPS4{Float64, KVec3, 6+4+1}()

@inline function calc_particle_forces!(s, pos1, pos2)
    segment = pos1 - pos2
    norm1 = norm(segment)
    unit_vector = segment / norm1

    v_app_perp = s.v_apparent - s.v_apparent ⋅ unit_vector * unit_vector
    half_drag_force = norm(v_app_perp)
    nothing
end

t = @benchmark calc_particle_forces!(kps4, pos1, pos2) setup=(pos1 = KVec3(1.0, 2.0, 3.0);  
                                        pos2 = KVec3(2.0, 3.0, 4.0))
@test t.memory == 0

My impression is that norm now allocates 32 bytes. This happens since StaticArrays 1.5.13.

[mateuszbaran]

Thank you, I will open a PR with a fix in a moment.

[ufechner7]

Thanks a lot for creating a PR so fast! 🥇