common.gradle

// Gradle settings and tasks common to all jme-vehicles subprojects

apply plugin: 'checkstyle' // to analyze Java sourcecode for style violations
apply plugin: 'java'       // to compile and test Java projects

java {
    sourceCompatibility = JavaVersion.VERSION_1_8
    targetCompatibility = JavaVersion.VERSION_1_8
}

javadoc {
    // Disable doclint for JDK15+ to avoid "no comment" warnings.
    if (JavaVersion.current().isCompatibleWith(JavaVersion.VERSION_15)) {
        options.addStringOption('Xdoclint:none', '-quiet')
    }
}

checkstyle {
    toolVersion libs.versions.checkstyle.get()
}

tasks.withType(JavaCompile).configureEach { // Java compile-time options:
    options.compilerArgs << '-Xdiags:verbose'
    if (JavaVersion.current().isCompatibleWith(JavaVersion.VERSION_20)) {
        // Suppress warnings that source value 8 is obsolete.
        options.compilerArgs << '-Xlint:-options'
    }
    options.compilerArgs << '-Xlint:unchecked'
    options.deprecation = true // to provide detailed deprecation warnings
    options.encoding = 'UTF-8'
    if (JavaVersion.current().isCompatibleWith(JavaVersion.VERSION_1_10)) {
        options.release = 8
    }
}

import org.gradle.nativeplatform.platform.internal.DefaultNativePlatform
Boolean isMacOS = DefaultNativePlatform.currentOperatingSystem.isMacOsX()

tasks.withType(JavaExec).configureEach { // Java runtime options:
    if (isMacOS) {
        args '--noDialog'
        jvmArgs '-XstartOnFirstThread'
    }
    enableAssertions true
    //jvmArgs '-verbose:gc'
    jvmArgs '-Xms512m', '-Xmx512m' // to enlarge the Java heap
    jvmArgs '-XX:MaxDirectMemorySize=1200m' // to limit memory consumption by direct buffers
    //jvmArgs '-XX:+UseG1GC', '-XX:MaxGCPauseMillis=10'
}

// Register custom tasks for creating source/javadoc JARs:

tasks.register('javadocJar', Jar) {
    archiveClassifier = 'javadoc'
    dependsOn 'javadoc'
    description 'Creates a JAR of javadoc.'
    from javadoc.destinationDir
}

tasks.register('sourcesJar', Jar) {
    archiveClassifier = 'sources'
    description 'Creates a JAR of sourcecode.'
    from sourceSets.main.allJava // default is ".allSource", which includes resources
}