Don't minify JS files on debug builds (#369)

Signed-off-by: Juan Cruz Viotti <jv@jviotti.com>

Author: jviotti

CMakeLists.txt

@@ -35,6 +35,8 @@ if(REGISTRY_INDEX OR REGISTRY_SERVER)
 endif()
 
 if(REGISTRY_INDEX)
+  include(commands/esbuild)
+  include(commands/redocly)
   add_subdirectory(src/configuration)
   add_subdirectory(src/resolver)
   add_subdirectory(src/index)

cmake/commands/esbuild.cmake

@@ -0,0 +1,34 @@
+function(sourcemeta_esbuild_bundle)
+  cmake_parse_arguments(SOURCEMETA_ESBUILD_BUNDLE "" "ENTRYPOINT;OUTPUT" "DEPENDS" ${ARGN})
+
+  if(NOT SOURCEMETA_ESBUILD_BUNDLE_ENTRYPOINT)
+    message(FATAL_ERROR "You must pass the ENTRYPOINT option to ${CMAKE_CURRENT_FUNCTION}")
+  endif()
+  if(NOT SOURCEMETA_ESBUILD_BUNDLE_OUTPUT)
+    message(FATAL_ERROR "You must pass the OUTPUT option to ${CMAKE_CURRENT_FUNCTION}")
+  endif()
+
+  find_program(ESBUILD_BIN NAMES esbuild REQUIRED)
+
+  if(CMAKE_BUILD_TYPE STREQUAL "Release")
+    set(ESBUILD_OPTIONS "--minify")
+  else()
+    set(ESBUILD_OPTIONS "")
+  endif()
+
+  if(SOURCEMETA_ESBUILD_BUNDLE_DEPENDS)
+    add_custom_command(
+      OUTPUT "${SOURCEMETA_ESBUILD_BUNDLE_OUTPUT}"
+      COMMAND "${ESBUILD_BIN}" --bundle "${SOURCEMETA_ESBUILD_BUNDLE_ENTRYPOINT}"
+              --outfile="${SOURCEMETA_ESBUILD_BUNDLE_OUTPUT}"
+              ${ESBUILD_OPTIONS}
+      DEPENDS "${SOURCEMETA_ESBUILD_BUNDLE_ENTRYPOINT}" ${SOURCEMETA_ESBUILD_BUNDLE_DEPENDS})
+  else()
+    add_custom_command(
+      OUTPUT "${SOURCEMETA_ESBUILD_BUNDLE_OUTPUT}"
+      COMMAND "${ESBUILD_BIN}" --bundle "${SOURCEMETA_ESBUILD_BUNDLE_ENTRYPOINT}"
+              --outfile="${SOURCEMETA_ESBUILD_BUNDLE_OUTPUT}"
+              ${ESBUILD_OPTIONS}
+      DEPENDS "${SOURCEMETA_ESBUILD_BUNDLE_ENTRYPOINT}")
+  endif()
+endfunction()

cmake/commands/redocly.cmake

@@ -0,0 +1,29 @@
+function(sourcemeta_redocly_openapi_to_html)
+  cmake_parse_arguments(SOURCEMETA_REDOCLY_OPENAPI_TO_HTML "" "REDOCLY;INPUT;OUTPUT" "DEPENDS" ${ARGN})
+
+  if(NOT SOURCEMETA_REDOCLY_OPENAPI_TO_HTML_REDOCLY)
+    message(FATAL_ERROR "You must pass the REDOCLY option to ${CMAKE_CURRENT_FUNCTION}")
+  endif()
+
+  if(NOT SOURCEMETA_REDOCLY_OPENAPI_TO_HTML_INPUT)
+    message(FATAL_ERROR "You must pass the INPUT option to ${CMAKE_CURRENT_FUNCTION}")
+  endif()
+
+  if(NOT SOURCEMETA_REDOCLY_OPENAPI_TO_HTML_OUTPUT)
+    message(FATAL_ERROR "You must pass the OUTPUT option to ${CMAKE_CURRENT_FUNCTION}")
+  endif()
+
+  find_program(NODE_BIN NAMES node REQUIRED)
+
+  set(SOURCEMETA_REDOCLY_OPENAPI_TO_HTML_ALL_DEPS "${SOURCEMETA_REDOCLY_OPENAPI_TO_HTML_INPUT}")
+  if(SOURCEMETA_REDOCLY_OPENAPI_TO_HTML_DEPENDS)
+    list(APPEND SOURCEMETA_REDOCLY_OPENAPI_TO_HTML_ALL_DEPS ${SOURCEMETA_REDOCLY_OPENAPI_TO_HTML_DEPENDS})
+  endif()
+
+  add_custom_command(
+    OUTPUT "${SOURCEMETA_REDOCLY_OPENAPI_TO_HTML_OUTPUT}"
+    COMMAND "${NODE_BIN}" "${SOURCEMETA_REDOCLY_OPENAPI_TO_HTML_REDOCLY}"
+      build-docs --disableGoogleFont --output "${SOURCEMETA_REDOCLY_OPENAPI_TO_HTML_OUTPUT}"
+      "${SOURCEMETA_REDOCLY_OPENAPI_TO_HTML_INPUT}"
+    DEPENDS ${SOURCEMETA_REDOCLY_OPENAPI_TO_HTML_ALL_DEPS})
+endfunction()

