build.gradle

plugins {
	id 'groovy'
	id 'org.springframework.boot'
	id 'io.spring.dependency-management'
	id 'maven-publish'
}

group = 'com.example'
version = '0.0.1-SNAPSHOT'
sourceCompatibility = '17'

repositories {
	mavenCentral()
	mavenLocal()
	maven { url "https://repo.spring.io/snapshot" }
	maven { url "https://repo.spring.io/milestone" }
}

ext {
	set('springCloudVersion', "${BOM_VERSION}")
	set('camelVersion', "3.11.0")
}

println "Boot Version [${bootVersion}], Cloud version [${BOM_VERSION}]"

dependencies {
	implementation("org.apache.camel.springboot:camel-spring-boot-starter:${camelVersion}")
	implementation("org.apache.camel:camel-jackson:${camelVersion}")
	implementation("org.apache.camel:camel-xstream:${camelVersion}")
	implementation("org.apache.camel:camel-rabbitmq:${camelVersion}")

	testImplementation("org.springframework.boot:spring-boot-starter-test")
	testImplementation("org.glassfish.jaxb:jaxb-runtime:2.4.0-b180830.0438")
	testImplementation("org.springframework.cloud:spring-cloud-starter-contract-stub-runner")
}

dependencyManagement {
	imports {
		mavenBom "org.springframework.cloud:spring-cloud-dependencies:${springCloudVersion}"
	}
}

test {
	useJUnitPlatform()
	testLogging {
		exceptionFormat = 'full'
	}
	afterSuite { desc, result ->
		if (!desc.parent) {
			println "Results: (${result.testCount} tests, ${result.successfulTestCount} successes, ${result.failedTestCount} failures, ${result.skippedTestCount} skipped)"
			boolean skipTests = Boolean.parseBoolean(project.findProperty('SKIP_TESTS') ?: "false")
			if (result.testCount == 0 && !skipTests) {
				throw new IllegalStateException("No tests were found. Failing the build")
			}
		}
	}
}

publishing {
	publications {
		mavenJava(MavenPublication) {
			artifact bootJar

			// https://github.com/spring-gradle-plugins/dependency-management-plugin/issues/273
			versionMapping {
				usage("java-api") {
					fromResolutionOf("runtimeClasspath")
				}
				usage("java-runtime") {
					fromResolutionResult()
				}
			}
		}
	}
}