uom data conversion explanation and queries

Author: philblackwood

migration/v13.0/queries/checkAspects.rq

@@ -0,0 +1,22 @@
+# sanity check: see if you have found all of the Aspects returned by this query
+# 
+# some possibilities: 
+#
+#    - Aspect defined but never used
+#    - Aspect used by pattern not included in the queries (investigate and write custom queries)
+#
+select ?possibleAspect
+where {
+
+  {
+    ?possibleAspect  (rdfs:subClassOf|(owl:equivalentClass/owl:intersectionOf/rdf:first))+ gist:Magnitude .
+
+    filter(?possibleAspect != gist:ReferenceValue)
+  }
+  union
+  {
+   ?possibleAspect rdfs:subClassOf+ gist:Aspect .
+  }
+
+  }
+

migration/v13.0/queries/findAspects1-template.rq

@@ -0,0 +1,49 @@
+# find existing Aspects that are represented as either:
+#
+#   - a property of a Magnitude 
+#   - or the value of a property of a Magnitude
+#
+# use this query iteratively as follows:
+#
+#   - run the query
+#   - pick a few lines of output
+#   - update the upper section of the query with concepts that do NOT involve an Aspect
+#   - update the lower section of the query (filter not exists) with properties and values that DO represent Aspects
+#   - repeat
+#
+# this iterative process accounts for every property and value associated with a Magnitude
+# when the query returns no results, every row of the original output has been accounted for
+
+select distinct ?magnitudeProperty ?magnitudePropertyValue
+
+where {
+  
+   ?magnitude gist:hasUnitOfMeasure ?unit ;
+              ?magnitudeProperty ?magnitudePropertyValue ;
+              .
+              
+   filter(?magnitudeProperty not in (   # properties that do not involve an Aspect
+           gist:hasUnitOfMeasure,
+           gist:numericValue,
+           skos:definition,
+           skos:scopeNote,
+           skos:prefLabel,
+           rdfs:isDefinedBy
+           )) 
+              
+   filter(?magnitudePropertyValue not in (     # values that do not represent Aspects
+           gist:Magnitude,
+           owl:Thing,
+           owl:NamedIndividual
+           ))
+   
+
+  filter not exists {
+
+     values (?magnitudeProperty     ?magnitudePropertyValue) {    # property/value pairs with a property or value that represents an Aspect
+       
+            (rdf:type               gist:Duration)            # sample value
+            }
+  }
+}
+order by ?magnitudeProperty ?magnitudePropertyValue

migration/v13.0/queries/findAspects2-template.rq

@@ -0,0 +1,75 @@
+# find existing Aspects that are represented as either:
+#
+#   - a property of a Thing with a Magnitude or
+#   - the value of the property
+#
+# use this query iteratively as follows:
+#
+#   - run the query
+#   - pick a few lines of output
+#   - update the upper section of the query with concepts that do NOT involve an Aspect
+#   - update the lower section of the query (filter not exists) with properties and values that DO represent Aspects
+#   - repeat
+#
+# this iterative process accounts for every property and value associated with a Magnitude
+# when the query returns no results, every row of the original output has been accounted for
+
+
+
+select distinct  ?thingProperty ?thingPropertyValue
+
+where {
+  
+   ?magnitude gist:hasUnitOfMeasure ?unit .
+
+   ?thing gist:hasMagnitude ?magnitude ;
+          ?thingProperty ?thingPropertyValue ;
+          .
+                
+   filter(?thingProperty not in (         # properties that do not represent and Aspect and never have a value that represents an Aspect
+           gist:actualEndMicrosecond,
+           gist:actualEndMinute,
+           gist:actualStartAtDate,
+           gist:actualStartMinute,
+           gist:conformsTo,
+           gist:containedText,
+           gist:description,
+           gist:hasDirectPart,
+           gist:hasGoal,
+           gist:hasMagnitude,
+           gist:hasPart,
+           gist:hasPhysicalLocation,
+           gist:isAffectedBy,
+           gist:isBasedOn,
+           gist:isConnectedTo,
+           gist:isRecognizedBy,
+           gist:isRecordedAt,
+           gist:name,
+           gist:plannedEndDate,
+           gist:plannedStartDate,
+           gist:uniqueText,
+           rdfs:comment,
+           rdfs:isDefinedBy,
+           skos:altLabel,
+           skos:definition,
+           skos:prefLabel,
+           skos:scopeNote
+
+           )) 
+              
+   filter(?thingPropertyValue not in (         # values that do not represent Aspects
+
+          gist:Event,             # sample value
+          owl:NamedIndividual,
+          owl:Thing
+          ))
+
+  filter not exists {
+
+     values (?thingProperty     ?thingPropertyValue) {    # property/value pairs with a property or value that represents an Aspect
+                                                 
+
+            }
+  }
+}
+order by ?thingProperty ?thingPropertyValue

