initial commit

Author: skywind3000

.gitignore

@@ -158,3 +158,6 @@ cython_debug/
 #  and can be added to the global gitignore or merged into this file.  For a more nuclear
 #  option (not recommended) you can uncomment the following to ignore the entire idea folder.
 #.idea/
+
+/update.cmd
+

autoload/cpatch.vim

@@ -0,0 +1,66 @@
+"======================================================================
+"
+" cpatch.vim - help functions
+"
+" Created by skywind on 2024/01/05
+" Last Modified: 2024/01/05 16:29:52
+"
+"======================================================================
+
+
+"----------------------------------------------------------------------
+" remove style
+"----------------------------------------------------------------------
+function! cpatch#remove_style(what) abort
+	let need = ['underline', 'undercurl', 'reverse', 'inverse', 'italic']
+	call extend(need, ['standout', 'bold'])
+	call filter(need, 'v:val != a:what')
+	let hid = 1
+	while 1
+		let hln = synIDattr(hid, 'name')
+		if !hlexists(hln) | break | endif
+		if hid == synIDtrans(hid) 
+			let change = ''
+			for mode in ['gui', 'term', 'cterm']
+				if synIDattr(hid, a:what, mode)
+					let atr = deepcopy(need)
+					call filter(atr, 'synIDattr(hid, v:val, mode)')
+					let result = empty(atr) ? 'NONE' : join(atr, ',')
+					let change .= printf(' %s=%s', mode, result)
+				endif
+			endfor
+			if change != ''
+				exec 'highlight ' . hln . ' ' . change
+			endif
+		endif
+		let hid += 1
+	endwhile
+endfunc
+
+
+
+"----------------------------------------------------------------------
+" 
+"----------------------------------------------------------------------
+function! cpatch#disable_italic() abort
+	call cpatch#remove_style('italic')
+endfunc
+
+
+"----------------------------------------------------------------------
+" 
+"----------------------------------------------------------------------
+function! cpatch#disable_bold() abort
+	call cpatch#remove_style('bold')
+endfunc
+
+
+"----------------------------------------------------------------------
+" 
+"----------------------------------------------------------------------
+function! cpatch#remove_background(group) abort
+	exe printf('hi %s ctermbg=NONE guibg=NONE', a:group)
+endfunc
+
+
+

plugin/cpatch.vim

@@ -0,0 +1,138 @@
+" vim: set ts=4 sw=4 tw=78 noet :"
+"======================================================================
+"
+" cpatch.vim - load colorscheme patch automatically
+"
+" Created by skywind on 2024/01/05
+" Last Modified: 2024/01/05 14:48:57
+"
+" USAGE:
+" 
+" This script will load colorscheme patch when current color changed
+" 
+"   let g:cpatch_path = '~/.vim/cpatch'
+"
+" After setting "g:cpatch_path", if you change the current color:
+"   
+"   :color {NAME}
+"
+" This script will try to load the following scripts in order:
+"
+"   1) "~/.vim/cpatch/__init__.vim"
+"   2) "~/.vim/cpatch/{NAME}.vim"
+"
+" The first script "__init__.vim" in the "g:cpatch_path" folder will 
+" be loaded for every colorscheme
+"
+"======================================================================
+
+
+"----------------------------------------------------------------------
+" configuration
+"----------------------------------------------------------------------
+
+" color patch path: script will be searched here
+let g:cpatch_path = get(g:, 'cpatch_path', '')
+
+" color patch subdirectory in every runtime path
+let g:cpatch_name = get(g:, 'cpatch_name', '')
+
+" runtime bang
+let g:cpatch_bang = get(g:, 'cpatch_bang', 0)
+
+
+"----------------------------------------------------------------------
+" load script
+"----------------------------------------------------------------------
+function! s:load_patch(name, force)
+	let names = ['__init__.vim', a:name .. '.vim']
+	let paths = []
+	let s:previous_color = get(s:, 'previous_color', '')
+	if a:force == 0
+		if a:name == s:previous_color
+			return 1
+		endif
+	endif
+	let s:previous_color = a:name
+	if type(g:cpatch_path) == type('')
+		let paths = split(g:cpatch_path, ',')
+	elseif type(g:cpatch_path) == type([])
+		let paths = g:cpatch_path
+	endif
+	for name in names
+		let rtpname = g:cpatch_name .. '/' .. name
+		if g:cpatch_name != ''
+			let bang = (g:cpatch_bang == 0)? '' : '!'
+			try
+				exec printf('runtime%s %s', bang, fnameescape(rtpname))
+			catch
+				let msg = v:throwpoint
+				let p1 = stridx(msg, '_load_patch[')
+				if p1 > 0
+					let p2 = stridx(msg, ']..', p1)
+					if p2 > 0
+						let msg = strpart(msg, p2 + 3)
+					endif
+				endif
+				redraw
+				echohl ErrorMsg
+				echom 'Error detected in ' . msg
+				echom v:exception
+				echohl None
+			endtry
+		endif
+		for p in paths
+			if p == ''
+				continue
+			endif
+			let p = expand(p)
+			if isdirectory(p)
+				if p !~ '\v[\/\\]$'
+					let p = p .. '/'
+				endif
+				let p = tr(p, '\', '/')
+				let t = p .. name
+				if filereadable(t)
+					try
+						exec 'source ' .. fnameescape(t)
+					catch
+						let msg = v:throwpoint
+						let p1 = stridx(msg, '_load_patch[')
+						if p1 > 0
+							let p2 = stridx(msg, ']..', p1)
+							if p2 > 0
+								let msg = strpart(msg, p2 + 3)
+							endif
+						endif
+						redraw
+						echohl ErrorMsg
+						echom 'Error detected in ' . msg
+						echom v:exception
+						echohl None
+					endtry
+				endif
+			endif
+		endfor
+	endfor
+	return 0
+endfunc
+
+
+"----------------------------------------------------------------------
+" load script
+"----------------------------------------------------------------------
+let g:colors_name = get(g:, 'colors_name', '')
+call s:load_patch(g:colors_name, 0)
+
+
+"----------------------------------------------------------------------
+" autocmd
+"----------------------------------------------------------------------
+augroup CPatchEventGroup
+	au!
+	au VimEnter * call s:load_patch(g:colors_name, 0)
+	au ColorScheme * call s:load_patch(expand('<amatch>'), 1)
+augroup END
+
+
+