src/index/CMakeLists.txt

@@ -58,19 +58,26 @@ install(TARGETS sourcemeta_registry_index
   RUNTIME DESTINATION "${CMAKE_INSTALL_BINDIR}"
   COMPONENT sourcemeta_registry)
 
-# Generate JS
-find_program(ESBUILD_BIN NAMES esbuild REQUIRED)
-add_custom_command(OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/main.min.js"
-  COMMAND "${ESBUILD_BIN}" --bundle 
-    "${CMAKE_CURRENT_SOURCE_DIR}/assets/main.js"
-    --outfile="${CMAKE_CURRENT_BINARY_DIR}/main.min.js"
-    --minify
+sourcemeta_esbuild_bundle(
+  ENTRYPOINT "${CMAKE_CURRENT_SOURCE_DIR}/assets/main.js" 
+  OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/main.min.js" 
   DEPENDS 
     "${CMAKE_CURRENT_SOURCE_DIR}/assets/main.js"
     "${CMAKE_CURRENT_SOURCE_DIR}/assets/search.js"
     "${CMAKE_CURRENT_SOURCE_DIR}/assets/tabs.js"
     "${CMAKE_CURRENT_SOURCE_DIR}/assets/editor.js")
-target_sources(sourcemeta_registry_index PRIVATE "${CMAKE_CURRENT_BINARY_DIR}/main.min.js")
+target_sources(sourcemeta_registry_index 
+  PRIVATE "${CMAKE_CURRENT_BINARY_DIR}/main.min.js")
+
+sourcemeta_redocly_openapi_to_html(
+  REDOCLY "${PROJECT_SOURCE_DIR}/node_modules/@redocly/cli/bin/cli.js" 
+  INPUT "${PROJECT_SOURCE_DIR}/openapi/openapi.yaml" 
+  OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/openapi.html"
+  DEPENDS
+    "${PROJECT_SOURCE_DIR}/package.json"
+    "${PROJECT_SOURCE_DIR}/package-lock.json")
+target_sources(sourcemeta_registry_index 
+  PRIVATE "${CMAKE_CURRENT_BINARY_DIR}/openapi.html")
 
 # Generate CSS
 include(BootstrapFiles)
@@ -85,18 +92,6 @@ add_custom_command(OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/style.min.css"
     ${BOOTSTRAP_SCSS_FILES})
 target_sources(sourcemeta_registry_index PRIVATE "${CMAKE_CURRENT_BINARY_DIR}/style.min.css")
 
-# Generate OpenAPI docs
-find_program(NODE_BIN NAMES node REQUIRED)
-add_custom_command(OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/openapi.html"
-  COMMAND "${NODE_BIN}" "${PROJECT_SOURCE_DIR}/node_modules/@redocly/cli/bin/cli.js" 
-    build-docs --disableGoogleFont --output "${CMAKE_CURRENT_BINARY_DIR}/openapi.html" 
-    "${PROJECT_SOURCE_DIR}/openapi/openapi.yaml"
-  DEPENDS
-    "${PROJECT_SOURCE_DIR}/openapi/openapi.yaml"
-    "${PROJECT_SOURCE_DIR}/package.json"
-    "${PROJECT_SOURCE_DIR}/package-lock.json")
-target_sources(sourcemeta_registry_index PRIVATE "${CMAKE_CURRENT_BINARY_DIR}/openapi.html")
-
 # Generate static files
 set(REGISTRY_STATIC
   "${CMAKE_CURRENT_BINARY_DIR}/openapi.html"

src/index/assets/main.js

@@ -24,7 +24,7 @@ document.querySelectorAll('[data-sourcemeta-ui-editor-highlight]').forEach((elem
     const url = element.getAttribute('data-sourcemeta-ui-editor-highlight');
     const pointer = element.getAttribute('data-sourcemeta-ui-editor-highlight-pointer');
     if (EDITORS[url]) {
-      const positions = await window.fetch(`${url}?positions=1`);
+      const positions = await window.fetch(`/api/schemas/positions${url.replace(/\.json$/i, "")}`);
       if (!positions.ok) {
         throw new Error(positions.statusText);
       }