migration/v13.0/queries/findAspects3-template.rq

@@ -0,0 +1,32 @@
+# find existing Aspects that are represented as a property with a Magnitude as object
+# (e.g. hasMass)
+#
+# use this query iteratively as follows:
+#
+#   - run the query
+#   - pick a few lines of output
+#   - update the upper section of the query with properties that do NOT represent an Aspect
+#   - update the lower section of the query (filter not exists) with properties that DO represent Aspects
+#   - repeat
+#
+# this iterative process accounts for every property that has a a Magnitude as object
+# when the query returns no results, every row of the original output has been accounted for
+
+
+select distinct ?thingToMagnitudeProperty
+
+where {
+  
+  ?magnitude gist:hasUnitOfMeasure ?unit .
+  
+  ?thing ?thingToMagnitudeProperty ?magnitude .
+
+  filter (?thingToMagnitudeProperty != gist:hasMagnitude)   # properties that do not represent an Aspect
+  
+  filter not exists {
+
+    values ?thingToMagnitudeProperty {     # properties that represent a Magnitude
+
+       }
+    }
+  } order by ?thingToMagnitudeProperty

migration/v13.0/queries/findAspects4-template.rq

@@ -0,0 +1,6 @@
+# find Aspects that are the subject of gist:isAspectOf
+
+select ?aspect
+
+where { ?aspect gist:isAspectOf ?x .}
+

migration/v13.0/queries/findAspects5-template.rq

@@ -0,0 +1,81 @@
+# find Aspects that are represented within the name of a Magnitude or Thing with a Magnitude
+# 
+# fill in the upper section from the filter-not-exists conditions of the first 4 queries
+#
+# the use this query iteratively as follows:
+#
+#   - run the query
+#   - pick a few lines of output
+#   - update the lower section of the query with strings embedded in Magnitude IRI or Thing IRI that represent an Aspect
+#   - repeat
+#
+# this iterative process accounts for every Magnitude and Thing with a Magnitude
+# when the query returns no results, every row of the original output has been accounted for
+
+select distinct ?magnitude ?thing
+
+where {
+  
+   ?magnitude gist:hasUnitOfMeasure ?unit .
+  
+   optional {?thing gist:hasMagnitude ?magnitude . }
+              
+  filter not exists {
+    
+     ?magnitude  ?magnitudeProperty ?magnitudePropertyValue .
+
+     ############# copy values from findAspects1.rq ###################
+     values (?magnitudeProperty     ?magnitudePropertyValue) {        # pairs where the property or the value represents a Magnitude
+       
+            (rdf:type               gist:Duration)            # sample value
+
+            }
+
+            ####################################################
+
+     }
+    
+  filter not exists {              # filter out things for which an Aspect has been identified
+
+     ?thing ?thingProperty ?thingPropertyValue .
+
+     ############## copy values from findAspects2.rq ###################
+     values (?thingProperty     ?thingPropertyValue) {      # more pairs with a property or value that represents an Aspect
+       
+            }
+            ####################################################
+    }
+
+  filter not exists {  # filter out properties that represent an Aspect and have a Magnitude as object
+
+     ?thing ?thingToMagnitudeProperty ?magnitude .
+
+     ############## copy from findAspects3.rq ###################
+     values ?thingToMagnitudeProperty {
+
+            }
+             ####################################################
+     }
+
+  filter not exists {         # filter out cases where an Aspect has the property gist:isAspectOf
+
+     {?aspect gist:isAspectOf ?magnitude .} union {?aspect gist:isAspectOf ?thing.}
+
+     ############## copy from findAspects4.rq ###################
+     values ?aspect {
+  
+            }
+            ####################################################
+     }
+  
+
+# in this section, include substrings of a Magnitude IRI or Thing IRI that represent an Aspect
+#########################################################################################################
+
+   filter(!contains(str(?magnitude), "abc"))             # embedded strings that indicate an Aspect
+
+   filter(!contains(str(?thing), "xyz")) 
+
+#########################################################################################################
+}
+order by ?magnitude ?thing

