Migrate buildSrc scripts to build-logic

build-logic/build.gradle.kts

@@ -0,0 +1,3 @@
+plugins {
+    `kotlin-dsl`
+}

build-logic/settings.gradle.kts

@@ -0,0 +1,15 @@
+@file:Suppress("UnstableApiUsage")
+
+dependencyResolutionManagement {
+    repositories {
+        gradlePluginPortal()
+        mavenCentral()
+    }
+    versionCatalogs {
+        register("libs") {
+            from(files("../gradle/libs.versions.toml")) // include from parent project
+        }
+    }
+}
+
+rootProject.name = "build-logic"

build-logic/src/main/kotlin/jagr-publish.gradle.kts

@@ -0,0 +1,53 @@
+import java.net.URI
+
+plugins {
+    java
+    `maven-publish`
+}
+
+extensions.configure<JavaPluginExtension> {
+    withJavadocJar()
+    withSourcesJar()
+}
+
+extensions.configure<PublishingExtension> {
+    repositories {
+        maven {
+            credentials {
+                username = project.findProperty("sonatypeUsername") as? String
+                password = project.findProperty("sonatypePassword") as? String
+            }
+            val releasesRepoUrl = "https://s01.oss.sonatype.org/service/local/staging/deploy/maven2/"
+            val snapshotsRepoUrl = "https://s01.oss.sonatype.org/content/repositories/snapshots"
+            url = URI(if (version.toString().endsWith("SNAPSHOT")) snapshotsRepoUrl else releasesRepoUrl)
+        }
+    }
+    publications {
+        register<MavenPublication>("maven") {
+            from(components["java"])
+            pom {
+                name.set("jagr")
+                description.set("An automated tool for grading programming assignments")
+                url.set("https://www.sourcegrade.org")
+                scm {
+                    url.set("https://github.com/sourcegrade/jagr")
+                    connection.set("scm:git:https://github.com/sourcegrade/jagr.git")
+                    developerConnection.set("scm:git:https://github.com/sourcegrade/jagr.git")
+                }
+                licenses {
+                    license {
+                        name.set("GNU AFFERO GENERAL PUBLIC LICENSE Version 3")
+                        url.set("https://www.gnu.org/licenses/agpl-3.0.html")
+                        distribution.set("repo")
+                    }
+                }
+                developers {
+                    rootProject.file("authors").readLines()
+                        .asSequence()
+                        .map { it.split(",") }
+                        .forEach { (_id, _name) -> developer { id.set(_id); name.set(_name) } }
+                }
+            }
+        }
+    }
+}

build-logic/src/main/kotlin/jagr-sign.gradle.kts

@@ -0,0 +1,12 @@
+plugins {
+    signing
+}
+
+extensions.configure<PublishingExtension> {
+    publications {
+        val maven = getByName<MavenPublication>("maven")
+        extensions.configure<SigningExtension> {
+            sign(maven)
+        }
+    }
+}

core/build.gradle.kts

@@ -1,12 +1,10 @@
-import org.sourcegrade.jagr.script.JagrPublishPlugin
-
 plugins {
     kotlin("jvm")
     kotlin("plugin.serialization")
+    id("jagr-publish")
+    id("jagr-sign")
 }
 
-apply<JagrPublishPlugin>()
-
 dependencies {
     api(project(":jagr-launcher"))
     implementation(libs.csv)

grader-api/build.gradle.kts

@@ -1,11 +1,9 @@
-import org.sourcegrade.jagr.script.JagrPublishPlugin
-
 plugins {
     `java-library`
+    id("jagr-publish")
+    id("jagr-sign")
 }
 
-apply<JagrPublishPlugin>()
-
 tasks {
     withType<PublishToMavenRepository> {
         // check if rootProject version ends with .0 or .0-SNAPSHOT

launcher/build.gradle.kts

@@ -1,15 +1,14 @@
-import org.sourcegrade.jagr.script.JagrPublishPlugin
 import org.sourcegrade.jagr.script.apiProject
 
 plugins {
     kotlin("jvm")
     kotlin("kapt")
     kotlin("plugin.serialization")
     id("com.github.johnrengelman.shadow")
+    id("jagr-publish")
+    id("jagr-sign")
 }
 
-apply<JagrPublishPlugin>()
-
 dependencies {
     apiProject(project, "jagr-grader-api")
     api(libs.coroutines)

launcher/gradle-plugin/build.gradle.kts

@@ -1,15 +1,13 @@
-import org.sourcegrade.jagr.script.JagrPublishPlugin
-
 @Suppress("DSL_SCOPE_VIOLATION") // https://youtrack.jetbrains.com/issue/KTIJ-19369
 plugins {
     `java-gradle-plugin`
     alias(libs.plugins.gradle.publish)
     alias(libs.plugins.kotlin.jvm)
     alias(libs.plugins.kotlin.serialization)
+    id("jagr-publish")
+    // signing done by gradle-publish plugin
 }
 
-apply<JagrPublishPlugin>()
-
 tasks {
     withType<PublishToMavenRepository> {
         onlyIf { project.version.toString().endsWith("-SNAPSHOT") }

settings.gradle.kts

@@ -7,6 +7,14 @@ dependencyResolutionManagement {
     }
 }
 
+pluginManagement {
+    includeBuild("build-logic")
+    repositories {
+        mavenCentral()
+        gradlePluginPortal()
+    }
+}
+
 rootProject.name = "jagr"
 
 include(":jagr-launcher-gradle-plugin")