publish.gradle

apply plugin: 'maven-publish'
apply plugin: 'signing'

publishing {
    publications {
        all {
            pom {
                url = 'https://github.com/xenit-eu/dynamic-extensions-for-alfresco'
                name = "dynamic-extensions-for-alfresco-" + project.name
                description = "Adds an OSGi container to alfresco repository supporting dynamic code reloading, " +
                        "classpath isolation and a bunch of other useful features"

                scm {
                    connection = 'scm:git:git@github.com:xenit-eu/dynamic-extensions-for-alfresco.git'
                    developerConnection = 'scm:git:git@github.com:xenit-eu/dynamic-extensions-for-alfresco.git'
                    url = 'https://github.com/xenit-eu/dynamic-extensions-for-alfresco.git'
                }
                developers {
                    developer {
                        id = "xenit"
                        name = "Xenit Solutions NV"
                    }
                }

                licenses {
                    license {
                        name = 'The Apache License, Version 2.0'
                        url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                    }
                }
            }
        }
    }

    repositories {
        maven {
            def releasesRepoUrl = "https://s01.oss.sonatype.org/service/local/staging/deploy/maven2/"
            def snapshotsRepoUrl = "https://s01.oss.sonatype.org/content/repositories/snapshots/"
            url = version.endsWith('SNAPSHOT') ? snapshotsRepoUrl : releasesRepoUrl

            credentials {
                username = project.findProperty('sonatype_username')
                password = project.findProperty('sonatype_password')
            }
        }
    }
}

signing {
    required { !version.toString().endsWith("SNAPSHOT") }
    useInMemoryPgpKeys(findProperty("signingKeyId"), findProperty("signingKey"), findProperty("signingPassword"))
    sign publishing.publications
}