migration/v13.0/queries/findMagnitudesWithNoAspect.rq

@@ -0,0 +1,11 @@
+# find Magnitudes with no gist:hasAspect
+
+select ?magnitude
+
+where {
+  
+  ?magnitude gist:hasUnitOfMeasure ?unit .
+
+  filter not exists {?magnitude gist:hasAspect ?anything .}
+
+  }

migration/v13.0/queries/findSubclassesOfMagnitude.rq

@@ -0,0 +1,14 @@
+# find subclasses of Magnitude that represent Aspects
+# note: the subclass ReferenceValue does not represent an Aspect
+# 
+# use the output to customize the values list of removeSubclassesOfMagnitude 
+
+select distinct ?subclass
+
+where {
+
+    ?subclass  (rdfs:subClassOf|(owl:equivalentClass/owl:intersectionOf/rdf:first))+ gist:Magnitude .
+    filter(?subclass != gist:ReferenceValue)
+
+}
+order by ?subclass 

migration/v13.0/queries/findSubclassesOfUnitOfMeasure.rq

@@ -0,0 +1,13 @@
+# find subclasses of Unit of Measure
+# 
+# use the output to customize the values list of removeSubclassesOfUnitOfMeasure
+
+select distinct ?subclass
+
+where {
+
+    ?subclass  (rdfs:subClassOf|(owl:equivalentClass/owl:intersectionOf/rdf:first))+ gist:UnitOfMeasure .
+
+}
+order by ?subclass 
+

migration/v13.0/queries/insertAspects1-template.rq

@@ -0,0 +1,42 @@
+# insert new Aspects into the graph, where the old Aspect was represented as a property of a Magnitude, or its value
+
+# test
+select distinct ?magnitude ?aspect ?newAspect
+# select distinct ?magnitude ?magnitudeProperty ?magnitudePropertyValue ?newAspect
+# select distinct ?magnitude ?magnitudeProperty ?newAspect
+
+# insert { ?magnitude gist:hasAspect ?newAspect . }}
+
+where {
+  
+   ?magnitude gist:hasUnitOfMeasure ?unit ;
+              ?magnitudeProperty ?magnitudePropertyValue  ;
+              .
+
+   filter not exists {?magnitude gist:hasAspect ?anything . }   # to prevent duplicates (idempotent)
+              
+  {
+    ################ copy ?magnitudePropertyValue from findAspects1, and add new Aspect #################
+    values (?magnitudePropertyValue   ?newAspect)  {
+       
+           (gist:Duration             gistd:_Aspect_duration)    # sample value
+           }
+
+           ##################################################
+
+   bind(?magnitudePropertyValue as ?aspect)
+  }
+
+  union
+  {
+   ################ copy ?magnitudeProperty from findAspects1, and add new Aspect #################
+   values (?magnitudeProperty   ?newAspect) {
+
+          }
+          ##################################################
+
+   bind(?magnitudeProperty as ?aspect)
+  }
+
+}
+order by ?magnitude ?newAspect