support tflu

this removes the need to patch the AmbiqSuite SDK
- startup_gcc_tflu.c has an increased stack size
- apollo3_tflu.ld is a linker script that provides the necessary symbols and C++ initialization array

Author: oclyke

common/tools_sfe/templates/apollo3_tflu.ld

@@ -0,0 +1,77 @@
+/******************************************************************************
+ *
+ * apollo3_tflu.ld - linker script for apollo3 targets in tensorflow lite micro
+ *
+ *****************************************************************************/
+ENTRY(Reset_Handler)
+
+MEMORY
+{
+    FLASH (rx) : ORIGIN = 0x0000C000, LENGTH = 960K
+    SRAM (rwx) : ORIGIN = 0x10000000, LENGTH = 384K
+}
+
+SECTIONS
+{
+    .text :
+    {
+        . = ALIGN(4);
+        KEEP(*(.isr_vector))
+        KEEP(*(.patch))
+        *(.text)
+        *(.text*)
+
+	/* These are the C++ global constructors.  Stick them all here and
+	 * then walk through the array in main() calling them all.
+	 */
+	_init_array_start = .;
+	KEEP (*(SORT(.init_array*)))
+	_init_array_end = .;
+
+	/* XXX Currently not doing anything for global destructors. */
+
+        *(.rodata)
+        *(.rodata*)
+        . = ALIGN(4);
+        _etext = .;
+    } > FLASH
+
+    /* User stack section initialized by startup code. */
+    .stack (NOLOAD):
+    {
+        . = ALIGN(8);
+        *(.stack)
+        *(.stack*)
+        . = ALIGN(8);
+    } > SRAM
+
+    .data :
+    {
+        . = ALIGN(4);
+        _sdata = .;
+        *(.data)
+        *(.data*)
+        . = ALIGN(4);
+        _edata = .;
+    } > SRAM AT>FLASH
+
+    /* used by startup to initialize data */
+    _init_data = LOADADDR(.data);
+
+    .bss :
+    {
+        . = ALIGN(4);
+        _sbss = .;
+        *(.bss)
+        *(.bss*)
+        *(COMMON)
+        . = ALIGN(4);
+        _ebss = .;
+    } > SRAM
+    /* Add this to satisfy reference to symbol "end" from libnosys.a(sbrk.o)
+     * to denote the HEAP start.
+     */
+   end = .;
+
+    .ARM.attributes 0 : { *(.ARM.attributes) }
+}