Not documented: how to access ibm_resource_key.objectstorage.credentials.cos_hmac_keys.access_key_id

[powellquiring]

In the example below it is possible to access ibm_resource_key.objectstorage.credentials.apikey but not the cos_hmac_keys.access_key_id and cos_hmac_keys.secret_access_key

resource "ibm_resource_instance" "objectstorage" {
  name              = "objectstorage"
  service           = "cloud-object-storage"
  plan              = var.cloudobjectstorage_plan
  location          = var.cloudobjectstorage_location
  resource_group_id = data.ibm_resource_group.group.id
}

resource "ibm_resource_key" "objectstorage" {
  name                 = "${var.environment_name}-cos-hmac-secret"
  role                 = "Writer"
  resource_instance_id = ibm_resource_instance.objectstorage.id

  parameters = {
     HMAC: true
  }
}
resource "kubernetes_secret" "cos" {
  type = "ibm/ibmc-s3fs"
  metadata {
    name = var.environment_name
  }
  data = {
    access-key = ibm_resource_key.objectstorage.credentials.cos_hmac_keys.access_key_id
    res-conf-apikey = ibm_resource_key.objectstorage.credentials.apikey
  }
}
➜  terraform git:(master) ✗ tfa
Error: Unsupported attribute
  on main.tf line 89, in resource "kubernetes_secret" "cos":
  89:     access-key = ibm_resource_key.objectstorage.credentials.cos_hmac_keys.access_key_id
This value does not have any attributes.

Snippet of the tf state file:

    {
      "mode": "managed",
      "type": "ibm_resource_key",
      "name": "objectstorage",
      "provider": "provider[\"registry.terraform.io/ibm-cloud/ibm\"]",
      "instances": [
        {
          "schema_version": 0,
          "attributes": {
            "credentials": {
              "apikey": "nNPVNt3NyadauyadayadayadaghjbTyPFy",
              "cos_hmac_keys.access_key_id": "6c2722b0yadyadayadayadae0c43d973",
              "cos_hmac_keys.secret_access_key": "65b4yadayadayadayadafd1a92a193ab5a5eed3",
              "endpoints": "https://control.cloud-object-storage.cloud.ibm.com/v2/endpoints",

[data-henrik]

see #1741

[data-henrik]

and https://stackoverflow.com/questions/64709253/this-value-does-not-have-any-attributes-error-while-trying-to-use-cos-hmac-crede

[powellquiring]

Duplicate of #1741

[powellquiring]

This worked:

resource "kubernetes_secret" "cos" {
  type = "ibm/ibmc-s3fs"
  metadata {
    name = var.environment_name
  }

  data = {
    access-key = ibm_resource_key.objectstorage.credentials["cos_hmac_keys.access_key_id"]
    secret-key = ibm_resource_key.objectstorage.credentials["cos_hmac_keys.secret_access_key"]
    res-conf-apikey = ibm_resource_key.objectstorage.credentials.apikey
  }
}

Please assign this to someone on the doc team.

I could not figure this out. I guess each of the services need to contribute service specific docs when required here: https://cloud.ibm.com/docs/terraform?topic=terraform-resource-mgmt-resources#resource-key

Or does each service create it's own add in section that discusses unique contribution?

[powellquiring]

https://registry.terraform.io/providers/IBM-Cloud/ibm/latest/docs/resources/resource_key

This isn't a string. Document what it really is.

[hkantare]

We will look into the issue in upcoming sprint