qml: Add Information.qml in src/qml/controls

- This is an object similar to Setting.qml
- Instead of a switch button this allows to have the text as the
  option's value.
- The text could also double as an hyperlink if the link is given.
- The header text has the property that it could be set to be an
  editable text.
- Adds an optional property to display image instead of descriptive
  text, which also optionally can have a link attached to it.

Author: shaavan

src/Makefile.qt.include

@@ -309,6 +309,7 @@ QML_RES_QML = \
   qml/components/StorageOptions.qml \
   qml/controls/ContinueButton.qml \
   qml/controls/Header.qml \
+  qml/controls/Information.qml \
   qml/controls/PageIndicator.qml \
   qml/controls/OptionButton.qml \
   qml/controls/OptionSwitch.qml \

src/qml/bitcoin_qml.qrc

@@ -6,6 +6,7 @@
         <file>components/StorageOptions.qml</file>
         <file>controls/ContinueButton.qml</file>
         <file>controls/Header.qml</file>
+        <file>controls/Information.qml</file>
         <file>controls/PageIndicator.qml</file>
         <file>controls/OptionButton.qml</file>
         <file>controls/OptionSwitch.qml</file>

src/qml/controls/Information.qml

@@ -0,0 +1,90 @@
+// Copyright (c) 2022 The Bitcoin Core developers
+// Distributed under the MIT software license, see the accompanying
+// file COPYING or http://www.opensource.org/licenses/mit-license.php.
+
+import QtQuick 2.15
+import QtQuick.Controls 2.15
+import QtQuick.Layouts 1.15
+
+Control {
+    id: root
+    property bool last: parent && root === parent.children[parent.children.length - 1]
+    required property string header
+    property string subtext
+    property int subtextMargin: 3
+    property string description
+    property int descriptionMargin: 10
+    property int descriptionSize: 18
+    property bool isReadonly: true
+    property bool hasIcon: false
+    property string iconSource
+    property int iconWidth: 30
+    property int iconHeight: 30
+    property string link
+    contentItem: ColumnLayout {
+        spacing: 20
+        width: parent.width
+        RowLayout {
+            Header {
+                Layout.fillWidth: true
+                center: false
+                header: root.header
+                headerSize: 18
+                description: root.subtext
+                descriptionSize: 15
+                descriptionMargin: root.subtextMargin
+                wrap: false
+            }
+            Loader {
+                Layout.fillWidth: true
+                Layout.preferredWidth: 0
+                Layout.rightMargin: 12
+                active: root.description.length > 0
+                visible: active
+                sourceComponent: TextEdit {
+                    topPadding: root.descriptionMargin
+                    font.family: "Inter"
+                    font.styleName: "Regular"
+                    font.pointSize: root.descriptionSize
+                    color: Theme.color.neutral8
+                    textFormat: Text.RichText
+                    text: "<style>a:link { color: " + Theme.color.neutral8 + "; text-decoration: none;}</style>" + "<a href=\"" + link + "\">" + root.description + "</a>"
+                    readOnly: isReadonly
+                    onLinkActivated: Qt.openUrlExternally(link)
+                    horizontalAlignment: Text.AlignRight
+                    wrapMode: Text.WordWrap
+                }
+            }
+            Loader {
+                Layout.preferredWidth: root.iconWidth
+                Layout.preferredHeight: root.iconHeight
+                Layout.alignment: Qt.AlignRight
+                Layout.rightMargin: 12
+                active: root.hasIcon
+                visible: active
+                sourceComponent: Image {
+                    horizontalAlignment: Image.AlignRight
+                    source: root.iconSource
+                    fillMode: Image.PreserveAspectFit
+                    mipmap: true
+                    MouseArea {
+                        anchors.fill: parent
+                        onClicked: {
+                            Qt.openUrlExternally(link)
+                        }
+                    }
+                }
+            }
+        }
+        Loader {
+            Layout.fillWidth:true
+            Layout.columnSpan: 2
+            active: !last
+            visible: active
+            sourceComponent: Rectangle {
+                height: 1
+                color: Theme.color.neutral5
+            }
+        }
+    }
+}