vortex/java/build.gradle.kts at develop · vortex-data/vortex · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
// SPDX-License-Identifier: Apache-2.0
// SPDX-FileCopyrightText: Copyright the Vortex contributors

import net.ltgt.gradle.errorprone.errorprone

plugins {
    id("com.diffplug.spotless") version "8.6.0"
    id("com.palantir.git-version") version "5.0.0"
    id("com.palantir.java-format") version "2.93.0"
    id("net.ltgt.errorprone") version "5.1.0" apply false
    id("com.vanniktech.maven.publish") version "0.36.0" apply false
}

subprojects {
    apply(plugin = "com.vanniktech.maven.publish")
}

val gitVersion: groovy.lang.Closure<String> by extra
version = gitVersion()

allprojects {
    apply(plugin = "com.diffplug.spotless")

    group = "dev.vortex"
    version = rootProject.version

    repositories {
        mavenCentral()
    }

    plugins.withType<JavaLibraryPlugin> {
        apply(plugin = "net.ltgt.errorprone")

        dependencies {
            "errorprone"("com.google.errorprone:error_prone_core:2.36.0")
            "errorprone"("com.jakewharton.nopen:nopen-checker:1.0.1")
            "compileOnly"("com.jakewharton.nopen:nopen-annotations:1.0.1")
        }

        spotless {
            java {
                palantirJavaFormat().formatJavadoc(true)
                licenseHeaderFile("${rootProject.projectDir}/.spotless/java-license-header.txt")
                removeUnusedImports()
                forbidWildcardImports()
                importOrder("")
                trimTrailingWhitespace()
                leadingTabsToSpaces(4)
                targetExclude("**/generated/**")
                targetExcludeIfContentContains("// spotless:disabled")
            }
        }

        tasks.withType<JavaCompile> {
            options.errorprone.disable("UnusedVariable")
            options.errorprone.disableWarningsInGeneratedCode = true
            options.release = 17
            options.compilerArgs.add("-Werror")

            options.generatedSourceOutputDirectory = projectDir.resolve("generated_src")
        }

        tasks.withType<Javadoc> {
            (options as StandardJavadocDocletOptions).addBooleanOption("Xdoclint:-missing", true)
        }

        the<JavaPluginExtension>().toolchain {
            languageVersion.set(JavaLanguageVersion.of(17))
            vendor.set(JvmVendorSpec.AMAZON)
        }

        tasks["check"].dependsOn("spotlessCheck")
    }

    spotless {
        kotlinGradle {
            ktlint()
        }
    }

    if (project.name == "vortex-spark_2.12") {
        // vortex-spark_2.12 and vortex-spark_2.13 share a projectDir; format from the 2.13 variant only.
        tasks.register("format") { enabled = false }
    } else {
        tasks.register("format").get().dependsOn("spotlessApply")
    }
}